SmartConfig fails connection - appears not saving SSID

[mickeypop]

Hardware:

Board:                                        ESP32 Core Dev Module, Generic Modules, and ESP32-VROOM
Core Installation/update date:  I do git update weekly, this update 2/10/18
IDE name:                                   Arduino IDE, 1.8.5
Flash Frequency:                        80Mhz
Upload Speed:                           921600

Description:

I may have found what is failing, but not sure how to fix this.
Note the print statements between "SmartConfig done." and "Waiting for WiFi".

Verbose Log shows SSID: myplace was passed but appears not to be saving. This is reproduced on 4 different boards.

Reading NVR the password is stored correctly but SSID does not seem to be saved, more so its blank.
This seems to be the fault resulting in connection failure.

Like others; the "Waiting for WiFi" loop never exits with AUTH_FAIL.

Note i added 2 extra log statements to the _smartConfigCallback() for better info

		log_d("bssid_set: %d", sta_conf->bssid_set);
		log_d("BSSID: %x", sta_conf->bssid); 

BASIC demo sketch with just a few prints added (indented)

#include "WiFi.h"
void setup() {
  Serial.begin(115200);
  WiFi.mode(WIFI_AP_STA);
  WiFi.beginSmartConfig();

  Serial.println("Waiting for SmartConfig.");
  while (!WiFi.smartConfigDone()) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("SmartConfig done.");

	Serial.print( "\n\tREADING NVR\n");
	Serial.printf( "\tSSID = %s\n"   , WiFi.SSID().c_str() );
	Serial.printf( "\tPSK  = %s\n\n" , WiFi.psk().c_str()  );

  Serial.println("Waiting for WiFi");

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.print("WiFi Connected.\nIP Address: ");
  Serial.println(WiFi.localIP());
}
void loop() {
}

=== Verbose Log ==============

ets Jun  8 2016 00:22:57

rst:0x10 (RTCWDT_RTC_RESET),boot:0x13 (SPI_FAST_FLASH_BOOT)
configsip: 0, SPIWP:0xee
clk_drv:0x00,q_drv:0x00,d_drv:0x00,cs0_drv:0x00,hd_drv:0x00,wp_drv:0x00
mode:DIO, clock div:1
load:0x3fff0018,len:4
load:0x3fff001c,len:956
load:0x40078000,len:0
load:0x40078000,len:11904
entry 0x40078a3c
[D][WiFiGeneric.cpp:265] _eventCallback(): Event: 13 - AP_STOP
[D][WiFiGeneric.cpp:265] _eventCallback(): Event: 14 - AP_STACONNECTED
[D][WiFiGeneric.cpp:265] _eventCallback(): Event: 14 - AP_STACONNECTED
Waiting for SmartConfig.
.........[D][WiFiSTA.cpp:621] _smartConfigCallback(): Status: FIND_CHANNEL
...............[D][WiFiSTA.cpp:621] _smartConfigCallback(): Status: GETTING_SSID_PSWD
[D][WiFiSTA.cpp:624] _smartConfigCallback(): Type: ESPTOUCH
.....[D][WiFiSTA.cpp:621] _smartConfigCallback(): Status: LINK
[D][WiFiSTA.cpp:627] _smartConfigCallback(): SSID: myplace
[D][WiFiSTA.cpp:629] _smartConfigCallback(): bssid_set: 131
.
SmartConfig done.

	READING NVR
	SSID = 
	PSK  = J************e

	Waiting for WiFi
....[D][WiFiGeneric.cpp:265] _eventCallback(): Event: 5 - STA_DISCONNECTED
[W][WiFiGeneric.cpp:270] _eventCallback(): Reason: 201 - AUTH_FAIL
..........................

My modified WiFiSTAClass::_smartConfigCallback( )

