Skip to content
/ Arduino-IRremote Public
forked from Arduino-IRremote/Arduino-IRremote

Infrared remote library for Arduino: send and receive infrared signals with multiple protocols

License

View license
0 stars 1.8k forks Branches Tags Activity
Star
Notifications You must be signed in to change notification settings

jorgnyg/Arduino-IRremote

BranchesTags
 
 

Repository files navigation

IRremote Arduino Library

Available as Arduino library "IRremote"

Version 3.6.0 - work in progress

License: MIT Commits since latest Installation instructions LibraryBuild

This library enables you to send and receive using infra-red signals on an Arduino.

Table of content

API

A Doxygen documentation of the sources is available on the project homepage.

Installation

Click on the LibraryManager badge above to see the instructions.

Supported IR Protocols

Denon / Sharp, JVC, LG, NEC / Onkyo / Apple, Panasonic / Kaseikyo, RC5, RC6, Samsung, Sony, (Pronto), BoseWave, Lego, Whynter and optional MagiQuest.
Protocols can be switched off and on by defining macros before the line #include <IRremote.hpp> like here:

#define DECODE_NEC
//#define DECODE_DENON
#include <IRremote.hpp>

Old Wiki

This is a quite old but maybe useful wiki for this library.

Features of the 3.x version

  • You can use any pin for sending now, like you are used with receiving.
  • Simultaneous sending and receiving. See the SendAndReceive example.
  • No more need to use 32 bit hex values in your code. Instead a (8 bit) command value is provided for decoding (as well as an 16 bit address and a protocol number).
  • Protocol values comply to protocol standards, i.e. NEC, Panasonic, Sony, Samsung and JVC decode and send LSB first.
  • Supports more protocols, since adding a protocol is quite easy now.
  • Better documentation and more examples :-).
  • Compatible with tone() library, see ReceiveDemo.
  • Supports more platforms, since the new structure allows to easily add a new platform.
  • Feedback LED also for sending.
  • Ability to generate a non PWM signal to just simulate an active low receiver signal for direct connect to existent receiving devices without using IR.
  • Easy configuration of protocols required, directly in your source code. This reduces the memory footprint and increases decoding time.

Converting your 2.x program to the 3.x version

Starting with the 3.1 version, the generation of PWM for sending is done by software, thus saving the hardware timer and enabling arbitrary output pins for sending.
If you use an (old) Arduino core that does not use the -flto flag for compile, you can activate the line #define SUPPRESS_ERROR_MESSAGE_FOR_BEGIN in IRRemote.h, if you get false error messages regarding begin() during compilation.

  • Now there is an IRreceiver and IRsender object like the well known Arduino Serial object.
  • Just remove the line IRrecv IrReceiver(IR_RECEIVE_PIN); and/or IRsend IrSender; in your program, and replace all occurrences of IRrecv. or irrecv. with IrReceiver and replace all IRsend or irsend with IrSender.
  • Since the decoded values are now in IrReceiver.decodedIRData and not in results any more, remove the line decode_results results or similar.
  • Like for the Serial object, call IrReceiver.begin(IR_RECEIVE_PIN, ENABLE_LED_FEEDBACK); or IrReceiver.begin(IR_RECEIVE_PIN, DISABLE_LED_FEEDBACK); instead of the IrReceiver.enableIRIn(); or irrecv.enableIRIn(); in setup(). For sending, call IrSender.begin(IR_SEND_PIN, ENABLE_LED_FEEDBACK); or IrSender.begin(IR_SEND_PIN, DISABLE_LED_FEEDBACK); in setup().
  • Old decode(decode_results *aResults) function is replaced by simple decode(). So if you have a statement if(irrecv.decode(&results)) replace it with if (IrReceiver.decode()).
  • The decoded result is now in in IrReceiver.decodedIRData and not in results any more, therefore replace any occurrences of results.value and results.decode_type (and similar) to IrReceiver.decodedIRData.decodedRawData and IrReceiver.decodedIRData.protocol.
  • Overflow, Repeat and other flags are now in IrReceiver.receivedIRData.flags.
  • Seldom used: results.rawbuf and results.rawlen must be replaced by IrReceiver.decodedIRData.rawDataPtr->rawbuf and IrReceiver.decodedIRData.rawDataPtr->rawlen.

Example

2.x program:

#include <IRremote.h>

IRrecv irrecv(RECV_PIN);
decode_results results;

void setup()
{
...
  irrecv.enableIRIn(); // Start the receiver
}

void loop() {
  if (irrecv.decode(&results)) {
      Serial.println(results.value, HEX);
      ...
      irrecv.resume(); // Receive the next value
  }
  ...
}

