Support VectorQuadraticFunction objectives

Project.toml

@@ -10,12 +10,14 @@ MathOptInterface = "b8f27783-ece8-5eb3-8dc8-9495eed66fee"
 [compat]
 Combinatorics = "1"
 HiGHS = "1"
+Ipopt = "1"
 MathOptInterface = "1.12"
 julia = "1.6"
 
 [extras]
 HiGHS = "87dc4568-4c63-4d18-b0c0-bb2238e4078b"
+Ipopt = "b6b21f68-93f8-5de0-b562-5493be1d77c9"
 Test = "8dfed614-e22c-5e08-85e1-65c5234f0b40"
 
 [targets]
-test = ["HiGHS", "Test"]
+test = ["HiGHS", "Ipopt", "Test"]

src/MultiObjectiveAlgorithms.jl

@@ -71,6 +71,25 @@ function _scalarise(f::MOI.VectorAffineFunction, w::Vector{Float64})
     return MOI.ScalarAffineFunction(terms, constant)
 end
 
+function _scalarise(f::MOI.VectorQuadraticFunction, w::Vector{Float64})
+    @assert MOI.output_dimension(f) == length(w)
+    quad_terms = MOI.ScalarQuadraticTerm{Float64}[
+        MOI.ScalarQuadraticTerm(
+            w[term.output_index] * term.scalar_term.coefficient,
+            term.scalar_term.variable_1,
+            term.scalar_term.variable_2,
+        ) for term in f.quadratic_terms
+    ]
+    affine_terms = MOI.ScalarAffineTerm{Float64}[
+        MOI.ScalarAffineTerm(
+            w[term.output_index] * term.scalar_term.coefficient,
+            term.scalar_term.variable,
+        ) for term in f.affine_terms
+    ]
+    constant = sum(w[i] * f.constants[i] for i in 1:length(w))
+    return MOI.ScalarQuadraticFunction(quad_terms, affine_terms, constant)
+end
+
 abstract type AbstractAlgorithm end
 
 MOI.Utilities.map_indices(::Function, x::AbstractAlgorithm) = x

test/algorithms/Dichotomy.jl

@@ -8,6 +8,7 @@ module TestDichotomy
 using Test
 
 import HiGHS
+import Ipopt
 import MultiObjectiveAlgorithms as MOA
 
 const MOI = MOA.MOI
@@ -333,6 +334,33 @@ maxobjective: [1.0 * x, -1.0 * x, 2.0 * x + 2.0]
     return
 end
 
+function test_quadratic()
+    μ = [0.05470748600000001, 0.18257110599999998]
+    Q = [0.00076204 0.00051972; 0.00051972 0.00546173]
+    N = 2
+    model = MOA.Optimizer(Ipopt.Optimizer)
+    MOI.set(model, MOA.Algorithm(), MOA.Dichotomy())
+    MOI.set(model, MOA.SolutionLimit(), 10)
+    MOI.set(model, MOI.Silent(), true)
+    w = MOI.add_variables(model, N)
+    MOI.add_constraint.(model, w, MOI.GreaterThan(0.0))
+    MOI.add_constraint.(model, w, MOI.LessThan(1.0))
+    MOI.add_constraint(model, sum(1.0 * w[i] for i in 1:N), MOI.EqualTo(1.0))
+    var = sum(Q[i, j] * w[i] * w[j] for i in 1:N, j in 1:N)
+    mean = sum(-μ[i] * w[i] for i in 1:N)
+    f = MOI.Utilities.operate(vcat, Float64, var, mean)
+    MOI.set(model, MOI.ObjectiveSense(), MOI.MIN_SENSE)
+    MOI.set(model, MOI.ObjectiveFunction{typeof(f)}(), f)
+    MOI.optimize!(model)
+    @test MOI.get(model, MOI.ResultCount()) == 10
+    for i in 1:MOI.get(model, MOI.ResultCount())
+        w_sol = MOI.get(model, MOI.VariablePrimal(i), w)
+        y = MOI.get(model, MOI.ObjectiveValue(i))
+        @test y ≈ [w_sol' * Q * w_sol, -μ' * w_sol]
+    end
+    return
+end
+
 end
 
 TestDichotomy.run_tests()