Remove old .jars in lib folder when installing new version

[willfurnell]

I'm submitting a…

• bug report
• feature request
• other

Short description of the issue/suggestion:
This may be more of a Inno Setup rather than a JavaPackager question - so I apologise if this is the case.
However, I've now released a few versions of https://github.com/stfc/CertWizard. This uses a number of libraries, and when installing on Windows, these are put in C:\Program Files\CertWizard\libs\. Over time, this has built up a large number of no longer needed dependencies. Is it possible to remove these on installing a new version please?

Do you have outputs, screenshots, demos or samples which demonstrate the problem or enhancement?

What is the motivation / use case for changing the behavior?
Old libs are no longer needed - and could have security flaws - so we should remove these from the users system as we are no longer using them.

Please tell us about your environment:

• JavaPackager version: 1.6.2
• OS version: Windows 10
• JDK version: 11
• Build tool:
  • Maven
  • Gradle

Other information (e.g. related issues, suggestions how to fix, links for us to have context)

[fvarrui]

Hi @willfurnell!
So, let's see if I understand correctly, the problem is that when installing a new version of your app for Windows with the Inno Setup generated installer, which includes different dependencies, the previous (not necessary) ones are not removed?

[willfurnell]

That is correct yes!

[fvarrui]

Ok, a possible solution would be to run an Inno Setup Pascal script that removes the installed version, if exists, before installing the new one, because I haven't found any option in the IS setup to do that.

I you want this feature right now, without waiting for a new version of the plugin to be released, do the following:

• Create the file ${project.basedir}\assets\windows\iss.vtl with the next content in your project:

\#define MyAppName "${info.name}"
\#define MyAppVersion "${info.version}"
\#define MyAppPublisher "${info.organizationName}"
\#define MyAppURL "$!{info.organizationUrl}"
\#define MyAppExeName "${info.executable.name}"
\#define MyAppFolder "${info.name}"
\#define MyAppLicense "$!{info.licenseFile.absolutePath}"
\#define MyAppIcon "${info.iconFile.absolutePath}"