3.x program:

#include <IRremote.hpp>

void setup()
{
...
  IrReceiver.begin(IR_RECEIVE_PIN, ENABLE_LED_FEEDBACK); // Start the receiver
}

void loop() {
  if (IrReceiver.decode()) {
      Serial.println(IrReceiver.decodedIRData.decodedRawData, HEX);
      IrReceiver.printIRResultShort(&Serial); // optional use new print version
      ...
      IrReceiver.resume(); // Enable receiving of the next value
  }
  ...
}

Do not want to convert your 2.x program and use the 3.x library version?

First consider to just use the original 2.4 release form 2017 or the last backwards compatible 2.8 version for you project. It may be sufficient and deals flawlessly with 32 bit IR codes.
If not, the 3.x versions try to be backwards compatible, so you can easily run your old examples. But some functions like e.g. sendNEC() -see below- could not made backwards compatible. The (old and deprecated) call of irrecv.decode(&results) uses the old MSB first decoders like in 2.x and sets the 32 bit codes in results.value!
But only the following decoders are available then: Denon, JVC, LG, NEC, Panasonic, RC5, RC6, Samsung, Sony.

The old functions sendNEC() and sendJVC() are deprecated and renamed to sendNECMSB() and sendJVCMSB(), to make it clearer that they send data with MSB first, which is not the standard for NEC and JVC. Use them to send your old MSB-first 32 bit IR data codes. In the new version you will send NEC (and other) commands not by 32 bit codes but by a (constant) 8 bit address and an 8 bit command.

How to convert old MSB first 32 bit IR data codes to new LSB first 32 bit IR data codes

For the new decoders for NEC, Panasonic, Sony, Samsung and JVC, the result IrReceiver.decodedIRData.decodedRawData is now LSB-first, as the definition of these protocols suggests!
To convert one into the other, you must reverse the byte/nibble positions and then reverse all bit positions of each byte/nibble or write it as one binary string and reverse/mirror it.

Example:

  • 0xCB340102 byte reverse -> 02 01 34 CB. Bit reverse of byte -> 40 80 2C D3.
  • 0xCB340102 nibble reverse -> 201043BC. Bit reverse of nibble -> 40802CD3.
    Nibble reverse map: | 1->8 | 2->4 | 3->C | 4->2 | 5->A | 6->6 | 7->E | 8->1 | 9->9 | A->5 | B->D | C->3 | D->B | E->7 | F->F |
  • 0xCB340102 is binary 11001011001101000000000100000010.
    0x40802CD3 is binary 01000000100000000010110011010011.
    If you read the first binary sequence backwards (right to left), you get the second sequence.

Using the new *.hpp files / how to avoid multiple definitions linker errors

In order to support compile options more easily, the line #include <IRremote.h> must be changed to #include <IRremote.hpp>, but only in your main program (.ino file), like it is done in the examples.
In all other files you must use #include <IRremoteInt.h>, otherwise you will get tons of "multiple definition" errors. Be careful to define these 3 macros RAW_BUFFER_LENGTH and IR_SEND_PIN and SEND_PWM_BY_TIMER in IRremoteInt.h consistent with the definitions in the .ino file!

Receiving IR codes

