Implement .public Model endpoint

That delays publicizing new alerts (to let us fix typos, undo it, etc)

Author: zoffixznet

bin/server.p6

@@ -9,15 +9,15 @@ my $Alerts := P6lert::Model::Alerts.new;
 sub MAIN (Str:D :$host = 'localhost', UInt:D :$port = 10000) {
     my $application = route {
         get -> {
-            content 'text/html', html-render-alerts $Alerts.all
+            content 'text/html', html-render-alerts $Alerts.public
         }
         get -> 'alert', UInt $id {
             content 'text/html', html-render-alerts $Alerts.get: $id
         }
 
         get -> 'api', 'v1', 'all' {
             content 'application/json', to-json {
-                alerts => $Alerts.all».TO-JSON,
+                alerts => $Alerts.public».TO-JSON,
             };
         }
 

lib/P6lert/Model/Alerts.pm6

@@ -3,6 +3,7 @@ use DBIish;
 use P6lert::Alert;
 
 has IO::Path:D $.db-file = 'alerts.sqlite.db'.IO;
+has UInt $.public-delay  = 60*10; # delay before making messages public
 has $!dbh;
 
 submethod TWEAK {
@@ -50,6 +51,16 @@ method all {
     }
 }
 
+method public {
+    given $!dbh.prepare: ｢
+        SELECT * FROM alerts WHERE time < ? ORDER BY time DESC
+    ｣ {
+        LEAVE .finish;
+        .execute: time - $!public-delay;
+        eager .allrows(:array-of-hash).map: { P6lert::Alert.new: |$_ }
+    }
+}
+
 method get (UInt:D $id) {
     given $!dbh.prepare: ｢SELECT * FROM alerts where id = ?｣ {
         LEAVE .finish;

t/model/00-basic.t

@@ -1,17 +1,19 @@
 use lib <lib>;
 use Testo;
-use Temp::Path;
-use DBIish;
 
+plan 21;
+
+use Temp::Path;
 use P6lert::Model::Alerts;
 
+my $public-delay := 4;
 my $db-file := make-temp-path.extension: 'sqlite', :parts(0..*);
-my $alerts  := P6lert::Model::Alerts.new: :$db-file;
+my $alerts  := P6lert::Model::Alerts.new: :$db-file, :$public-delay;
 is $alerts, P6lert::Model::Alerts, '.new constructs right object';
 is $db-file, *.e, ".new creates db file $db-file";
 
 is (my $id = $alerts.add: 'test♥1'), UInt:D, ｢.add returns new alert's ID｣;
-
+is $alerts.public, 0, '.public gives 0 alerts';
 is $alerts.all, 1, 'have total 1 alert in db';
 group '.all.head object' => 7 => {
     with $alerts.all.head -> \a {
@@ -27,12 +29,14 @@ group '.all.head object' => 7 => {
 
 is $alerts.delete($id), *, 'deleting alert';
 is $alerts.all, 0, 'no alerts in db any more';
+is $alerts.public, 0, '.public still gives 0 alerts';
 
 is $alerts.add('test♥2'), UInt:D, ｢re-added first message｣;
 is $alerts.add(
   'meow2', :creator<Zof>, :affects('2017.12 and earlier'), :severity<critical>,
 ), UInt:D, ｢added second message｣;
 is $alerts.all, 2, 'two messages in db';
+is $alerts.public, 0, '.public still gives 0 alerts';
 
 group 'first message' => 7 => {
     with $alerts.all.head -> \a {
@@ -57,3 +61,34 @@ group 'second message' => 7 => {
         is a.affects,   '2017.12 and earlier',  '.affects';
     }
 }
+
+is *, *, 'waiting for public delay expire';
+sleep $public-delay+1;
+
+is $alerts.add('unpublic'), UInt:D, ｢added third, not-yet public message｣;
+is $alerts.all,    3, 'have 3 total alerts in db';
+is $alerts.public, 2, 'have 2 total public alerts in db';
+
+group 'first public message' => 7 => {
+    with $alerts.public.head -> \a {
+        is a,           P6lert::Alert,  'righ type';
+        is a.id,        2,              '.id';
+        is a.alert,     'test♥2',       '.alert';
+        is a.time,      /^\d**9..11$/,  '.time looks approximately right';
+        is a.creator,   'Anonymous',    '.creator';
+        is a.severity,  'normal',       '.severity';
+        is a.affects,   '',             '.affects';
+    }
+}
+
+group 'second public message' => 7 => {
+    with $alerts.public.tail -> \a {
+        is a,           P6lert::Alert,  'righ type';
+        is a.id,        3,              '.id';
+        is a.alert,     'meow2',        '.alert';
+        is a.time,      /^\d**9..11$/,  '.time looks approximately right';
+        is a.creator,   'Zof',          '.creator';
+        is a.severity,  'critical',      '.severity';
+        is a.affects,   '2017.12 and earlier',  '.affects';
+    }
+}