Skip to content
OpenStack Swift Puppet Module http://openstack.org
Ruby Puppet HTML
Latest commit c41983c @mwhahaha mwhahaha Update to swift hash parameters
This change adds the ability to configure the swift_hash_path_prefix for
swift. Additionally it deprecated swift_hash_suffix in favor of a new
parameter called swift_hash_path_suffix for consistency.

Change-Id: I26935fe21af42b488f4479c4e50e8f481a75ea40
Closes-Bug: #1505269
Failed to load latest commit information.
ext Add test for keystone auth
files Manage swift with swiftinit service provider
lib/puppet Merge "Add support to change meta entry for ring devices"
manifests Update to swift hash parameters
spec Update to swift hash parameters
templates
tests Document and example for storage filters use
.gemfile Update module to use puppetlabs_spec_helper gem
.gitignore Try to use zuul-cloner to prepare fixtures
.gitreview Update .gitreview file for project rename
.sync.yml Initial msync run for all Puppet OpenStack modules
CHANGELOG.md release: prepare 7.0.0 (liberty)
Gemfile Add rspec-puppet-facts to the spec_helper
LICENSE Synchronize LICENSE file with OpenStack projects
README.md Document and example for storage filters use
Rakefile Use puppet-openstack_spec_helper for Rakefile & spec_helper_acceptance
metadata.json release: prepare 7.0.0 (liberty)

README.md

swift

7.0.0 - 2015.2 - Liberty

Table of Contents

  1. Overview - What is the swift module?
  2. Module Description - What does the module do?
  3. Setup - The basics of getting started with swift
  4. Reference - The classes, defines,functions and facts available in this module
  5. Implementation - An under-the-hood peek at what the module is doing
  6. Limitations - OS compatibility, etc.
  7. Development - Guide for contributing to the module
  8. Contributors - Those with commits

Overview

The swift module is a part of OpenStack, an effort by the Openstack infrastructure team to provide continuous integration testing and code review for Openstack and Openstack community projects as part of the core software. The module itself is used to flexibly configure and manage the object storage service for Openstack.

Module Description

The swift module is a thorough attempt to make Puppet capable of managing the entirety of swift. This includes manifests to provision such things as keystone, storage backends, proxies, and the ring. Types are shipped as part of the swift module to assist in manipulation of configuration files. A custom service provider built around the swift-init tool is also provided as an option for enhanced swift service management. The classes in this module will deploy Swift using best practices for a typical deployment.

This module is tested in combination with other modules needed to build and leverage an entire Openstack software stack. In addition, this module requires Puppet's exported resources.

Setup

What the swift module affects

  • Swift, the object storage service for Openstack.

Installing swift

puppet module install openstack/swift

Beginning with swift

You much first setup exported resources.

To utilize the swift module's functionality you will need to declare multiple resources. This is not an exhaustive list of all the components needed, we recommend you consult and understand the core openstack documentation.

Defining a swift storage node

class { 'swift':
  swift_hash_suffix => 'swift_secret',
}

swift::storage::loopback { ['1', '2']:
 require => Class['swift'],
}

class { 'swift::storage::all':
  storage_local_net_ip => $ipaddress_eth0
}

@@ring_object_device { "${ipaddress_eth0}:6000/1":
  region => 1, # optional, defaults to 1
  zone   => 1,
  weight => 1,
}
@@ring_container_device { "${ipaddress_eth0}:6001/1":
  zone   => 1,
  weight => 1,
}
@@ring_account_device { "${ipaddress_eth0}:6002/1":
  zone   => 1,
  weight => 1,
}

@@ring_object_device { "${ipaddress_eth0}:6000/2":
  region => 2,
  zone   => 1,
  weight => 1,
}
@@ring_container_device { "${ipaddress_eth0}:6001/2":
  region => 2,
  zone   => 1,
  weight => 1,
}
@@ring_account_device { "${ipaddress_eth0}:6002/2":
  region => 2,
  zone   => 1,
  weight => 1,
}

Swift::Ringsync<<||>>```

Usage
-----

### Class: swift

Class that will set up the base packages and the base /etc/swift/swift.conf

```puppet
class { 'swift': swift_hash_suffix => 'shared_secret', }

swift_hash_suffix

The shared salt used when hashing ring mappings.

Class swift::proxy

Class that installs and configures the swift proxy server.

class { 'swift::proxy':
  account_autocreate => true,
  proxy_local_net_ip => $ipaddress_eth1,
  port               => '11211',
}

account_autocreate

Specifies if the module should manage the automatic creation of the accounts needed for swift. This should be set to true if tempauth is also being used.

proxy_local_net_ip