void WiFiSTAClass::_smartConfigCallback(uint32_t st, void* result) {
    smartconfig_status_t status = (smartconfig_status_t) st;
    log_d("Status: %s", sc_status_strings[st % 5]);
    if (status == SC_STATUS_GETTING_SSID_PSWD) {
        smartconfig_type_t * type = (smartconfig_type_t *)result;
        log_d("Type: %s", sc_type_strings[*type % 3]);
    } else if (status == SC_STATUS_LINK) {
        wifi_sta_config_t *sta_conf = reinterpret_cast<wifi_sta_config_t *>(result);
        log_d("SSID: %s", (char *)(sta_conf->ssid));
		
		log_d("bssid_set: %d", sta_conf->bssid_set);
		log_d("BSSID: %x", sta_conf->bssid);
		
        esp_wifi_set_config(WIFI_IF_STA, (wifi_config_t *)sta_conf);
        esp_wifi_connect();
        _smartConfigDone = true;
    } else if (status == SC_STATUS_LINK_OVER) {
        if(result){
            ip4_addr_t * ip = (ip4_addr_t *)result;
            log_d("Sender IP: " IPSTR, IP2STR(ip));
        }
        WiFi.stopSmartConfig();
    }
}

[mickeypop]

UPDATE
on a whim i scanned an found 2 example sketches were not updated.

I renamed the esp32 folder and did full clone.

It's working now

[dhernandezgt]

Hi Mickey how are your doing?

I am testing SmartConfig on ESP32 but have the problem you reported here.
I am able to config SSID/pass on ESP32 dev kit but after I reboot it configuration deleted and I have to use APP again for set confirgaration.
I copy your modified WiFiSTAClass::_smartConfigCallback( ) on .cpp file but still continue without store configuration
Would you share your solution for issue please?

thanks in advance

[mickeypop]

@dhernandezgt

for it to reconnect automatically on boot, you have to read in the stored WiFi settings and
run the WiFi.begin() with the stored settings

this should offer a complete SmartConfig / WiFi skeleton
- it deals with when to run SmartConfig, WiFi UP and DOWN
- Automatic reconnect and secondary credentials storage to prevent repeated writes to flash

i used WS8212 LEDs for the flasher and makes for too much code here.
Left notes to where i used the flasher if you want indicators.
ESP32Ticker library set the timing for flashing leds if you want a good esp32 ticker.

My approach to the flasher was to leave the ticker running and set a variable true or false to start and stop the LED.

#include "FS.h"
#include "esp_system.h"
#include <esp_wifi.h>
#include <string.h>
#include <WiFi.h>
#include <Preferences.h>  // WiFi storage

  const  char* rssiSSID;       // NO MORE hard coded set AP, all SmartConfig
  const  char* password;
  String PrefSSID, PrefPassword;  // used by preferences storage

  int  WFstatus;
  int UpCount; = 0;
  int32_t rssi;           // store WiFi signal strength here
  String getSsid;
  String getPass;
  String  MAC;

  // SSID storage
       Preferences preferences;  // declare class object
  // END SSID storage
  
void setup() {
  Serial.begin(115200);
  Serial.printf("\tWiFi Setup -- \n"  ); 

  wifiInit();       // get WiFi connected
  IP_info();
  MAC = getMacAddress();

  delay(2000);
} //  END setup()
  
void loop()
{
  if ( WiFi.status() ==  WL_CONNECTED )      // Main connected loop

  { 
		// ANY MAIN LOOP CODE HERE

  }   // END Main connected loop()
  else
  {            // WiFi DOWN

     //  wifi down start LED flasher here

         WFstatus = getWifiStatus( WFstatus );

     WiFi.begin( PrefSSID.c_str() , PrefPassword.c_str() );
     int WLcount = 0;
     while (WiFi.status() != WL_CONNECTED && WLcount < 200 )
     {
      delay( 100 );
         Serial.printf(".");

         if (UpCount >= 60)  // keep from scrolling sideways forever
         {
            UpCount = 0;
               Serial.printf("\n");
         }
         ++UpCount;
         ++WLcount;
     }

    if( getWifiStatus( WFstatus ) == 3 )   //wifi returns
    { 
		// stop LED flasher, wifi going up
    }
     delay( 1000 );
  }  // END WiFi down 
} // END loop()
  
