Initializing SD Card on Waveshare LCD Touch 7"

[extremerotary]

Good morning,
I am facing an issue where I am unable to initialize the SD Card on the Waveshare LCD Touch 7". I realize this may be a little out-of-scope for the purposes of this library, but I am looking for some guidance as I believe the issue is either with conflicting PINs or something to do with how the IO Expander is initialized because I then need to access the IO Expander to initialize and utilize the SD Card. I am programming in PlatformIO.
The Waveshare's example code below compiles in ArduinoIDE without issue and properly outputs the 8Gb SD Card I have inserted into the display.

#include "waveshare_sd_card.h"

// Initial Setup
void setup(){
    Serial.begin(115200);

    Serial.println("Initialize IO expander");
    /* Initialize IO expander */
    ESP_IOExpander_CH422G *expander = new ESP_IOExpander_CH422G((i2c_port_t)I2C_MASTER_NUM, ESP_IO_EXPANDER_I2C_CH422G_ADDRESS, I2C_MASTER_SCL_IO, I2C_MASTER_SDA_IO);
    expander->init();
    expander->begin();

    Serial.println("Set the IO0-7 pin to output mode.");
    expander->enableAllIO_Output();
    expander->digitalWrite(TP_RST , HIGH);
    expander->digitalWrite(LCD_RST , HIGH);
    expander->digitalWrite(LCD_BL , HIGH);

    // Use extended GPIO for SD card
    expander->digitalWrite(SD_CS, LOW);

    // Turn off backlight
    expander->digitalWrite(LCD_BL, LOW);

    // When USB_SEL is HIGH, it enables FSUSB42UMX chip and gpio19, gpio20 wired CAN_TX CAN_RX, and then don't use USB Function 
    expander->digitalWrite(USB_SEL, LOW);

    // Initialize SPI
    SPI.setHwCs(false);
    SPI.begin(SD_CLK, SD_MISO, SD_MOSI, SD_SS);
    if (!SD.begin()) {
        Serial.println("Card Mount Failed"); // SD card mounting failed
        return;
    }
    uint8_t cardType = SD.cardType();

    if (cardType == CARD_NONE) {
        Serial.println("No SD card attached"); // No SD card connected
        return;
    }

    Serial.print("SD Card Type: "); // SD card type
    if (cardType == CARD_MMC) {
        Serial.println("MMC");
    } else if (cardType == CARD_SD) {
        Serial.println("SDSC");
    } else if (cardType == CARD_SDHC) {
        Serial.println("SDHC");
    } else {
        Serial.println("UNKNOWN"); // Unknown Type
    }

    uint64_t cardSize = SD.cardSize() / (1024 * 1024);
    Serial.printf("SD Card Size: %lluMB\n", cardSize); // SD card size

    // Testing file system functionality
    listDir(SD, "/", 0);
    createDir(SD, "/mydir");
    listDir(SD, "/", 0);
    removeDir(SD, "/mydir");
    listDir(SD, "/", 2);
    writeFile(SD, "/hello.txt", "Hello ");
    appendFile(SD, "/hello.txt", "World!\n");
    readFile(SD, "/hello.txt");
    deleteFile(SD, "/foo.txt");
    renameFile(SD, "/hello.txt", "/foo.txt");
    readFile(SD, "/foo.txt");
    testFileIO(SD, "/test.txt");
    Serial.printf("Total space: %lluMB\n", SD.totalBytes() / (1024 * 1024)); // Total space
    Serial.printf("Used space: %lluMB\n", SD.usedBytes() / (1024 * 1024)); // Used space
}

// Main Loop
void loop() {
    
}

In my PlatformIO project, I have attempted to port this code over in such a way that I can call SD_init(). However, when I do so, I either get system crashes (when trying to define a new IO Expander), or the LCD itself turns my UI blue (likely an issue on conflicting PINs or order of operations between the board and LCD init() functions and the SD_init() function).

Is there any way you help guide me on the proper way to initialize and utilize the SD Card on this board? For reference, my setup() function looks like this:

