build: Add CMake-based build system (4 of N)

CMakeLists.txt

@@ -0,0 +1,199 @@
+# Copyright (c) 2023 The Bitcoin Core developers
+# Distributed under the MIT software license, see the accompanying
+# file COPYING or http://www.opensource.org/licenses/mit-license.php.
+
+# IMPORTANT: Changes which affect binary results may not be quietly gated
+#            by CMake version.
+#
+# Debian 10 Buster, https://wiki.debian.org/LTS, EOL 2024:
+#  - CMake 3.13.4, https://packages.debian.org/buster/cmake
+#
+# Ubuntu 22.04 Jammy, https://wiki.ubuntu.com/Releases, EOL 2032:
+#  - CMake 3.22.1, https://packages.ubuntu.com/jammy/cmake
+#
+# Visual Studio 17 2022, https://visualstudio.microsoft.com:
+#  - CMake 3.24
+#
+# All policies known to the running version of CMake and introduced
+# in the 3.24 version or earlier will be set to use NEW behavior.
+# All policies introduced in later versions will be unset.
+# See: https://cmake.org/cmake/help/latest/manual/cmake-policies.7.html
+cmake_minimum_required(VERSION 3.13...3.24)
+
+project("Bitcoin Core"
+  VERSION 24.99.0
+  DESCRIPTION "Bitcoin client software"
+  HOMEPAGE_URL "https://bitcoincore.org/"
+  LANGUAGES CXX C ASM
+)
+
+set(CLIENT_VERSION_IS_RELEASE "false")
+set(COPYRIGHT_YEAR "2023")
+set(COPYRIGHT_HOLDERS "The %s developers")
+set(COPYRIGHT_HOLDERS_FINAL "The ${PROJECT_NAME} developers")
+set(PACKAGE_BUGREPORT "https://github.com/bitcoin/bitcoin/issues")
+
+list(APPEND CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake/module)
+
+# Configurable options.
+# When adding a new option, end the <help_text> with a full stop for consistency.
+include(CMakeDependentOption)
+option(BUILD_DAEMON "Build bitcoind executable." ON)
+option(ASM "Use assembly routines." ON)
+cmake_dependent_option(CXX20 "Enable compilation in C++20 mode." OFF "NOT MSVC" ON)
+
+if(CXX20)
+  set(CMAKE_CXX_STANDARD 20)
+else()
+  set(CMAKE_CXX_STANDARD 17)
+endif()
+set(CMAKE_CXX_STANDARD_REQUIRED ON)
+set(CMAKE_CXX_EXTENSIONS OFF)
+
+set(configure_warnings)
+if(CMAKE_VERSION VERSION_GREATER_EQUAL 3.14)
+  include(CheckPIESupported)
+  check_pie_supported(OUTPUT_VARIABLE check_pie_output LANGUAGES CXX)
+  if(NOT CMAKE_CXX_LINK_PIE_SUPPORTED)
+    list(APPEND configure_warnings "PIE link options are not supported for executable targets: ${check_pie_output}.")
+  endif()
+else()
+  list(APPEND configure_warnings "No PIE options will be passed to a linker for executable targets.")
+endif()
+set(CMAKE_POSITION_INDEPENDENT_CODE ON)
+
+include(CheckSourceCompilesAndLinks)
+include(cmake/introspection.cmake)
+
+if(WIN32)
+  add_compile_definitions(_WIN32_WINNT=0x0601 _WIN32_IE=0x0501 WIN32_LEAN_AND_MEAN)
+endif()
+
+if(MSVC)
+  set(CMAKE_MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>")
+  add_compile_definitions(NOMINMAX _CRT_SECURE_NO_WARNINGS)
+  add_compile_options(/utf-8 /Zc:__cplusplus)
+  add_link_options($<$<CONFIG:Release>:/NODEFAULTLIB:LIBCMTD>)
+endif()
+
+if(MINGW)
+  add_compile_definitions(_MT WIN32 _WINDOWS)
+  add_link_options(-static)
+  # We require Windows 7 (NT 6.1) or later.
+  add_link_options(-Wl,--major-subsystem-version,6 -Wl,--minor-subsystem-version,1)
+endif()
+
+if(APPLE)
+  add_compile_definitions(MAC_OSX)
+endif()
+
+include(cmake/crc32c.cmake)
+include(cmake/leveldb.cmake)
+include(cmake/minisketch.cmake)
+include(cmake/secp256k1.cmake)
+
+include(CheckStdFilesystem)
+check_std_filesystem()
+
+if(CMAKE_CROSSCOMPILING AND DEPENDS_ALLOW_HOST_PACKAGES)
+  list(APPEND CMAKE_FIND_ROOT_PATH "${CMAKE_SYSTEM_PREFIX_PATH}")
+endif()
+
+if(BUILD_DAEMON)
+  set(THREADS_PREFER_PTHREAD_FLAG ON)
+  find_package(Threads REQUIRED)
+  if(NOT MINGW AND NOT CMAKE_SYSTEM_NAME STREQUAL "FreeBSD")
+    target_compile_definitions(Threads::Threads INTERFACE
+      $<$<COMPILE_FEATURES:cxx_thread_local>:HAVE_THREAD_LOCAL>
+    )
+  endif()
+
+  if(APPLE AND BREW_COMMAND)
+    execute_process(
+      COMMAND ${BREW_COMMAND} --prefix boost
+      OUTPUT_VARIABLE BOOST_ROOT
+      ERROR_QUIET
+      OUTPUT_STRIP_TRAILING_WHITESPACE
+    )
+  endif()
+  set(Boost_NO_BOOST_CMAKE ON)
+  # Find Boost headers only.
+  find_package(Boost 1.64.0 REQUIRED)
+  mark_as_advanced(Boost_INCLUDE_DIR)
+  target_compile_definitions(Boost::boost INTERFACE
+    $<$<CONFIG:Debug>:BOOST_MULTI_INDEX_ENABLE_SAFE_MODE>
+  )
+  if(CMAKE_VERSION VERSION_LESS 3.15)
+    add_library(Boost::headers ALIAS Boost::boost)
+  endif()
+endif()
+
+include(CrossPkgConfig)
+if(BUILD_DAEMON)
+  cross_pkg_check_modules(libevent REQUIRED libevent>=2.1.8 IMPORTED_TARGET)
+  target_link_libraries(PkgConfig::libevent INTERFACE
+    $<$<PLATFORM_ID:Windows>:iphlpapi;ws2_32>
+  )
+endif()
+
+if(NOT WIN32 AND BUILD_DAEMON)
+  cross_pkg_check_modules(libevent_pthreads REQUIRED libevent_pthreads>=2.1.8 IMPORTED_TARGET)
+endif()
+
+add_subdirectory(src)
+
+message("\n")
+message("Configure summary")
+message("=================")
+message("Executables:")
+message("  bitcoind ............................ ${BUILD_DAEMON}")
+message("")
+if(CMAKE_CROSSCOMPILING)
+  set(cross_status "TRUE, for ${CMAKE_SYSTEM_NAME}, ${CMAKE_SYSTEM_PROCESSOR}")
+else()
+  set(cross_status "FALSE")
+endif()
+message("Cross compiling ....................... ${cross_status}")
+get_directory_property(definitions COMPILE_DEFINITIONS)
+string(REPLACE ";" " " definitions "${definitions}")
+message("Preprocessor defined macros ........... ${definitions}")
+message("C compiler ............................ ${CMAKE_C_COMPILER}")
+message("CFLAGS ................................ ${CMAKE_C_FLAGS}")
+message("C++ compiler .......................... ${CMAKE_CXX_COMPILER}")
+message("CXXFLAGS .............................. ${CMAKE_CXX_FLAGS}")
+get_directory_property(common_compile_options COMPILE_OPTIONS)
+string(REPLACE ";" " " common_compile_options "${common_compile_options}")
+message("Common compile options ................ ${common_compile_options}")
+get_directory_property(common_link_options LINK_OPTIONS)
+string(REPLACE ";" " " common_link_options "${common_link_options}")
+message("Common link options ................... ${common_link_options}")
+if(DEFINED CMAKE_BUILD_TYPE)
+  message("Build type:")
+  message(" - CMAKE_BUILD_TYPE ................... ${CMAKE_BUILD_TYPE}")
+  string(TOUPPER "${CMAKE_BUILD_TYPE}" build_type)
+  message(" - CFLAGS ............................. ${CMAKE_C_FLAGS_${build_type}}")
+  message(" - CXXFLAGS ........................... ${CMAKE_CXX_FLAGS_${build_type}}")
+  message(" - LDFLAGS for executables ............ ${CMAKE_EXE_LINKER_FLAGS_${build_type}}")
+  message(" - LDFLAGS for shared libraries ....... ${CMAKE_SHARED_LINKER_FLAGS_${build_type}}")
+else()
+  message("Available configurations .............. ${CMAKE_CONFIGURATION_TYPES}")
+  message("Debug configuration:")
+  message(" - CFLAGS ............................. ${CMAKE_C_FLAGS_DEBUG}")
+  message(" - CXXFLAGS ........................... ${CMAKE_CXX_FLAGS_DEBUG}")
+  message(" - LDFLAGS for executables ............ ${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
+  message(" - LDFLAGS for shared libraries ....... ${CMAKE_SHARED_LINKER_FLAGS_DEBUG}")
+  message("Release configuration:")
+  message(" - CFLAGS ............................. ${CMAKE_C_FLAGS_RELEASE}")
+  message(" - CXXFLAGS ........................... ${CMAKE_CXX_FLAGS_RELEASE}")
+  message(" - LDFLAGS for executables ............ ${CMAKE_EXE_LINKER_FLAGS_RELEASE}")
+  message(" - LDFLAGS for shared libraries ....... ${CMAKE_SHARED_LINKER_FLAGS_RELEASE}")
+endif()
+message("Use assembly routines ................. ${ASM}")
+message("\n")
+if(configure_warnings)
+    message("  ******\n")
+    foreach(warning IN LISTS configure_warnings)
+      message(WARNING "${warning}")
+    endforeach()
+    message("  ******\n")
+endif()

cmake/bitcoin-config.h.in

@@ -0,0 +1,193 @@
+// Copyright (c) 2023 The Bitcoin Core developers
+// Distributed under the MIT software license, see the accompanying
+// file COPYING or http://www.opensource.org/licenses/mit-license.php.
+
+#ifndef BITCOIN_CONFIG_H
+
+#define BITCOIN_CONFIG_H
+
+/* Define this symbol if type char equals int8_t */
+#cmakedefine CHAR_EQUALS_INT8 1
+
+/* Version Build */
+#define CLIENT_VERSION_BUILD @PROJECT_VERSION_PATCH@
+
+/* Version is release */
+#define CLIENT_VERSION_IS_RELEASE @CLIENT_VERSION_IS_RELEASE@
+
+/* Major version */
+#define CLIENT_VERSION_MAJOR @PROJECT_VERSION_MAJOR@
+
+/* Minor version */
+#define CLIENT_VERSION_MINOR @PROJECT_VERSION_MINOR@
+
+/* Copyright holder(s) before %s replacement */
+#define COPYRIGHT_HOLDERS "@COPYRIGHT_HOLDERS@"
+
+/* Copyright holder(s) */
+#define COPYRIGHT_HOLDERS_FINAL "@COPYRIGHT_HOLDERS_FINAL@"
+
+/* Replacement for %s in copyright holders string */
+#define COPYRIGHT_HOLDERS_SUBSTITUTION "@PROJECT_NAME@"
+
+/* Copyright year */
+#define COPYRIGHT_YEAR @COPYRIGHT_YEAR@
+
+/* Define this symbol if you have __builtin_clzl */
+#cmakedefine HAVE_BUILTIN_CLZL 1
+
+/* Define this symbol if you have __builtin_clzll */
+#cmakedefine HAVE_BUILTIN_CLZLL 1
+
+/* Define to 1 if you have the <byteswap.h> header file. */
+#cmakedefine HAVE_BYTESWAP_H 1
+
+/* Define to 1 if you have the declaration of `be16toh', and to 0 if you
+   don't. */
+#cmakedefine01 HAVE_DECL_BE16TOH
+
+/* Define to 1 if you have the declaration of `be32toh', and to 0 if you
+   don't. */
+#cmakedefine01 HAVE_DECL_BE32TOH
+
+/* Define to 1 if you have the declaration of `be64toh', and to 0 if you
+   don't. */
+#cmakedefine01 HAVE_DECL_BE64TOH
+
+/* Define to 1 if you have the declaration of `bswap_16', and to 0 if you
+   don't. */
+#cmakedefine01 HAVE_DECL_BSWAP_16
+
+/* Define to 1 if you have the declaration of `bswap_32', and to 0 if you
+   don't. */
+#cmakedefine01 HAVE_DECL_BSWAP_32
+
+/* Define to 1 if you have the declaration of `bswap_64', and to 0 if you
+   don't. */
+#cmakedefine01 HAVE_DECL_BSWAP_64
+
+/* Define to 1 if you have the declaration of `fork', and to 0 if you don't.
+   */
+#cmakedefine01 HAVE_DECL_FORK
+
+/* Define to 1 if you have the declaration of `freeifaddrs', and to 0 if you
+   don't. */
+#cmakedefine01 HAVE_DECL_FREEIFADDRS
+
+/* Define to 1 if you have the declaration of `getifaddrs', and to 0 if you
+   don't. */
+#cmakedefine01 HAVE_DECL_GETIFADDRS
+
+/* Define to 1 if you have the declaration of `htobe16', and to 0 if you
+   don't. */
+#cmakedefine01 HAVE_DECL_HTOBE16
+
+/* Define to 1 if you have the declaration of `htobe32', and to 0 if you
+   don't. */
+#cmakedefine01 HAVE_DECL_HTOBE32
+
+/* Define to 1 if you have the declaration of `htobe64', and to 0 if you
+   don't. */
+#cmakedefine01 HAVE_DECL_HTOBE64
+
+/* Define to 1 if you have the declaration of `htole16', and to 0 if you
+   don't. */
+#cmakedefine01 HAVE_DECL_HTOLE16
+
+/* Define to 1 if you have the declaration of `htole32', and to 0 if you
+   don't. */
+#cmakedefine01 HAVE_DECL_HTOLE32
+
+/* Define to 1 if you have the declaration of `htole64', and to 0 if you
+   don't. */
+#cmakedefine01 HAVE_DECL_HTOLE64
+
+/* Define to 1 if you have the declaration of `le16toh', and to 0 if you
+   don't. */
+#cmakedefine01 HAVE_DECL_LE16TOH
+
+/* Define to 1 if you have the declaration of `le32toh', and to 0 if you
+   don't. */
+#cmakedefine01 HAVE_DECL_LE32TOH
+
+/* Define to 1 if you have the declaration of `le64toh', and to 0 if you
+   don't. */
+#cmakedefine01 HAVE_DECL_LE64TOH
+
+/* Define to 1 if you have the declaration of `pipe2', and to 0 if you don't.
+   */
+#cmakedefine01 HAVE_DECL_PIPE2
+
+/* Define to 1 if you have the declaration of `setsid', and to 0 if you don't.
+   */
+#cmakedefine01 HAVE_DECL_SETSID
+
+/* Define if the visibility attribute is supported. */
+#cmakedefine HAVE_DEFAULT_VISIBILITY_ATTRIBUTE 1
+
+/* Define if the dllexport attribute is supported. */
+#cmakedefine HAVE_DLLEXPORT_ATTRIBUTE 1
+
+/* Define to 1 if you have the <endian.h> header file. */
+#cmakedefine HAVE_ENDIAN_H 1
+
+/* Define to 1 if fdatasync is available. */
+#cmakedefine HAVE_FDATASYNC 1
+
+/* Define this symbol if the BSD getentropy system call is available with
+   sys/random.h */
+#cmakedefine HAVE_GETENTROPY_RAND 1
+
+/* Define this symbol if gmtime_r is available */
+#cmakedefine HAVE_GMTIME_R 1
+
+/* Define this symbol if you have malloc_info */
+#cmakedefine HAVE_MALLOC_INFO 1
+
+/* Define this symbol if you have mallopt with M_ARENA_MAX */
+#cmakedefine HAVE_MALLOPT_ARENA_MAX 1
+
+/* Define to 1 if O_CLOEXEC flag is available. */
+#cmakedefine01 HAVE_O_CLOEXEC
+
+/* Define this symbol to build code that uses getauxval) */
+#cmakedefine HAVE_STRONG_GETAUXVAL 1
+
+/* Define to 1 if std::system or ::wsystem is available. */
+#cmakedefine HAVE_SYSTEM 1
+
+/* Define to 1 if you have the <sys/endian.h> header file. */
+#cmakedefine HAVE_SYS_ENDIAN_H 1
+
+/* Define to 1 if you have the <sys/prctl.h> header file. */
+#cmakedefine HAVE_SYS_PRCTL_H 1
+
+/* Define to 1 if you have the <sys/resources.h> header file. */
+#cmakedefine HAVE_SYS_RESOURCES_H 1
+
+/* Define to 1 if you have the <sys/vmmeter.h> header file. */
+#cmakedefine HAVE_SYS_VMMETER_H 1
+
+/* Define to 1 if you have the <vm/vm_param.h> header file. */
+#cmakedefine HAVE_VM_VM_PARAM_H 1
+
+/* Define to the address where bug reports for this package should be sent. */
+#define PACKAGE_BUGREPORT "@PACKAGE_BUGREPORT@"
+
+/* Define to the full name of this package. */
+#define PACKAGE_NAME "@PROJECT_NAME@"
+
+/* Define to the home page for this package. */
+#define PACKAGE_URL "@PROJECT_HOMEPAGE_URL@"
+
+/* Define to the version of this package. */
+#define PACKAGE_VERSION "@PROJECT_VERSION@"
+
+/* Define to 1 if strerror_r returns char *. */
+#cmakedefine STRERROR_R_CHAR_P 1
+
+/* Define WORDS_BIGENDIAN to 1 if your processor stores words with the most
+   significant byte first (like Motorola and SPARC, unlike Intel). */
+#cmakedefine WORDS_BIGENDIAN 1
+
+#endif //BITCOIN_CONFIG_H