void wifiInit()  // 
{
   WiFi.mode(WIFI_AP_STA);   // required to read NVR before WiFi.begin()

   // load credentials from NVR, a little RTOS code here
   wifi_config_t conf;
   esp_wifi_get_config(WIFI_IF_STA, &conf);  // load wifi settings to struct comf
   rssiSSID = reinterpret_cast<const char*>(conf.sta.ssid);
   password = reinterpret_cast<const char*>(conf.sta.password);

    //  Serial.printf( "%s\n", rssiSSID );
    //  Serial.printf( "%s\n", password );

   // Open Preferences with "wifi" namespace. Namespace is limited to 15 chars
   preferences.begin("wifi", false);
       PrefSSID          =  preferences.getString("ssid", "none");      //NVS key ssid
       PrefPassword  =  preferences.getString("password", "none");  //NVS key password
   preferences.end();

   // keep from rewriting flash if not needed
   if( !checkPrefsStore() )    	// see is NV and Prefs are the same
   {  						// not the same, setup with SmartConfig
      if( PrefSSID == "none" )  // New...setup wifi
      {
        initSmartConfig(); 
        delay( 3000);
        ESP.restart();   // reboot with wifi configured
      }
   } 

   // I flash LEDs while connecting here

   WiFi.begin( PrefSSID.c_str() , PrefPassword.c_str() );

   int WLcount = 0;
   while (WiFi.status() != WL_CONNECTED && WLcount < 200 ) // can take > 100 loops depending on router settings
   {
     delay( 100 );
        Serial.printf(".");
     ++WLcount;
   }
  delay( 3000 );

  //  stop the led flasher here

  }  // END wifiInit()

// match WiFi IDs in NVS to Pref store,  assumes WiFi.mode(WIFI_AP_STA);  was executed
bool checkPrefsStore()   
{
    bool val = false;
    String NVssid, NVpass, prefssid, prefpass;

    NVssid = getSsidPass( "ssid" );
    NVpass = getSsidPass( "pass" );

    // Open Preferences with my-app namespace. Namespace name is limited to 15 chars
    preferences.begin("wifi", false);
        prefssid  =  preferences.getString("ssid", "none");     //NVS key ssid
        prefpass  =  preferences.getString("password", "none"); //NVS key password
    preferences.end();

    if( NVssid.equals(prefssid) && NVpass.equals(prefpass) )
      { val = true; }

  return val;
}

// optionally call this function any way you want in your own code
// to remap WiFi to another AP using SmartConfig mode.   Button, condition etc.. 
void initSmartConfig() 
{
   // start LED flasher
  int loopCounter = 0;

  WiFi.mode( WIFI_AP_STA );       //Init WiFi, start SmartConfig
      Serial.printf( "Entering SmartConfig\n" );

  WiFi.beginSmartConfig();

  while (!WiFi.smartConfigDone()) 
  {
     // flash led to indicate not configured
          Serial.printf( "." );
     if( loopCounter >= 40 )  // keep from scrolling sideways forever
     {
         loopCounter = 0;
         Serial.printf( "\n" );
     }
     delay(600);
    ++loopCounter;
  }
  loopCounter = 0;

  // stopped flasher here

   Serial.printf("\nSmartConfig received.\n Waiting for WiFi\n\n");
   delay(2000 );
	  
  while( WiFi.status() != WL_CONNECTED )    	// check till connected
  { 
    delay(500);
  }
  IP_info();  // connected lets see IP info

  preferences.begin("wifi", false);      // put it in storage
     preferences.putString( "ssid"         , getSsid);
     preferences.putString( "password", getPass);
  preferences.end();

    delay(300);
}  // END SmartConfig()