void setup()
{

  Serial.begin(115200);
  //createWifiKey();
  delay(100); // Rumors say it helps avoid sporadical crashes after wakeup from deep-sleep

  WiFi.mode(WIFI_STA);
  delay(50);

  Serial.print("MAC Address: ");
  Serial.println(WiFi.macAddress());
  myMac = WiFi.macAddress();
  if (esp_now_init() == ESP_OK)
  {
    esp_now_register_recv_cb(OnDataRecv);
    esp_now_register_send_cb(OnDataSent);
  }
  if (esp_now_set_pmk(esp_now_key) != ESP_OK)
  {
    Serial.println("Error setting ESP-NOW PMK");
  }
  // load UI
  Serial.println("Initializing board");
  Board *board = new Board();
  board->init();
  assert(board->begin());
  Serial.println("Initializing LVGL");
  lvgl_port_init(board->getLCD(), board->getTouch());

  Serial.println("Creating UI");
  ui_init();   // function defined in my ui.h file

initializeSdCard();
}

And here are the 2 helper functions for the SD Card:

bool SD_init(void) {

 Serial.println("Initialize IO expander");
    /* Initialize IO expander */
/*
    ESP_IOExpander_CH422G *expander = new ESP_IOExpander_CH422G((i2c_port_t)I2C_MASTER_NUM, ESP_IO_EXPANDER_I2C_CH422G_ADDRESS, I2C_MASTER_SCL_IO, I2C_MASTER_SDA_IO);
    expander->init();
    expander->begin();

    Serial.println("Set the IO0-7 pin to output mode.");
    expander->enableAllIO_Output();
    expander->digitalWrite(TP_RST , HIGH);
    expander->digitalWrite(LCD_RST , HIGH);
    expander->digitalWrite(LCD_BL , HIGH);

    // Use extended GPIO for SD card
    expander->digitalWrite(SD_CS, LOW);
 // Initialize SPI
    SPI.setHwCs(false);
    SPI.begin(SD_CLK, SD_MISO, SD_MOSI, SD_SS);
*/

/* The above code causes the board to go into a crash loop*/

  if (!SD.begin()) {
      Serial.println("Card Mount Failed"); // SD card mounting failed
      return false;
  }
  return true;
}
void initializeSdCard()
{
  sdCard = SD_init();   // global bool variable. Causes UI to be blue
  if (sdCard)
  {
    // Check the total space and used space on the SD card
    uint64_t totalBytes = SD.totalBytes();
    uint64_t usedBytes = SD.usedBytes();
    freePercentage = ((totalBytes - usedBytes) * 100) / totalBytes;

    Serial.printf("SD Card Total Space: %llu bytes\n", totalBytes);
    Serial.printf("SD Card Used Space: %llu bytes\n", usedBytes);
    Serial.printf("SD Card Free Space: %d%%\n", freePercentage);
  }
}

Any guidance you can provide is greatly appreciated. I see the expander being initialized in the esp_panel_board.cpp file, but I don't understand how to use that code to also initialize the SD Card. Thanks for your time.

[Lzw655]

Hi @extremerotary,

I think this problem is caused by the repeated creation and operation of CH422G by LCD (board) and SDCard. In fact, you can directly obtain the handle to obtain CH422G from board and use it for SDCard. Refer to the following code:

void setup()
{
...
  initializeSdCard(board->getIO_Expander()->getBase());
}

bool SD_init(esp_expander::Base *expander) {
    /* Don't need to initialize CH422G and operate LCD/Touch pins here */
    // ESP_IOExpander_CH422G *expander = new ESP_IOExpander_CH422G((i2c_port_t)I2C_MASTER_NUM, ESP_IO_EXPANDER_I2C_CH422G_ADDRESS, I2C_MASTER_SCL_IO, I2C_MASTER_SDA_IO);
    // expander->init();
    // expander->begin();
    //Serial.println("Set the IO0-7 pin to output mode.");
    //expander->enableAllIO_Output();
    //expander->digitalWrite(TP_RST , HIGH);
    //expander->digitalWrite(LCD_RST , HIGH);
    // expander->digitalWrite(LCD_BL , HIGH);

    // Use extended GPIO for SD card
    expander->digitalWrite(SD_CS, LOW);
    ...
}

