Revise hibernate bug fix (issue #70)

Following a discussion in the comments the DelphiDabbler Blog post at
https://tinyurl.com/mrp76mdy it seems that was not a good idea to rely
upon handling WM_POWERBROADCAST's PBT_APMPOWERSTATUSCHANGE event to
restore the overview pane's tree view nodes to the expected state after
Windows has recreated the tree view in an invalid state.

So I've modified the code to only rely on the PBT_APMSUSPEND event of
WM_POWERBROADCAST and not PBT_APMPOWERSTATUSCHANGE. PBT_APMSUSPEND is
handled to prepare for hibernation by not only saving the tree view's
state (as per the previous fix) but also setting an event handler that
gets called only when the tree view's window gets recreated by Windows
AND the treeview contains nodes with nil IView pointers. When called,
the event handler rebuilds the tree view with nodes containing valid
IView references.

The problem is that the event needs to be triggered from the
TTreeView.CreateWnd method that gets called when Windows recreates the
tree view. Since TTreeView exposes no suitable events, the only way is
to inject a suitable event using a nasty hack. Not good practise.

Note that all the methods that depend on the hack have been given names
beginning with "_HACK_" to make it obvious where the naughtiness lies.

Author: delphidabbler

Src/FmMain.pas

@@ -524,9 +524,10 @@   TMainForm = class(THelpAwareForm)
 
     ///  <summary>Handles the <c>WM_POWERBROADCAST</c> messages to detect and
     ///  respond to hibernation messages.</summary>
-    ///  <remarks>This is necessary as part of the fix for an obscure bug. See
+    ///  <remarks>!! HACK necessary as part of the fix for an obscure bug. See
     ///  https://github.com/delphidabbler/codesnip/issues/70</remarks>
     procedure WMPowerBroadcast(var Msg: TMessage); message WM_POWERBROADCAST;
+
     ///  <summary>Displays view item given by TViewItemAction instance
     ///  referenced by Sender and adds to history list.</summary>
     procedure ActViewItemExecute(Sender: TObject);
@@ -1587,18 +1588,15 @@ procedure TMainForm.splitVertCanResize(Sender: TObject;
 
 procedure TMainForm.WMPowerBroadcast(var Msg: TMessage);
 begin
+  // !! HACK
   // Sometimes when the computer is resumed from hibernation the tree view in
   // the overview frame is destroyed and recreated by Windows. Unfortunately the
   // IView instances associated with the recreated tree nodes are lost.
   // Attempting to read those (now nil) IView instances was resulting in an
   // access violation.
   case Msg.WParam of
     PBT_APMSUSPEND:
-      // Get ready for isolation
-      fMainDisplayMgr.PrepareForHibernate;
-    PBT_APMPOWERSTATUSCHANGE:
-      // Restore from hibernation: ensure the IView instances are recreeated
-      fMainDisplayMgr.RestoreFromHibernation;
+      fMainDisplayMgr._HACK_PrepareForHibernate;
   end;
 end;
 

Src/FrOverview.pas

@@ -26,6 +26,29 @@ interface
 
 type
 
+  // !! HACK
+  // Horrible hack to expose CreateWnd for overiding TTreeView.CreateWnd for the
+  // existing TTreeView component of TOverviewFrame. The hack avoids having to
+  // remove the component and replacing it with a descendant class that is
+  // manually constructed at run time.
+  // This is here to enable the tree view to be recreated with correctly
+  // instantiated TViewItemTreeNode nodes after Windows recreates the tree
+  // behind the scenes after resuming from hibernation.
+  // I am deeply ashamed of this hack.
+  TTreeView = class(ComCtrls.TTreeView)
+  strict private
+    var
+      _HACK_fOnAfterCreateNilViews: TNotifyEvent;
+  protected
+    procedure CreateWnd; override;
+  public
+    ///  <summary>!! HACK. Event triggered after the inherited CreateWnd is
+    ///  called. Only called if the tree view has nil references to IView
+    ///  objects.</summary>
+    property _HACK_OnAfterCreateNilViews: TNotifyEvent
+      read _HACK_fOnAfterCreateNilViews write _HACK_fOnAfterCreateNilViews;
+  end;
+
   {
   TOverviewFrame:
     Titled frame that displays lists of snippets grouped in various ways and
@@ -214,6 +237,10 @@       TTVDraw = class(TSnippetsTVDraw)
     procedure RestoreTreeState;
       {Restores last saved treeview expansion state from memory.
       }
+    ///  <summary>!! HACK: Sets an event handler on the tree view to work
+    ///  around a bug that can occur after resuming from hibernation.</summary>
+    ///  <remarks>Method of IOverviewDisplayMgr.</remarks>
+    procedure _HACK_SetHibernateHandler(const AHandler: TNotifyEvent);
     { IPaneInfo }
     function IsInteractive: Boolean;
       {Checks if the pane is currently interactive with user.
@@ -955,6 +982,12 @@ procedure TOverviewFrame.UpdateTreeState(const State: TTreeNodeAction);
   end;
 end;
 
+procedure TOverviewFrame._HACK_SetHibernateHandler(
+  const AHandler: TNotifyEvent);
+begin
+  tvSnippets._HACK_OnAfterCreateNilViews := AHandler;
+end;
+
 { TOverviewFrame.TTVDraw }
 
 function TOverviewFrame.TTVDraw.IsSectionHeadNode(
@@ -993,5 +1026,24 @@ function TOverviewFrame.TTVDraw.IsUserDefinedNode(
     Result := False;
 end;
 
+{ TTreeView }
+
+procedure TTreeView.CreateWnd;
+var
+  HasNilViews: Boolean;
+  Node: TTreeNode;
+begin
+  inherited;
+  HasNilViews := False;
+  for Node in Items do
+  begin
+    HasNilViews := not Assigned((Node as TViewItemTreeNode).ViewItem);
+    if HasNilViews then
+      Break;
+  end;
+  if HasNilViews and Assigned(_HACK_fOnAfterCreateNilViews) then
+    _HACK_fOnAfterCreateNilViews(Self);
+end;
+
 end.
 

Src/IntfFrameMgrs.pas

@@ -3,7 +3,7 @@
  * v. 2.0. If a copy of the MPL was not distributed with this file, You can
  * obtain one at https://mozilla.org/MPL/2.0/
  *
- * Copyright (C) 2005-2021, Peter Johnson (gravatar.com/delphidabbler).
+ * Copyright (C) 2005-2025, Peter Johnson (gravatar.com/delphidabbler).
  *
  * Declares interfaces, constants and enumerations required to manage various
  * parts of CodeSnip's UI.
@@ -19,6 +19,7 @@ interface
 uses
   // Delphi
   SHDocVw, ActiveX,
+  Classes, // !! For HACK
   // Project
   Browser.IntfDocHostUI, DB.USnippet, Compilers.UGlobals, UCommandBars, UView;
 
@@ -145,6 +146,9 @@ interface
     ///  <summary>Restore expand / collapse state of treeview to last save
     ///  state.</summary>
     procedure RestoreTreeState;
+    ///  <summary>!! HACK: Sets an event handler on the tree view to work
+    ///  around a bug that can occur after resuming from hibernation.</summary>
+    procedure _HACK_SetHibernateHandler(const AHandler: TNotifyEvent);
   end;
 
 type

Src/UMainDisplayMgr.pas

@@ -165,6 +165,11 @@   TMainDisplayMgr = class(TObject)
     procedure DisplayViewItem(ViewItem: IView; Mode: TDetailPageDisplayMode);
       overload;
 
+    ///  <summary>!! HACK event handle to redisplay the overview pane treeview.
+    ///  Called only if Windows has mysteriously recreated the treeview and lost
+    ///  necessary object references.</summary>
+    procedure _HACK_HibernateHandler(Sender: TObject);
+
   public
     ///  <summary>Object contructor. Sets up object to work with given frame
     ///  manager objects.</summary>
@@ -292,21 +297,12 @@   TMainDisplayMgr = class(TObject)
     /// <summary>Prepares display ready for database to be reloaded.</summary>
     procedure PrepareForDBReload;
 
-    ///  <summary>Gets the overview frame prepared for program hibernation.
-    ///  </summary>
+    ///  <summary>!!HACK: gets the overview frame prepared for program
+    ///  hibernation.</summary>
     ///  <remarks>Saves the overview tree view state ready for restoring after
-    ///  hibernation.</remarks>
-    procedure PrepareForHibernate;
-
-    ///  <summary>Restores the overview's tree view to have the correct IView
-    ///  instances after hibernation restores the previously saved state.
-    ///  </summary>
-    ///  <remarks>Sometimes, Windows quietly recreates the node of the tree view
-    ///  after resuming from hibernation, without restoring the associated IView
-    ///  instances, leading to access violations. This method should be called
-    ///  after resuming from hibernation to recreate the tree view with the
-    ///  correct IView instances.</remarks>
-    procedure RestoreFromHibernation;
+    ///  hibernation if Windows has recreated the overview pane's treeview,
+    ///  losing necessary IView object references..</remarks>
+    procedure _HACK_PrepareForHibernate;
 
   end;
 
@@ -583,12 +579,6 @@ procedure TMainDisplayMgr.PrepareForDBViewChange(View: IView);
   fPendingViewChange := True;
 end;
 
-procedure TMainDisplayMgr.PrepareForHibernate;
-begin
-  // simply save the state of the overview tree view ready for later restoration
-  (fOverviewMgr as IOverviewDisplayMgr).SaveTreeState;
-end;
-
 procedure TMainDisplayMgr.RedisplayOverview;
 begin
   (fOverviewMgr as IOverviewDisplayMgr).Display(Query.Selection, True);
@@ -616,12 +606,6 @@ procedure TMainDisplayMgr.ReStart;
   (fOverviewMgr as IOverviewDisplayMgr).Display(Query.Selection, True);
 end;
 
-procedure TMainDisplayMgr.RestoreFromHibernation;
-begin
-  (fOverviewMgr as IOverviewDisplayMgr).Display(Query.Selection, True);
-  (fOverviewMgr as IOverviewDisplayMgr).RestoreTreeState;
-end;
-
 procedure TMainDisplayMgr.SelectAll;
 begin
   // Only details pane supports text selection
@@ -720,5 +704,21 @@ procedure TMainDisplayMgr.UpdateOverviewTreeState(const State: TTreeNodeAction);
   (fOverviewMgr as IOverviewDisplayMgr).UpdateTreeState(State);
 end;
 
+procedure TMainDisplayMgr._HACK_HibernateHandler(Sender: TObject);
+begin
+  (fOverviewMgr as IOverviewDisplayMgr).Display(Query.Selection, True);
+  (fOverviewMgr as IOverviewDisplayMgr).RestoreTreeState;
+  // disable this handler until next resume from hibernation
+  (fOverviewMgr as IOverviewDisplayMgr)._HACK_SetHibernateHandler(nil);
+end;
+
+procedure TMainDisplayMgr._HACK_PrepareForHibernate;
+begin
+  (fOverviewMgr as IOverviewDisplayMgr).SaveTreeState;
+  (fOverviewMgr as IOverviewDisplayMgr)._HACK_SetHibernateHandler(
+    _HACK_HibernateHandler
+  );
+end;
+
 end.