void IP_info()
{
   getSsid = WiFi.SSID();
   getPass = WiFi.psk();
   rssi = getRSSI(  rssiSSID );
   WFstatus = getWifiStatus( WFstatus );
   MAC = getMacAddress();

      Serial.printf( "\n\n\tSSID\t%s, ", getSsid.c_str() );
      Serial.print( rssi);  Serial.printf(" dBm\n" );  // printf??
      Serial.printf( "\tPass:\t %s\n", getPass.c_str() ); 
      Serial.print( "\n\n\tIP address:\t" );  Serial.print(WiFi.localIP() );
      Serial.print( " / " );
      Serial.println( WiFi.subnetMask() );
      Serial.print( "\tGateway IP:\t" );  Serial.println( WiFi.gatewayIP() );
      Serial.print( "\t1st DNS:\t" );     Serial.println( WiFi.dnsIP() );
      Serial.printf( "\tMAC:\t\t%s\n", MAC.c_str() );
}

int getWifiStatus( int WiFiStatus  )
{
  WiFiStatus = WiFi.status();
  Serial.printf("\tStatus %d",  WiFiStatus );
  switch( WiFiStatus )
  {
    case WL_IDLE_STATUS :                         // WL_IDLE_STATUS     = 0,
          Serial.printf(", WiFi IDLE \n");
          break;
    case WL_NO_SSID_AVAIL:                        // WL_NO_SSID_AVAIL   = 1,
          Serial.printf(", NO SSID AVAIL \n");
          break;
    case WL_SCAN_COMPLETED:                       // WL_SCAN_COMPLETED  = 2,
          Serial.printf(", WiFi SCAN_COMPLETED \n");
          break;
    case WL_CONNECTED:                            // WL_CONNECTED       = 3,
          Serial.printf(", WiFi CONNECTED \n");
          break;
    case WL_CONNECT_FAILED:                       // WL_CONNECT_FAILED  = 4,
          Serial.printf(", WiFi WL_CONNECT FAILED\n"); 
          break;
    case WL_CONNECTION_LOST:                      // WL_CONNECTION_LOST = 5,
          Serial.printf(", WiFi CONNECTION LOST\n");
          WiFi.persistent(false);                 // don't write FLASH
          break;
    case WL_DISCONNECTED:                         // WL_DISCONNECTED    = 6
          Serial.printf(", WiFi DISCONNECTED ==\n");
          WiFi.persistent(false);                 // don't write FLASH when reconnecting
          break;
  }
  return WiFiStatus;
}
// END getWifiStatus()

// Get the station interface MAC address.
// @return String MAC
String getMacAddress(void)
{
    WiFi.mode(WIFI_AP_STA);                    // required to read NVR before WiFi.begin()
    uint8_t baseMac[6];
    esp_read_mac( baseMac, ESP_MAC_WIFI_STA ); // Get MAC address for WiFi station
    char macStr[18] = { 0 };
    sprintf(macStr, "%02X:%02X:%02X:%02X:%02X:%02X", baseMac[0], baseMac[1], baseMac[2], baseMac[3], baseMac[4], baseMac[5]);
    return String(macStr);
}
// END getMacAddress()


// Return RSSI or 0 if target SSID not found
// const char* SSID = "YOUR_SSID";  // declare in GLOBAL space
// call:  int32_t rssi = getRSSI( SSID );
int32_t getRSSI( const char* target_ssid ) 
{
  byte available_networks = WiFi.scanNetworks();

  for (int network = 0; network < available_networks; network++) 
  {
    if ( strcmp(  WiFi.SSID( network).c_str(), target_ssid ) == 0) 
    {
      return WiFi.RSSI( network );
    }
  }
  return 0;
} //  END  getRSSI()


// Requires; #include <esp_wifi.h>
// Returns String NONE, ssid or pass arcording to request 
// ie String var = getSsidPass( "pass" );
String getSsidPass( String s )
{
  String val = "NONE";  // return "NONE" if wrong key sent
  s.toUpperCase();
  if( s.compareTo("SSID") == 0 )
  {
     wifi_config_t conf;
     esp_wifi_get_config( WIFI_IF_STA, &conf );
     val = String( reinterpret_cast<const char*>(conf.sta.ssid) );
  }
  if( s.compareTo("PASS") == 0 )
  {
     wifi_config_t conf;
     esp_wifi_get_config( WIFI_IF_STA, &conf );
     val = String( reinterpret_cast<const char*>(conf.sta.password) );
  }
 return val;
}

[dhernandezgt]

hi Mickey,