void initializeSdCard(esp_expander::Base *expander)
{
  sdCard = SD_init(expander);   // global bool variable. Causes UI to be blue
  ...
}

[extremerotary]

Thank you! I will try this in my morning and report back.

[extremerotary]

This is working as expected. Thank you very much for your assistance!

[Lzw655]

Great! You are welcome.

[extremerotary]

@Lzw655 - I may have been a little premature. It does now read the SD card but when it renders the LCD has the blue hue. Any idea what could be causing the hue change and/or do you have a board you can replicate this issue on?

[Lzw655]

Can you take a picture of the LCD display when there is a problem? Please also provide the project source code if it's ok?

[extremerotary]

Good morning,
I will work on getting you the information today. I can't provide all my code, but I'll see if I can create a small version that replicates the issue. Updates to follow, thanks!

[extremerotary]

@Lzw655
Good morning and sorry about the delay here. I've been very busy! I'm attaching a zip file with example code to reproduce the issue. Obviously it's difficult to get the colors right with taking a picture of a screen, but here you go -

This picture is with commenting out line 55 of main.cpp. You can see that the colors look good and the block text is black.

This picture is after removing the comment on line 55. You can see that the colors' hue is off and the block text is blue.

The difference is a lot easier to see in person.

sdCardTest.zip

[Lzw655]

Hi @extremerotary,

Could you try to use the following platform packages? I think it might be related to the RGB screen drift issue.

platform_packages =
    platformio/framework-arduinoespressif32@https://github.com/espressif/arduino-esp32.git#3.1.1
; Use high performance libraries to improve the performance, and avoid esp32s3 RGB LCD screen drifting issue
    platformio/framework-arduinoespressif32-libs@https://dl.espressif.com/AE/esp-arduino-libs/esp32-3.1.1-h.zip

[extremerotary]

I updated my platformio.ini file to this:

[platformio]
default_envs =
        BOARD_WAVESHARE_ESP32_S3_TOUCH_LCD_7

[common]
build_flags =
; Arduino related:
    -DCORE_DEBUG_LEVEL=0    ; Set to `5` for full debug output, `0` for none
; LVGL related:
    -DLV_CONF_INCLUDE_SIMPLE
    -DLV_LVGL_H_INCLUDE_SIMPLE
; Include path:
    -I src
; Others:
    ; -DDISABLE_ALL_LIBRARY_WARNINGS    ; Disable all library warnings

[spi_qspi_lcd]
build_flags =
; LVGL related:
    -DLV_COLOR_16_SWAP=1

[rgb_mipi_lcd]
build_flags =
; LVGL related:
    -DLV_COLOR_16_SWAP=0

;
[env:BOARD_WAVESHARE_ESP32_S3_TOUCH_LCD_7]
board = BOARD_WAVESHARE_ESP32_S3_TOUCH_LCD_7
framework = arduino
;platform = https://github.com/pioarduino/platform-espressif32/releases/download/53.03.11/platform-espressif32.zip
platform = espressif32@53.3.11
platform_packages =
    platformio/framework-arduinoespressif32@3.1.1
    platformio/framework-arduinoespressif32-libs@https://dl.espressif.com/AE/esp-arduino-libs/esp32-3.1.1-h.zip
monitor_speed = 115200
lib_deps =
    https://github.com/esp-arduino-libs/ESP32_Display_Panel.git
    https://github.com/esp-arduino-libs/ESP32_IO_Expander.git#v1.1.0
    https://github.com/esp-arduino-libs/esp-lib-utils.git#v0.2.0
    https://github.com/lvgl/lvgl.git#v8.4.0

; Explicitly set the flash size and maximum size
board_build.flash_size = 8MB
board_build.maximum_size = 8388608
board_build.mcu = esp32s3
board_build.f_flash = 80000000L
board_build.partitions = partitions.csv