This is the ip that the proxy service will bind to when it starts.

port

The port for which the proxy service will bind to when it starts.

Class swift::proxy::dlo

Configures DLO middleware for swift proxy.

class { '::swift::proxy::dlo':
  rate_limit_after_segment    => '10',
  rate_limit_segments_per_sec => '1',
  max_get_time                => '86400'
}

rate_limit_after_segment

Start rate-limiting DLO segment serving after the Nth segment of a segmented object.

rate_limit_segments_per_sec

Once segment rate-limiting kicks in for an object, limit segments served to N per second. 0 means no rate-limiting.

max_get_time

Time limit on GET requests (seconds).

Class: swift::storage

Class that sets up all of the configuration and dependencies for swift storage server instances.

class { 'swift::storage': storage_local_net_ip => $ipaddress_eth1, }

storage_local_net_ip

This is the ip that the storage service will bind to when it starts.

Class: swift::ringbuilder

A class that knows how to build swift rings. Creates the initial ring via exported resources and rebalances the ring if it is updated.

class { 'swift::ringbuilder':
  part_power     => '18',
  replicas       => '3',
  min_part_hours => '1',
}

part_power

The number of partitions in the swift ring. (specified as the power of 2)

replicas

The number of replicas to store.

min_part_hours

Time before a partition can be moved.

Define: swift::storage::server

Defined resource type that can be used to create a swift storage server instance. If you keep the sever names unique it is possibly to create multiple swift servers on a single physical node.

This will configure an rsync server instance and swift storage instance to manage the all devices in the devices directory.

swift::storage::server { '6010':
  type                 => 'object',
  devices              => '/srv/node',
  storage_local_net_ip => '127.0.0.1'
}

Define: swift::storage::filter::recon

Configure the swift recon middleware on a swift:storage::server Can be configured on: account, container, object servers.

Define: swift::storage::filter::healthcheck

Configure the swift health check middleware on a swift:storage::server Can be configured on: account, container, object servers.

Declaring either the recon or health check middleware in a node manifest is required when specifying the recon or healthcheck middleware in an (account|container|object)_pipeline.

example manifest:


class { 'swift::storage::all':
  storage_local_net_ip => $swift_local_net_ip,
  account_pipeline     => ['healthcheck', 'recon', 'account-server'],
  container_pipeline   => ['healthcheck', 'recon', 'container-server'],
  object_pipeline      => ['healthcheck', 'recon', 'object-server'],
}
$rings = [
  'account',
  'object',
  'container']
swift::storage::filter::recon { $rings: }
swift::storage::filter::healthcheck { $rings: }

namevar

The namevar/title for this type will map to the port where the server is hosted.

type

The type of device, e.g. account, object, or container.

device

The directory where the physical storage device will be mounted.

storage_local_net_ip

This is the ip that the storage service will bind to when it starts.

Define: swift::storage::loopback

This defined resource type was created to test swift by creating a loopback device that can be used a storage device in the absent of a dedicated block device.

It creates a partition of size [$seek] at basedir/[$name] using dd with [$byte_size], formats is to be a xfs filesystem which is then mounted at [$mnt_base_dir]/[$name].

Then, it creates an instance of defined class for the xfs file system that will eventually lead the mounting of the device using the swift::storage::mount define.

swift::storage::loopback { '1':
  base_dir  => '/srv/loopback-device',
  mnt_base_dir => '/srv/node',
  byte_size => '1024',
  seek      => '25000',
}

base_dir

The directory where the flat files will be stored that house the file system to be loop back mounted.

mnt_base_dir

The directory where the flat files that store the file system to be loop back mounted are actually mounted at.

byte_size

The byte size that dd uses when it creates the file system.

seek

The size of the file system that will be created. Defaults to 25000.

Class: swift::objectexpirer

Class that will set Swift object expirer, for scheduled deletion of objects.

class { 'swift::objectexpirer': }

It is assumed that the object expirer service will usually be installed in a proxy node. On Red Hat-based distributions, if the class is included in a non-proxy node, the openstack-swift-proxy package will need to be installed.

Swiftinit service provider

The 'swiftinit' provider is a custom provider of the service type.

"Swift services are generally managed with swift-init. the general usage is swift-init , where service is the swift service to manage (for example object, container, account, proxy)" From http://docs.openstack.org/developer/swift/admin_guide.html#managing-services

