Add noselect to wildmode option

[girishji]

When noselect is present in wildmode and wildmenu is enabled, the completion menu appears without pre-selecting the first item.

This change makes it easier to implement command-line auto-completion, where the menu dynamically appears as characters are typed, and <Tab> can be used to manually select an item. This can be achieved by leveraging the CmdlineChanged event to insert wildchar(m), triggering completion menu.

Without this change, auto-completion using the wildmenu mechanism is not feasible, as it automatically inserts the first match, preventing dynamic selection.

The following snippet demonstrates how to configure auto-completion using noselect:

set wim=noselect:lastused,full wop=pum wcm=<C-@> wmnu
autocmd CmdlineChanged : timer_start(0, function(CmdComplete, [getcmdline()]))
def CmdComplete(cur_cmdline: string, timer: number)
    var [cmdline, curpos] = [getcmdline(), getcmdpos()]
    if cur_cmdline ==# cmdline # Avoid completing each char of keymaps and pasted text
      && !pumvisible() && curpos == cmdline->len() + 1
      && cmdline =~ '\%(\w\|[*/:.-]\)$' && cmdline !~ '^\d\+$'  # Reduce noise
        feedkeys("\<C-@>", "ti")
        set eventignore+=CmdlineChanged  # Suppress redundant completion attempts
        timer_start(0, (_) => {
            getcmdline()->substitute('\%x00', '', 'g')->setcmdline()  # Remove <C-@> if no completion items exist
            set eventignore-=CmdlineChanged
        })
    endif
enddef
autocmd CmdlineEnter : set bo+=error
autocmd CmdlineLeave : set bo-=error

def MuteEventAndSend(key: string): string
    set ei+=CmdlineChanged
    timer_start(0, (_) => execute('set ei-=CmdlineChanged'))
    return (pumvisible() ? "\<c-e>" : "") .. key
enddef
cnoremap <expr> <up> MuteEventAndSend("\<up>")
cnoremap <expr> <down> MuteEventAndSend("\<down>")

---

Edit:

Here are a few examples that utilize the above auto-completion mechanism:

Fuzzy Find:

set findfunc=FuzzyFind
def FuzzyFind(cmdarg: string, _: bool): list<string>
    if allfiles == null_list
        allfiles = systemlist($'find {get(g:, "fzfind_root", ".")} \! \( -path "*/.git" -prune \) -type f -follow')
    endif
    return cmdarg == '' ? allfiles : allfiles->matchfuzzy(cmdarg)
enddef
var allfiles: list<string>
autocmd CmdlineEnter : allfiles = null_list
nnoremap <leader>f :find<space><c-@>
nnoremap <leader>V :<c-r>=execute('let fzfind_root="$VIMRUNTIME"')\|''<cr>find<space><c-@>

Grep (Interactive):

command! -nargs=+ -complete=customlist,GrepComplete Grep VisitFile(<q-args>)
def GrepComplete(arglead: string, cmdline: string, cursorpos: number): list<any>
    return arglead != null_string ? systemlist($'grep -REIHns "{arglead}"' ..
       ' --exclude-dir=.git --exclude=".*"') : []
enddef
def VisitFile(line: string)
    var qfitem = getqflist({lines: [line]}).items[0]
    if qfitem->has_key('bufnr')
        var pos = qfitem.vcol > 0 ? 'setcharpos' : 'setpos'
        exec $':b +call\ {pos}(".",\ [0,\ {qfitem.lnum},\ {qfitem.col},\ 0]) {qfitem.bufnr}'
        setbufvar(qfitem.bufnr, '&buflisted', 1)
    endif
enddef
nnoremap <leader>g :Grep<space>
nnoremap <leader>G :Grep <c-r>=expand("<cword>")<cr>

[zeertzjq]

Tthe default value of 'wildmenu' is on:

    {"wildmenu",    "wmnu", P_BOOL|P_VI_DEF,
			    (char_u *)&p_wmnu, PV_NONE, NULL, NULL,
			    {(char_u *)TRUE, (char_u *)0L} SCTX_INIT},

And 'wildmenu' is already on here, so this line doesn't do anything.

[ychin]

Just playing around with it. I managed to get Vim to crash with this PR by doing the following:

1. Launch Vim with --clean.
2. :set wim=noselect.
3. :set cot=nosel<Tab><C-Y>

[ychin]

Also, the examples listed were quite useful to demonstrate the use case!

[girishji]

Just playing around with it. I managed to get Vim to crash with this PR by doing the following:

1. Launch Vim with --clean.
2. :set wim=noselect.
3. :set cot=nosel<Tab><C-Y>

Thanks for testing! Should be fixed now.

[chrisbra]

thanks!

[zeertzjq]

This doesn't look right. WIM_NOSELECT is 0x10, which is equal to WILD_ADD_SLASH, which is never set in options.

[zeertzjq]

And the 0 | isn't needed here. But why do options now need to be passed when they don't need to be passed before?

[ychin]

I was wondering about that too

[girishji]

Good catch. It was supposed to be just nextwild(xp, WILD_PREV, options, escape); (replace 0 with options). Don't know how the meaningless thing got in there. options is needed here to prevent xp_files from being emptied out if there is only 1 entry. For noselect single element completion menu should be retained. options contains WILD_KEEP_SOLE_ITEM when noselect is set.

[girishji]

Fixed #16778

[justinmk]

Seems to be order-sensitive. Does the test pass if this line is changed to:

set wildmode=full,noselect

[zeertzjq]

Isn't this just how 'wildmode' works?

[justinmk]

That means set wildmode+=noselect doesn't work with the default value. Seems strange, and probably should be documented if this is expected.

[ychin]

Doesn't the docs say this?

It is a comma-separated list of up to four parts. Each part specifies what to do for each consecutive use of 'wildchar'. The first part specifies the behavior for the first use of 'wildchar', The second part for the second use, etc.

Each part consists of a colon separated list consisting of the following possible values:
…

It has always been order sensitive and the examples also don't use +=. I do wonder if it noselect ever makes sense to be not used as the first item in the element.

[justinmk]

No, not really. The docs you quoted are maybe barely understandable in these terms if you already know what you are looking for.

If set wildmode+=... produces nonsense it should be an error, instead of pretending to support +=.

[ychin]

Sure, I'm just pointing out that it's not specific to this noselect change, as the other values there are already order dependent for this option. That part of the docs has always been a bit hard to parse. I tried to give more examples in #8078 but maybe it's not clear enough.

I feel like clearing up the docs is better than just making += produce an error though, since it's not like it literally produces nonsense (unless you mean doing extra validation inside set wildmode+= to check each value). It just adds a value to the end. The important part is understanding that wildmode is order dependent (it's kind of impossible to properly configure this option without understanding that).

[girishji]

The wildmode option is inherently order-sensitive. Each comma-separated fragment determines the sequence in which wildchar behaves. Within each fragment, the colon-separated parts define simultaneous effects for wildchar. This is not clearly explained in the documentation. I considered rewriting the docs but chose not to include it in this PR.

Additionally, set wildmode=full,noselect does not behave as expected. Ideally, the first wildchar should open the menu, selecting and inserting the first item (full), while the second wildchar should unselect the item and revert the command-line change (noselect). However, this use case is unlikely to be meaningful. In practice, the implementation simply ignores noselect unless it appears before the first comma.

[girishji]

#17100