[euler] add solution for problem 18

Author: felher

euler/prob018-felher.pl

@@ -0,0 +1,38 @@
+use v6;
+
+my $triangle =
+	'75
+	95 64
+	17 47 82
+	18 35 87 10
+	20 04 82 47 65
+	19 01 23 75 03 34
+	88 02 77 73 07 63 67
+	99 65 04 28 06 16 70 92
+	41 41 26 56 83 40 80 70 33
+	41 48 72 33 47 32 37 16 94 29
+	53 71 44 65 25 43 91 52 97 51 14
+	70 11 33 28 77 73 17 78 39 68 17 57
+	91 71 52 38 17 14 91 43 58 50 27 29 48
+	63 66 04 68 89 53 67 30 73 16 69 87 40 31
+	04 62 98 27 23 09 70 98 73 93 38 53 60 04 23';
+
+my @lines = string-to-array($triangle).reverse;
+
+# reduce the triangle by adding up the lines until only one line with one
+# element is left; then print it.
+say @lines.reduce: &add-maxima;
+
+# this function assumes the shorter and longer array to be consecutive lines
+# in an reversed triangle. It then adds each of the maxima of consecutive fields
+# of the longer array to their shared diagonal neighbour in the shorter array.
+sub add-maxima(@longer, @shorter is copy) {
+	for 0 .. @longer - 2 -> $i {
+		@shorter[$i] += max @longer[$i], @longer[$i + 1];
+	}
+}
+
+sub string-to-array($string) {
+	my @lines = $string.lines;
+	@lines .= map(-> $line { $line.comb(/\d+/).item });
+}