This new provider is intended to improve puppet-swift deployments in the following ways:

  • The default service provider for puppet-swift is to use distribution specific service providers such as systemd and upstart. If distribution provided init scripts do not specify the full range of service commands, puppet will fall back to methods such as process name matching which is not very reliable. For example, if you were to tail a log file with the same name as a swift process, puppet will interpret that process table match as the swift-proxy service running and fail to start the swift service.
  • Minimize customer impact: Using the swiftinit service provider enables more specific and targeted control of swift services. Swift-init provides grateful stop/start reload/restart of swift services which will allow swift processes to finish any current requests before completely stopping the old processes.
  • Specific control of services starting at boot is implemented by adding or removing a templated init or services file. This is managed by this provider. For EL and non Ubuntu Debian OS types, this provider will also make calls out to systemctl reload and systemctl enable/disable.
  • Future use of the swiftinit provider is planed to allow for starting multiple servers using swift-init and multiple configuration files, to support a dedicated replication network.

Using the swiftinit service provider

  • To use the swiftinit service provider set "service_provider" on the supported components you have defined in your config manifest.
  class { '::swift::storage::account':
    service_provider => 'swiftinit',
  }
  class { '::swift::storage::container':
    service_provider => 'swiftinit',
  }
  class { '::swift::storage::object':
    service_provider => 'swiftinit',
  }
  class {'::swift::objectexpirer':
    service_provider => 'swiftinit',
  }
  class { '::swift::proxy':
    service_provider => 'swiftinit',
  }

Moving from the default service providers to the swiftinit service provider is supported. On the next puppet run after setting the swiftinit service provider swift services are stopped on the old provider and immediately started using swift-init. This provides a supported upgrade path with no down time.

The swiftinit service provider uses the following service type parameters to manage swift services in a non standard way.

  • manifest is used to pass in the config file the service should be configured with. Ex object-server.conf
  • pattern is used to pass in the debian/redhat osfamily specific service names as found in params.pp. Used to match names on services files as provided by distro packages. Debian/Ubuntu service names already match names used by swift-init.

To aid with input validation to the swiftinit provider there is a defined type swift::service

Class: swift::service

This is a wrapper defined type for the swift service providers. It provides a centraziled location to manage and validate in put for use to the default as well as the swiftinit service providers.

namevar

The namevar/title of swift::service must be one of the swift_init_service_names listed in swift::params.pp. These names are parsed by the swiftinit provider to provide service management as well as template boot files.

os_family_service_name

The distribution specific service name from swift::params. This name is passed to the default service provider. This name is used by the swiftinit provider to match on default provider service names when moving from a default provider to the swiftinit provider. The swiftinit provider also uses the service_name to manage service and init files.

config_file_name

The swift service configuration file name. It must be one of the following: object-server.conf, account-server.conf, container-server.conf, proxy-server.conf, object-expirer.conf.

service_ensure

The state of the service to ensure, running or stopped.

enabled

Should the service be enabled to start at boot.

service_provider

To use the swiftinit service provider to manage swift services, set service_provider to "swiftinit". When enable is true the provider will populate boot files that start swift using swift-init at boot. Defaults to $::swift::params::service_provider.

Verifying installation

This modules ships with a simple Ruby script that validates whether or not your swift cluster is functional.

The script can be run as:

ruby $modulepath/swift/files/swift_tester.rb

Implementation

swift

puppet-swift is a combination of Puppet manifest and ruby code to deliver configuration and extra functionality through types and providers.

Types

swift_config

The swift_config provider is a children of the ini_setting provider. It allows one to write an entry in the /etc/swift/swift.conf file.

swift_config { 'DEFAULT/verbose' :
  value => true,
}

This will write verbose=true in the [DEFAULT] section.

name

Section/setting name to manage from swift.conf

value

The value of the setting to be defined.

secret

Whether to hide the value from Puppet logs. Defaults to false.

ensure_absent_val

If value is equal to ensure_absent_val then the resource will behave as if ensure => absent was specified. Defaults to <SERVICE DEFAULT>

swift_account_config

Same as swift_config, but path is /etc/swift/account-server.conf

swift_bench_config

Same as swift_config, but path is /etc/swift/swift-bench.conf

swift_container_config

Same as swift_config, but path is /etc/swift/container-server.conf

swift_dispersion_config

Same as swift_config, but path is /etc/swift/dispersion.conf

swift_object_config

Same as swift_config, but path is /etc/swift/object-server.conf

swift_proxy_config

Same as swift_config, but path is /etc/swift/proxy-server.conf

Limitations

  • No explicit support external NAS devices (i.e. Nexenta and LFS) to offload the ring replication requirements.

Beaker-Rspec

This module has beaker-rspec tests

To run:

shell bundle install bundle exec rspec spec/acceptance

Development

Developer documentation for the entire puppet-openstack project.

Contributors

Something went wrong with that request. Please try again.