thanks for your code and your fast response, a little more complex, I have a question about *.h sources and another for variables in code. please have a look on them.

1. the sources file I don't have some of them such as FS.h, esp_system.h, string.h and Preferences.h. do they belong to different packages?

#include "FS.h"
#include "esp_system.h"
#include <esp_wifi.h>
#include <string.h>
#include <WiFi.h>
#include <Preferences.h> // WiFi storage

2. I tried to pass on Arduino IDE but it pop up with a variable does not declared onto scope. it is UpCount and probably WLcount else

the part of code is:

WiFi.begin( PrefSSID.c_str() , PrefPassword.c_str() );
int WLcount = 0;
while (WiFi.status() != WL_CONNECTED && WLcount < 200 )
{
delay( 100 );
Serial.printf(".");

     if (UpCount >= 60)  // keep from scrolling sideways forever
     {
        UpCount = 0;
           Serial.printf("\n");
     }
     ++UpCount;
  ++WLcount;
}

Regards.

DH

[mickeypop]

1 the .h files are part of the espressif clone you did to setup arduino

2 put UpCount at top of your code near int WFstatus

int UpCount = 0;

[dhernandezgt]

hi Mickey,

After set UpCount variable compiling continues but display another error shows below. I tried to use same approach (it is not variable I guess it because it attached to a method) without successful.

thanks again for your support, regards.

DH

[mickeypop]

sorry about that. I put that skeleton together fairly fast from other code.
any time you see an <object>.<function> it's part of a Class.
ie preferences.getString(...);

So Preferences preferences; declares the object "preferences"

put this in top section of code below the .h declarations and before setup()

  **// SSID storage
         Preferences preferences;  // declare class object
  // END SSID storage**

[dhernandezgt]

Thanks Mickey. great code.!!👏

…

On Mon, May 28, 2018 at 1:09 PM, Mickey ***@***.***> wrote: sorry about that. I put that skeleton together fairly fast. any time you see an . it's part of a Class. ie preferences.getString(...); So Preferences preferences; declares the object "preferences" put this in top section of code **``` // SSID storage Preferences preferences; // declare class object // END SSID storage — You are receiving this because you commented. Reply to this email directly, view it on GitHub <#1100 (comment)>, or mute the thread <https://github.com/notifications/unsubscribe-auth/Al18tlPigZ03xBPOlsq5_deVYyOcw5KFks5t3EtwgaJpZM4SBrcp> .

[vinot]

Hi all,
thank you so much Mickey, I still don't know how, but you resolved it ( I was also trying to save ssid/pass to recover it after rebooting the esp through nvs). What surprise me is, after load and test (very quick) your sketch, I upload my sketch (without modifications) and, after several reboots, esp loads ssid/pass at first time.

thank you again
toni

[mickeypop]

vinot
Glad you like it

You want to see what it can do?

While it is running unplug your router and watch.
In about 15-30 seconds it will see the wifi is down.

Plug it back in and in about 40 seconds it will reconnect automatically and be back on line.

[vinot]

hi Mickey

definetly I'm going to spend the necessary time to understand all your code. We are developing a simple hardware (virtual feet) for VR and esp32 seems to be a good way, even it's more complex than others mcu, but also more powerful.

thank you again

[rodrigoazor]

Hi Mickey,

Sory... can you help me ?

[mickeypop]

@rodrigoazor

not seeing your code, esp_system.h has got to be missing
ESP_MAC_WIFI_STA is declared as a typedef there.

just add it to the top of your code in global space;
#include "esp_system.h"

==========
Separately just for info;
look at my getMacAddress() in the skeleton code above.
first line sets mode, this is critically important.
WiFi.mode( WIFI_AP_STA ); // required to read NVR before WiFi.begin() or mode set

if you don't have wifi connected before a call to esp_read_mac() it will fail and the compiler will catch it.

have wifi.mode set before esp_read_mac() and it should work

if WiFi services are not setup several data areas are not accessible. SSID, PASS, MAC, INDEX etc...
once the WiFi is connected(sets mode) or the mode is set they open up.