build_flags =
    ${common.build_flags}
    ${rgb_mipi_lcd.build_flags}
    -DESP_PANEL_BOARD_DEFAULT_USE_SUPPORTED=1
    -DBOARD_WAVESHARE_ESP32_S3_TOUCH_LCD_7
    -DLV_CONF_PATH="C:\Users\extre\OneDrive\DialedN\OneGauge\DigitalDashV2\src\lv_conf.h"
    -DSECURE_BOOT
    -DBOARD_HAS_PSRAM
    -DARDUINO_USB_MODE=1
    -DARDUINO_FLASH_SIZE=8388608

I have the same behavior with the blueish hue.

I also tried to increase my buffer size between board init and begin in my setup function, but also the same result:

board = new Board();
  board->init();

  auto bus = static_cast<esp_panel::drivers::BusRGB *>(board->getLCD()->getBus());
  bus->configRGB_BounceBufferSize(800 * 20);

  assert(board->begin());

[Lzw655]

I'm so sorry, I haven't encountered this phenomenon yet.

Hi @Y1hsiaochunnn, do you have any suggestions for this problem?

[Y1hsiaochunnn]

It might seem like this can only be caused by repeated calls to RGB GPIO pins (which I have encountered), but from the schematic of waveshare, they shouldn't interfere. Is Platformio occupying the RGB signal pin when configuring SD? Or hidden IO effects?

My suggestion is to test the demo of esp-idf or Arduino ide is it the difference on the platform?

[extremerotary]

@Y1hsiaochunnn
I am unable to set the PSRAM option from the ArduinoIDE documentation. There is no "OPI-PSRAM"

When I set to disabled, it crashes over and over without anything displayed.

When I set it to enabled, it still crashes over and over, but I do get an image displayed momentarily, and it looks like the correct hue.

12:24:58.984 -> Initializing board
12:24:58.984 -> [I][LvPort]esp_panel_board.cpp:0066: Initializing board (Waveshare:ESP32_S3_TOUCH_LCD_7)
12:24:59.026 -> [I][LvPort]esp_panel_board.cpp:0235: Board initialize success
12:24:59.026 -> [I][LvPort]esp_panel_board.cpp:0253: Beginning board (Waveshare:ESP32_S3_TOUCH_LCD_7)
12:24:59.026 -> [I][Expander]esp_io_expander_ch422g.c:0075: version: 0.1.0
12:24:59.138 -> E (357) lcd_panel.rgb: lcd_rgb_panel_alloc_frame_buffers(164): no mem for frame buffer
12:24:59.138 -> E (358) lcd_panel.rgb: esp_lcd_new_rgb_panel(347): alloc frame buffers failed
12:24:59.138 -> [E][LvPort]esp_panel_lcd_st7262.cpp:0079: Create refresh panel failed [ESP_ERR_NO_MEM]
12:24:59.184 -> [E][LvPort]esp_panel_lcd.cpp:0404: Init failed
12:24:59.184 -> [E][LvPort]esp_panel_board.cpp:0315: LCD device begin failed
12:24:59.184 ->
12:24:59.219 -> assert failed: void setup() C:\Users\extre\Documents\Arduino\waveshare7_touch_lcd_sdcard_test_arduino_ide\waveshare7_touch_lcd_sdcard_test_arduino_ide.ino:100 (board->begin())
12:24:59.219 ->
12:24:59.219 -> Backtrace: 0x40376692:0x3fcabbd0 0x4037d631:0x3fcabbf0 0x403843c9:0x3fcabc10 0x4200259a:0x3fcabd40 0x42043c1a:0x3fcabd90 0x4037e252:0x3fcabdb0
12:24:59.219 ->
12:24:59.219 ->
12:24:59.219 ->
12:24:59.219 ->
12:24:59.219 -> ELF file SHA256: 019608a9d
12:24:59.219 ->
12:24:59.609 -> Rebooting...

If you can help me get the ArduinoIDE to compile without crashing, I can verify better.