Check for available data can be done by if (IrReceiver.decode()) {. This also decodes the received data. After successful decoding, the IR data is contained in the IRData structure, available as IrReceiver.decodedIRData.

struct IRData {
    decode_type_t protocol;  // UNKNOWN, NEC, SONY, RC5, ...
    uint16_t address;        // Decoded address
    uint16_t command;        // Decoded command
    uint16_t extra;          // Used by MagiQuest and for Kaseikyo unknown vendor ID.  Ticks used for decoding Distance protocol.
    uint16_t numberOfBits;   // Number of bits received for data (address + command + parity) - to determine protocol length if different length are possible.
    uint8_t flags;               // See IRDATA_FLAGS_* definitions above
    uint32_t decodedRawData;     // Up to 32 bit decoded raw data, used for sendRaw functions.
    irparams_struct *rawDataPtr; // Pointer of the raw timing data to be decoded. Mainly the data buffer filled by receiving ISR.
};

To access e.g. the RAW data, use uint32_t myRawdata= IrReceiver.decodedIRData.decodedRawData;.
The content of the IrReceiver.decodedIRData.flags is described here.
To print all fields, use IrReceiver.printIRResultShort(&Serial);.
To print the raw timing data received, use IrReceiver.printIRResultRawFormatted(&Serial, true);.

Minimal NEC receiver

For applications only requiring NEC protocol, there is a receiver which has very small code size of 500 bytes and does NOT require any timer. See the MinimalReceiver and IRDispatcherDemo example how to use it.

Sending IR codes

Please do not use the old send*Raw() functions for sending like e.g. IrSender.sendNECRaw(0xE61957A8,2), even if this functions are used in a lot of (old) tutorials. They are only kept for backward compatibility and unsupported and error prone.
Much better is to use the new structured functions with address and command parameters like e.g. IrSender.sendNEC(0xA8, 0x19, 2). Especially if you are able to receive these remote codes and get the address and command values. You will discover that the address is a constant and the commands sometimes are sensibly grouped.

List of public IR code databases

http://www.harctoolbox.org/IR-resources.html

FAQ and hints

  • IR does not work right when I use Neopixels (aka WS2811/WS2812/WS2812B) or other libraries blocking interrupts for a longer time (> 50 µs).
    Whether you use the Adafruit Neopixel lib, or FastLED, interrupts get disabled on many lower end CPUs like the basic Arduinos for longer than 50 µs. In turn, this stops the IR interrupt handler from running when it needs to.
    You can try to wait for the IR receiver to be idle before you send the Neopixel data with if (IrReceiver.isIdle()) { strip.show();}. This prevents at least breaking a running IR transmission and -depending of the update rate of the Neopixel- may work quite well.
    There are some other solutions to this on more powerful processors, see this page from Marc MERLIN
  • Another library is only working if I deactivate the line IrReceiver.begin(IR_RECEIVE_PIN, ENABLE_LED_FEEDBACK);. Please see below.
  • You can use multiple IR receiver by just connecting the output pins of several IR receivers together. The IR receivers use an NPN transistor as output device with just a 30k resistor to VCC. This is almost "open collector" and allows connecting of several output pins to one Arduino input pin.
  • The minimal CPU frequency for receiving is 4 MHz, since the 50 µs timer ISR takes around 12 µs on a 16 MHz ATmega.
  • To increase strength of sent output signal you can increase the current through the send diode, and/or use 2 diodes in series, since one IR diode requires only 1.5 volt.
  • The line #include "ATtinySerialOut.h" in PinDefinitionsAndMore.h (requires the library to be installed) saves 370 bytes program space and 38 bytes RAM for Digispark boards as well as enables serial output at 8MHz.
  • The default software generated PWM has problems on AVR running with 8 MHz. The PWM frequency is around 30 instead of 38 kHz and RC6 is not reliable. You can switch to timer PWM generation by #define SEND_PWM_BY_TIMER.

Handling unknown Protocols

Disclaimer

This library was never designed to handle long codes like the ones used by air conditioners.
For air condioners see this fork which supports an impressive set of protocols and a lot of air conditioners and the blog entry: "Recording long Infrared Remote control signals with Arduino".
The main reason is, that it was designed to fit inside MCUs with relatively low levels of resources and was intended to work as a library together with other applications which also require some resources of the MCU to operate.

Protocol=PULSE_DISTANCE

If you get something like this: PULSE_DISTANCE: HeaderMarkMicros=8900 HeaderSpaceMicros=4450 MarkMicros=550 OneSpaceMicros=1700 ZeroSpaceMicros=600 NumberOfBits=56 0x43D8613C 0x3BC3BC, then you have a code consisting of 56 bits, which is probably from an air condioner remote. You can send it with calling sendPulseDistanceWidthData() twice, once for the first 32 bit and next for the remaining 24 bits.
The PulseDistance or PulseWidth decoders just decode a timing steam to a bit stream. They can not put any semantics like address, command or checksum on this bitstream, since it is no known protocol. But the bitstram is way more readable, than a timing stream. This bitstram is read LSB first by default. If this does not suit you for further research, you can change it here.

Protocol=UNKNOWN

If you see something like Protocol=UNKNOWN Hash=0x13BD886C 35 bits received as output of e.g. the ReceiveDemo example, you either have a problem with decoding a protocol, or an unsupported protocol.

  • If you have an odd number of bits received, it is likely, that your receiver circuit has problems. Maybe because the IR signal is too weak.
  • If you see timings like + 600,- 600 + 550,- 150 + 200,- 100 + 750,- 550 then one 450 µs space was split into two 150 and 100 µs spaces with a spike / error signal of 200 µs between. Maybe because of a defective receiver or a weak signal in conjunction with another light emitting source nearby.
  • If you see timings like + 500,- 550 + 450,- 550 + 500,- 500 + 500,-1550, then marks are generally shorter than spaces and therefore MARK_EXCESS_MICROS (specified in your ino file) should be negative to compensate for this at decoding.
  • If you see Protocol=UNKNOWN Hash=0x0 1 bits received it may be that the space after the initial mark is longer than RECORD_GAP_MICROS. This was observed for some LG air conditioner protocols. Try again with a line e.g. #define RECORD_GAP_MICROS 12000 before the line #include <IRremote.hpp> in your ino file.
  • To see more info supporting you to find the reason for your UNKNOWN protocol, you must enable the line //#define DEBUG in IRremoteInt.h.

How to deal with protocols not supported by IRremote

If you do not know which protocol your IR transmitter uses, you have several choices.

  • Use the IRreceiveDump example to dump out the IR timing. You can then reproduce/send this timing with the SendRawDemo example. For long codes with more than 48 bits like from air conditioners, you can change the length of the input buffer in IRremote.h.
  • The IRMP AllProtocol example prints the protocol and data for one of the 40 supported protocols. The same library can be used to send this codes.
  • If you have a bigger Arduino board at hand (> 100 kByte program space) you can try the IRremoteDecode example of the Arduino library DecodeIR.
  • Use IrScrutinizer. It can automatically generate a send sketch for your protocol by exporting as "Arduino Raw". It supports IRremote, the old IRLib and Infrared4Arduino.

Examples for this library

In order to fit the examples to the 8K flash of ATtiny85 and ATtiny88, the Arduino library ATtinySerialOut is required for this CPU's.

SimpleReceiver + SimpleSender

This examples are a good starting point.

ReceiveDemo

Receives all protocols and play a beep on each packet received. By connecting pin 5 to ground, you can see the raw values for each packet.

ReceiveDump

Receives all protocols and dumps the received signal in different flavors. Since the printing takes so much time, repeat signals may be skipped or interpreted as UNKNOWN.

SendDemo

Sends all available protocols at least once.

SendAndReceive + UnitTest

ReceiveDemo + SendDemo in one program. Receiving while sending.

ReceiveAndSend

Record and play back last received IR signal at button press.

ReceiveOneAndSendMultiple

Serves as a IR remote macro expander. Receives Samsung32 protocol and on receiving a specified input frame, it sends multiple Samsung32 frames with appropriate delays in between. This serves as a Netflix-key emulation for my old Samsung H5273 TV.

SmallReceiver

If code size matters, look at these example.

MinimalReceiver

The MinimalReceiver example uses the TinyReceiver library which can only receive NEC codes, but does not require any timer.
MinimalReceiver can be tested online with WOKWI. Click on the receiver while simulation is running to specify individual IR codes.

IRDispatcherDemo

Framework for calling different functions of your program for different IR codes.

IRrelay

Control a relay (connected to an output pin) with your remote.

IRremoteExtensionTest

Example for a user defined class, which itself uses the IRrecv class from IRremote.

SendLGAirConditionerDemo

Example for sending LG air conditioner IR codes controlled by Serial input.
By just using the function bool Aircondition_LG::sendCommandAndParameter(char aCommand, int aParameter) you can control the air conditioner by any other command source.
The file acLG.h contains the command documentation of the LG air conditioner IR protocol. Based on reverse engineering of the LG AKB73315611 remote. LG AKB73315611 remote

ReceiverTimingAnalysis

This example analyzes the signal delivered by your IR receiver module. Values can be used to determine the stability of the received signal as well as a hint for determining the protocol.
It also computes the MARK_EXCESS_MICROS value, which is the extension of the mark (pulse) duration introduced by the IR receiver module.
It can be tested online with WOKWI. Click on the receiver while simulation is running to specify individual NEC IR codes.

Issues and discussions

  • Do not open an issue without first testing some of the examples!
  • If you have a problem, please post the MCVE (Minimal Complete Verifiable Example) showing this problem. My experience is, that most of the times you will find the problem while creating this MCVE 😄.
  • Use code blocks; it helps us help you when we can read your code!

Compile options / macros for this library

To customize the library to different requirements, there are some compile options / macros available.
Most macros must be defined in your program before the line #include <IRremote.hpp> to take effect. Modify them by enabling / disabling them, or change the values if applicable.

Name File Default value Description
RAW_BUFFER_LENGTH Before #include <IRremote.hpp> 100 Buffer size of raw input buffer. Must be even! 100 is sufficient for regular protocols of up to 48 bits, but for most air conditioner protocols a value of up to 750 is required. Use the ReceiveDump example to find smallest value for your requirements.
IR_SEND_PIN Before #include <IRremote.hpp> disabled If specified (as constant), reduces program size and improves send timing for AVR. If you want to use a runtime valiable send pin e.g. with setSendPin(uint8_t aSendPinNumber) , you must disable this macro.
SEND_PWM_BY_TIMER Before #include <IRremote.hpp> disabled Disable carrier PWM generation in software and use (restricted) hardware PWM. Enabled for ESP32 and RP2040 in all examples.
USE_NO_SEND_PWM Before #include <IRremote.hpp> disabled Use no carrier PWM, just simulate an active low receiver signal. Overrides SEND_PWM_BY_TIMER definition.
USE_OPEN_DRAIN_OUTPUT_FOR_SEND_PIN Before #include <IRremote.hpp> disabled Use or simulate open drain output mode at send pin. Attention, active state of open drain is LOW, so connect the send LED between positive supply and send pin!
EXCLUDE_EXOTIC_PROTOCOLS Before #include <IRremote.hpp> disabled If activated, BOSEWAVE, WHYNTER and LEGO_PF are excluded in decode() and in sending with IrSender.write(). Saves up to 650 bytes program space.
EXCLUDE_UNIVERSAL_PROTOCOLS Before #include <IRremote.hpp> disabled If activated, the universal decoder for pulse width or pulse distance protocols and decodeHash (special decoder for all protocols) are excluded in decode(). Saves up to 1000 bytes program space.
MARK_EXCESS_MICROS Before #include <IRremote.hpp> 20 MARK_EXCESS_MICROS is subtracted from all marks and added to all spaces before decoding, to compensate for the signal forming of different IR receiver modules.
RECORD_GAP_MICROS Before #include <IRremote.hpp> 5000 Minimum gap between IR transmissions, to detect the end of a protocol.
Must be greater than any space of a protocol e.g. the NEC header space of 4500 µs.
Must be smaller than any gap between a command and a repeat; e.g. the retransmission gap for Sony is around 24 ms.
Keep in mind, that this is the delay between the end of the received command and the start of decoding.
FEEDBACK_LED_IS_ACTIVE_LOW Before #include <IRremote.hpp> disabled Required on some boards (like my BluePill and my ESP8266 board), where the feedback LED is active low.
NO_LED_FEEDBACK_CODE Before #include <IRremote.hpp> disabled This completely disables the LED feedback code for send and receive, thus saving around 100 bytes program space for receiving, around 500 bytes for sending and halving the receiver ISR processing time.
IR_INPUT_IS_ACTIVE_HIGH Before #include <IRremote.hpp> disabled Enable it if you use a RF receiver, which has an active HIGH output signal.
DEBUG IRremoteInt.h disabled Enables lots of lovely debug output.
IR_SEND_DUTY_CYCLE_PERCENT IRremote.h 30 Duty cycle of IR send signal.
MICROS_PER_TICK IRremoteInt.h 50 Resolution of the raw input buffer data. Corresponds to 2 pulses of each 26.3 µs at 38 kHz.
IR_USE_AVR_TIMER* private/IRTimer.hpp Selection of timer to be used for generating IR receiving sample interval.
- - - -
IR_INPUT_PIN Before #include <TinyIRReceiver.hpp> 2 The pin number for TinyIRReceiver IR input, which gets compiled in.
IR_FEEDBACK_LED_PIN Before #include <TinyIRReceiver.hpp> LED_BUILTIN The pin number for TinyIRReceiver feedback LED, which gets compiled in.
NO_LED_FEEDBACK_CODE Before #include <TinyIRReceiver.hpp> disabled Enable it to disable the feedback LED function. Saves 14 bytes program space.

Changing include (*.h) files with Arduino IDE

First, use Sketch > Show Sketch Folder (Ctrl+K).
If you have not yet saved the example as your own sketch, then you are instantly in the right library folder.
Otherwise you have to navigate to the parallel libraries folder and select the library you want to access.
In both cases the library source and include files are located in the libraries src directory.
The modification must be renewed for each new library version!

Modifying compile options / macros with PlatformIO

If you are using PlatformIO, you can define the macros in the platformio.ini file with build_flags = -D MACRO_NAME or build_flags = -D MACRO_NAME=macroValue.

Modifying compile options / macros with Sloeber IDE

If you are using Sloeber as your IDE, you can easily define global symbols with Properties > Arduino > CompileOptions.
Sloeber settings

Supported Boards

Issues and discussions with the content "Is it possible to use this library with the ATTinyXYZ? / board XYZ" without any reasonable explanations will be immediately closed without further notice.

ATtiny and Digispark boards are only tested with the recommended ATTinyCore using New Style pin mapping for the pro board.

  • Arduino Uno / Mega / Leonardo / Duemilanove / Diecimila / LilyPad / Mini / Fio / Nano etc.
  • Teensy 1.0 / 1.0++ / 2.0 / 2++ / 3.0 / 3.1 / Teensy-LC - but limited support; Credits: PaulStoffregen (Teensy Team)
  • Sanguino
  • ATmega8, 48, 88, 168, 328
  • ATmega8535, 16, 32, 164, 324, 644, 1284,
  • ATmega64, 128
  • ATmega4809 (Nano every)
  • ATtiny84, 85, 167 (Digispark + Digispark Pro)
  • SAMD (Zero, MKR*, but not DUE, which is SAM architecture)
  • ESP32 (ESP32 C3 since board package 2.0.2 from Espressif)
  • ESP8266 This fork supports an impressive set of protocols and a lot of air conditioners
  • Sparkfun Pro Micro
  • Nano Every, Uno WiFi Rev2, nRF5 BBC MicroBit, Nano33_BLE
  • BluePill with STM32
  • RP2040 based boards (Raspberry Pi Pico, Nano RP2040 Connect etc.)

We are open to suggestions for adding support to new boards, however we highly recommend you contact your supplier first and ask them to provide support from their side.
If you can provide examples of using a periodic timer for interrupts for the new board, and the board name for selection in the Arduino IDE, then you have way better chances to get your board supported by IRremote.

Timer and pin usage

The receiver sample interval of 50 µs is generated by a timer. On many boards this must be a hardware timer, on some, where a software timer is available, the software timer is used.
Every pin can be used for receiving.
The code for the timer and the timer selection is located in private/IRTimer.hpp. It can be adjusted here.
Be aware that the hardware timer used for receiving should not be used for analogWrite()! See table below.

The MinimalReceiver example uses the TinyReceiver library, which can only receive NEC codes, but does not require any timer.

The send PWM signal is by default generated by software. Therefore every pin can be used for sending. The PWM pulse length is guaranteed to be constant by using delayMicroseconds(). Take care not to generate interrupts during sending with software generated PWM, otherwise you will get jitter in the generated PWM. E.g. wait for a former Serial.print() statement to be finished by Serial.flush(). Since the Arduino micros() function has a resolution of 4 µs at 16 MHz, we always see a small jitter in the signal, which seems to be OK for the receivers.

Software generated PWM showing small jitter because of the limited resolution of 4 µs of the Arduino core micros() function for an ATmega328 Detail (ATmega328 generated) showing 30% duty cycle
Software PWM Software PWM detail

Incompatibilities to other libraries and Arduino commands like tone() and analogWrite()

If you use a library which requires the same timer as IRremote, you have a problem, since the timer resource cannot be shared simultaneously by both libraries. The best approach is to change the timer used for IRremote, which can be accomplished by modifying the timer selection in private/IRTimer.hpp.
For the AVR platform the code to modify looks like:

// Arduino Mega
#elif defined(__AVR_ATmega1280__) || defined(__AVR_ATmega2560__)
#  if !defined(IR_USE_AVR_TIMER1) && !defined(IR_USE_AVR_TIMER2) && !defined(IR_USE_AVR_TIMER3) && !defined(IR_USE_AVR_TIMER4) && !defined(IR_USE_AVR_TIMER5)
//#define IR_USE_AVR_TIMER1   // send pin = pin 11
#define IR_USE_AVR_TIMER2     // send pin = pin 9
//#define IR_USE_AVR_TIMER3   // send pin = pin 5
//#define IR_USE_AVR_TIMER4   // send pin = pin 6
//#define IR_USE_AVR_TIMER5   // send pin = pin 46
#  endif

You just have to modify the comments of the current and desired timer line. But be aware that the new timer in turn might be incompatible with other libraries or commands.
The modification must be renewed for each new IRremote library version, or you use an IDE like Sloeber.
For other platforms you must modify the appropriate section guarded by e.g. #elif defined(ESP32).

Another approach can be to share the timer sequentially if their functionality is used only for a short period of time like for the Arduino tone() command. An example can be seen here, where the timer settings for IR receive are restored after the tone has stopped. For this we must call IrReceiver.start() or better IrReceiver.start(microsecondsOfToneDuration).
This only works since each call to tone() completely initializes the timer 2 used by the tone() command.

Hardware-PWM signal generation for sending

If you define SEND_PWM_BY_TIMER, the send PWM signal is forced to be generated by a hardware timer. The same timer as for the receiver is used. Since each hardware timer has its dedicated output pins, you must change timer to change PWM output.
The timer and the pin usage can be adjusted in private/IRTimer.hpp.

Board/CPU Receive
& PWM Timers		 Hardware-PWM Pin analogWrite()
pins occupied by timer
ATtiny84 1 6
ATtiny85 > 4 MHz 0, 1 0, 4 0, 1 & 4
ATtiny88 > 4 MHz 1 PB1 / 8 PB1 / 8 & PB2 / 9
ATtiny167 > 4 MHz 1 9 8 - 15
ATtiny1604 TCB0 PA05
ATmega8 1 9
ATmega168, ATmega328 1, 2 9, 3 9 & 10, 3 & 11
ATmega1284 1, 2, 3 13, 14, 6
ATmega164, ATmega324, ATmega644 1, 2 13, 14
ATmega8535 ATmega16, ATmega32 1 13
ATmega64, ATmega128, ATmega1281, ATmega2561 1 13
ATmega8515, ATmega162 1 13
ATmega1280, ATmega2560 1, 2, 3, 4, 5 5, 6, 9, 11, 46
ATmega4809 TCB0 A4
Leonardo (Atmega32u4) 1, 3, 4_HS 5, 9, 13
Zero (SAMD) TC3 *, 9
ESP32 Ledc chan. 0 All pins
Sparkfun Pro Micro 1, 3 5, 9
Teensy 1.0 1 17 15, 18
Teensy 2.0 1, 3, 4_HS 9, 10, 14 12
Teensy++ 1.0 / 2.0 1, 2, 3 1, 16, 25 0
Teensy-LC TPM1 16 17
Teensy 3.0 - 3.6 CMT 5
Teensy 4.0 - 4.1 FlexPWM1.3 8 7, 25
BluePill / STM32F103C8T6 3 % PA6 & PA7 & PB0 & PB1
BluePill / STM32F103C8T6 TIM4 % PB6 & PB7 & PB8 & PB9
RP2040 / Pi Pico default alarm pool All pins No pin
RP2040 / Mbed based Mbed Ticker All pins No pin

Why do we use 30% duty cycle for sending

We do it according to the statement in the Vishay datasheet:

  • Carrier duty cycle 50 %, peak current of emitter IF = 200 mA, the resulting transmission distance is 25 m.
  • Carrier duty cycle 10 %, peak current of emitter IF = 800 mA, the resulting transmission distance is 29 m. - Factor 1.16 The reason is, that it is not the pure energy of the fundamental which is responsible for the receiver to detect a signal. Due to automatic gain control and other bias effects, high intensity of the 38 kHz pulse counts more than mediunm intensity (e.g. 50% duty cycle) at the same total energy.

Increase sending power

The best way to increase the IR power is to use 2 or 3 IR diodes in series. One diode requires 1.1 to 1.5 volt so you can supply 3 diodes with a 5 volt output.
To keep the current, you must reduce the resistor by (5 - 1.3) / (5 - 2.6) = 1.5 e.g. from 150 ohm to 100 ohm for 25 mA and 2 diodes with 1.3 volt and a 5 volt supply.
For 3 diodes it requires factor 2.5 e.g. from 150 ohm to 60 ohm.

How we decode signals

The IR signal is sampled at a 50 µs interval. For a constant 525 µs pulse or pause we therefore get 10 or 11 samples, each with 50% probability.
And belive me, if you send a 525 µs signal, your receiver will output something between around 400 and 700 µs!
Therefore we decode by default with a +/- 25% margin using the formulas here.
E.g. for the NEC protocol with its 560 µs unit length, we have TICKS_LOW = 8.358 and TICKS_HIGH = 15.0. This means, we accept any value between 8 ticks / 400 µs and 15 ticks / 750 µs (inclusive) as a mark or as a zero space. For a one space we have TICKS_LOW = 25.07 and TICKS_HIGH = 45.0.
And since the receivers generated marks are longer or shorter than the spaces, we have introduced the [MARK_EXCESS_MICROS value]/https://github.com/Arduino-IRremote/Arduino-IRremote#protocolunknown) to compensate for this receiver (and signal stength as well as ambient light dependent :-( ) specific deviation. Welcome to the basics of real world signal processing.

NEC encoding diagrams

Created with sigrok PulseView with IR_NEC decoder by DjordjeMandic.
8 bit address NEC code 8 bit address NEC code 16 bit address NEC code 16 bit address NEC code

Quick comparison of 4 Arduino IR receiving libraries

Here you find an ESP8266/ESP32 version of IRremote with an impressive list of supported protocols.

This is a short comparison and may not be complete or correct.

I created this comparison matrix for myself in order to choose a small IR lib for my project and to have a quick overview, when to choose which library.
It is dated from 03.02.2021. If you have complains about the data or request for extensions, please send a PM or open a discussion.

Subject IRMP IRLremote IRLib2
mostly unmaintained		 IRremote Minimal NEC
Number of protocols 50 Nec + Panasonic + Hash * 12 + Hash * 17 + Hash * NEC
3.Party libs needed % PinChangeInterrupt if not pin 2 or 3 % % %
Timing method receive Timer2 or interrupt for pin 2 or 3 Interrupt Timer2 or interrupt for pin 2 or 3 Timer2 or interrupt for NEC Interrupt
Timing method send PWM and timing with Timer2 interrupts Timer2 interrupts Timer2 and blocking wait PWM with Timer2 and blocking wait with delayMicroseconds() %
Send pins All All All ? Timer dependent %
Decode method OnTheFly OnTheFly RAM RAM OnTheFly
Encode method OnTheFly OnTheFly OnTheFly OnTheFly or RAM %
Callback suppport x % % % x
Repeat handling Receive + Send (partially) % ? Receive + Send x
LED feedback x % x x x
FLASH usage (simple NEC example with 5 prints) 1820
(4300 for 15 main / 8000 for all 40 protocols)
(+200 for callback)
(+80 for interrupt at pin 2+3)		 1270
(1400 for pin 2+3)		 4830 1770 900
RAM usage 52
(73 / 100 for 15 (main) / 40 protocols)		 62 334 227 19
Supported platforms avr, megaAVR, attiny, Digispark (Pro), esp8266, ESP32, STM32, SAMD 21, Apollo3
(plus arm and pic for non Arduino IDE)		 avr, esp8266 avr, SAMD 21, SAMD 51 avr, attiny, esp8266, esp32, SAM, SAMD All platforms with attachInterrupt()
Last library update 2/2021 4/2018 9/2019 2/2021 2/2021
Remarks Decodes 40 protocols concurrently.
39 Protocols to send.
Work in progress.		 Only one protocol at a time. Consists of 5 libraries. Project containing bugs - 45 issues, no reaction for at least one year. Decoding and sending are easy to extend.
Supports Pronto codes.		 Requires no timer.

* The Hash protocol gives you a hash as code, which may be sufficient to distinguish your keys on the remote, but may not work with some protocols like Mitsubishi

Revision History

Please see changelog.md.

Contributing

If you want to contribute to this project:

  • Report bugs and errors
  • Ask for enhancements
  • Create issues and pull requests
  • Tell other people about this library
  • Contribute new protocols

Check here for some guidelines.

Adding new protocols

To add a new protocol is quite straightforward. Best is too look at the existing protocols to find a similar one and modify it.
As a rule of thumb, it is easier to work with a description of the protocol rather than trying to entirely reverse-engineer the protocol. Please include a link to the description in the header, if you found one.
The durations you receive are likely to be longer for marks and shorter for spaces than the protocol suggests, but this depends on the receiver circuit in use. Most protocols use multiples of one time-unit for marks and spaces like e.g. NEC. It's easy to be off-by-one with the last bit, since the last space is not recorded by IRremote.

Try to make use of the template functions decodePulseDistanceData() and sendPulseDistanceData(). If your protocol supports address and code fields, try to reflect this in your api like it is done in sendNEC(uint16_t aAddress, uint8_t aCommand, uint_fast8_t aNumberOfRepeats, bool aIsRepeat) and decodeNEC().

Integration

To integrate your protocol, you need to extend the two functions decode() and getProtocolString() in IRreceice.hpp, add macros and function declarations for sending and receiving and extend the enum decode_type_t in IRremote.h.
And at least it would be wonderful if you can provide an example how to use the new protocol. A detailed description can be found in the ir_Template.hpp file.

Creating API documentation

To generate the API documentation, Doxygen, as well as Graphviz should be installed. (Note that on Windows, it is useful to specify the installer to add Graphviz to PATH or to do it manually. With Doxygen and Graphviz installed, issue the command doxygen from the command line in the main project directory, which will generate the API documentation in HTML format. The just generated docs/index.html can now be opened in a browser.

Contributors

Check here

License

Up to the version 2.7.0, the License is GPLv2. From the version 2.8.0, the license is the MIT license.

Copyright

Initially coded 2009 Ken Shirriff http://www.righto.com
Copyright (c) 2016-2017 Rafi Khan
Copyright (c) 2020-2022 Armin Joachimsmeyer

About

Infrared remote library for Arduino: send and receive infrared signals with multiple protocols

Resources

Readme

License

View license
Activity

Stars

0 stars

Watchers

0 watching

Forks

0 forks
Report repository

Releases

24 tags

Packages

No packages published

Languages

  • C++ 92.3%
  • C 7.7%