[Setup]
AppId={#MyAppName}
AppName={#MyAppName}
AppVersion={#MyAppVersion}
AppVerName={#MyAppName} {#MyAppVersion}
AppPublisher={#MyAppPublisher}
AppPublisherURL={#MyAppURL}
AppSupportURL={#MyAppURL}
AppUpdatesURL={#MyAppURL}
DefaultDirName={autopf}\{#MyAppFolder}
#if ($info.winConfig.disableDirPage)
DisableDirPage=yes
#else
DisableDirPage=no
#end
#if ($info.winConfig.disableProgramGroupPage)
DisableProgramGroupPage=yes
#else
DefaultGroupName={#MyAppName}
DisableProgramGroupPage=no
#end
#if ($info.winConfig.disableFinishedPage)
DisableFinishedPage=yes
#else
DisableFinishedPage=no
#end
#if ($info.winConfig.disableWelcomePage)
DisableWelcomePage=yes
#else
DisableWelcomePage=no
#end
#if ($info.winConfig.setupMode.name() == "installForAllUsers") 
PrivilegesRequired=admin
PrivilegesRequiredOverridesAllowed=commandline
#elseif ($info.winConfig.setupMode.name() == "installForCurrentUser") 
PrivilegesRequired=lowest
PrivilegesRequiredOverridesAllowed=commandline
#else 
PrivilegesRequiredOverridesAllowed=commandline dialog
#end
LicenseFile={#MyAppLicense}
SetupIconFile={#MyAppIcon}
UninstallDisplayIcon={app}\{#MyAppExeName}
Compression=lzma
SolidCompression=yes
ArchitecturesInstallIn64BitMode=x64

[Languages]
#foreach ($language in $info.winConfig.setupLanguages.entrySet())
Name: "${language.key}"; MessagesFile: "${language.value}"
#end

[Tasks]
#if ($info.winConfig.createDesktopIconTask)
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked
#end

[Registry]
#if ($info.winConfig.registry)
#foreach ($entry in $info.winConfig.registry.entries)
Root: ${entry.root}; Subkey: "${entry.subkey}"; ValueType: ${entry.valueTypeAsInnoSetupString}; ValueName: "${entry.valueName}"; ValueData: "${entry.valueData}"; Flags: uninsdeletevalue
#end
#end
#foreach ($fileAssociation in $info.fileAssociations)
; ${fileAssociation.extension} extension file association
Root: HKA; Subkey: "Software\Classes\.${fileAssociation.extension}\OpenWithProgids"; ValueType: string; ValueName: "${info.name}.${fileAssociation.extension}"; ValueData: ""; Flags: uninsdeletevalue
Root: HKA; Subkey: "Software\Classes\\${info.name}.${fileAssociation.extension}"; ValueType: string; ValueName: ""; ValueData: "${fileAssociation.description}"; Flags: uninsdeletekey
Root: HKA; Subkey: "Software\Classes\\${info.name}.${fileAssociation.extension}\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\\${info.executable.name},0"; Flags: uninsdeletevalue
Root: HKA; Subkey: "Software\Classes\\${info.name}.${fileAssociation.extension}\shell\open\command"; ValueType: string; ValueName: ""; ValueData: """{app}\\${info.executable.name}"" ""%1"""; Flags: uninsdeletevalue
Root: HKA; Subkey: "Software\Classes\Applications\\${info.executable.name}\SupportedTypes"; ValueType: string; ValueName: ".${fileAssociation.extension}"; ValueData: ""; Flags: uninsdeletevalue
#end

[Files]
Source: "${info.appFolder}\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs

[Icons]
Name: "{autoprograms}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"; IconFilename: "{app}\\${info.iconFile.name}"
#if ($info.winConfig.createDesktopIconTask)
Name: "{autodesktop}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"; IconFilename: "{app}\\${info.iconFile.name}"; Tasks: desktopicon
#end

[Run]
#if (!$info.winConfig.disableRunAfterInstall)
Filename: "{app}\{#MyAppExeName}"; Description: "{cm:LaunchProgram,{#StringChange(MyAppName, '&', '&&')}}"; Flags: nowait postinstall skipifsilent runascurrentuser
#end

[Code]

function GetUninstallString(): String;
var
    sUnInstPath: String;
    sUnInstallString: String;
begin
    sUnInstPath := ExpandConstant('Software\Microsoft\Windows\CurrentVersion\Uninstall\{#emit SetupSetting("AppId")}_is1');
    sUnInstallString := '';
    if not RegQueryStringValue(HKLM, sUnInstPath, 'UninstallString', sUnInstallString) then
        RegQueryStringValue(HKCU, sUnInstPath, 'UninstallString', sUnInstallString);
    Result := RemoveQuotes(sUnInstallString);
end;

function IsUpgrade(): Boolean;
begin
    Result := (GetUninstallString() <> '');
end;

procedure UnInstallOldVersion();
var
    sUnInstallString: String;
    iResultCode: Integer;
begin
    sUnInstallString := GetUninstallString();
    if sUnInstallString <> '' then 
    begin
        Exec(sUnInstallString, '/SILENT /NORESTART /SUPPRESSMSGBOXES','', SW_HIDE, ewWaitUntilTerminated, iResultCode);
    end;
end;

procedure CurStepChanged(CurStep: TSetupStep);
begin
    if (CurStep=ssInstall) And (IsUpgrade()) then
    begin
        UnInstallOldVersion();
    end;
end;

This way you are overiding the default VTL template used to generate ISS file (needed for Inno Setup compiler), with this one, which now includes the [Code] section with a small Pascal script that uninstall the current one.

It worked fine for me. I hope it helps!

Thanks for your comments!

[fvarrui]

Sorry! I've realized that this solution might fail, as the uninstallation and installation start at the same time (even though I specify in the script to wait for the uninstallation process to finish - ewWaitUntilTerminated), which may end up leaving a corrupt installation. The problem here is that it waits for the uninst???.exe process to finish; but this process launches another process and the first one finishes, in order to be removed (uninstalled) ... the right thing would be that the script wait for this "copy" to finish. I'll have to do some more research about this.

[fvarrui]

Another possible solution could be to make a Pascal script which do the following:

1. Gets installation folder from Windows Registry key value (Software\Microsoft\Windows\CurrentVersion\Uninstall\{AppId}_is1\InstallLocation).
2. Removes only the libs folder (instead of runs "uninst???.exe").
3. Begins the installation.

This is the Pascal script code:

[Code]

function GetInstallLocation(): String;
var
    unInstPath: String;
    installLocation: String;
begin
    unInstPath := ExpandConstant('Software\Microsoft\Windows\CurrentVersion\Uninstall\{#emit SetupSetting("AppId")}_is1');
    installLocation := '';
    if not RegQueryStringValue(HKLM, unInstPath, 'InstallLocation', installLocation) then
        RegQueryStringValue(HKCU, unInstPath, 'InstallLocation', installLocation);
    Result := RemoveQuotes(installLocation);
end;

procedure RemoveOldLibs();
var
    installLocation: String;
    libsLocation: String;
begin
    installLocation := GetInstallLocation();
    if installLocation <> '' then 
    begin
        libsLocation := installLocation + 'libs';
        DelTree(libsLocation, True, True, True);
    end;
end;

procedure CurStepChanged(CurStep: TSetupStep);
begin
    if CurStep = ssInstall then
    begin
        RemoveOldLibs();
    end;
end;

[fvarrui]

I've tested and it seems to be working fine.

[willfurnell]

Thank you, I've tested this on my system and it also seems to work - but I'm going to do some more thorough testing to make sure everything is OK before packaging it up in a release. I'm also going to look at fully uninstalling the previous version to see what works best, Thanks!

[fvarrui]

Hi @willfurnell!
This new feature is already available in issue-137 branch (v1.6.3-SNAPSHOT). There's a new boolean property: winConfig.removeOldLibs. If true, old libs folder will be removed before installing a new version. In order to keep the old behavior, by default it's false.

[fvarrui]

SNAPSHOT versions has to be installed manually on your system. You can find further instructions on README.

[fvarrui]

I'm also going to look at fully uninstalling the previous version to see what works best, Thanks!

I think that uninstalling the entire app should be optional, since it's possible that some apps generate config files or other artifacts in the installation directory, and they should not be removed.

But if you consider it necessary, we can add another option which do the next:

[...]

procedure RemoveOldInstallation();
var
    installLocation: String;
begin
    installLocation := GetInstallLocation();
    if installLocation <> '' then 
    begin
        DelTree(installLocation , True, True, True);
    end;
end;

procedure CurStepChanged(CurStep: TSetupStep);
begin
    if CurStep = ssInstall then
    begin
        RemoveOldInstallation();
    end;
end;

I've not tested yet.

[willfurnell]

Oh indeed I agree it should be optional. I meant running the uninstaller rather than deleting the directory (as you do above running uninstXXX.exe) - as I wonder if that's 'cleaner' in a sense? I worry that someone will install it somewhere weird and then this may end up deleting more than they bargained for - even with just the lib directory!

[fvarrui]

The casuistry is extensive. For now, I think your problem would be solved 😃

[willfurnell]

Thank you! I think this works fine but I'm just going to test a bit more on my side to make sure,
Thank you again for implementing this,
Will.

[fvarrui]

Branch issue-137 merged into devel