Question about BIND and EXISTS

[nkaralis]

Hello.

According to the spec, given a FILTER (NOT) EXISTS pattern E, the variables of the group graph pattern that contains E are in scope of E.

Does this mean that queries, such as the one provided below, should be rejected?

PREFIX : <http://example.com/>
SELECT * WHERE {
  ?x :p ?n
  FILTER NOT EXISTS {
    ?x :q ?m .
    BIND(10 AS ?n) # ?n already in scope (?)
    FILTER(?n = ?m)
  }
}

[afs]

Hi @nkaralis,

The area of EXISTS is currently quite active within the working group.

It is the intention in SPARQL 1.1 that BIND(10 AS ?n) in the position in the example would be rejected because ?n is in-scope - it is a static syntax check.

[nkaralis]

Hello @afs,

Thank you for you response.

I have a follow up question about the scope. Are the variables of the outer group graph pattern supposed to be available in all nested group graph patterns of E?

[afs]

Example?

[nkaralis]

PREFIX : <http://example.com/>
SELECT * WHERE {
  ?x :p ?n
  FILTER NOT EXISTS {
    ?x :q ?m .
    { ?y :v ?m . FILTER(?n = ?m) } #is ?n still in-scope?
  }
}

?x :p ?n 
{ ?x :q ?m . FILTER(?n = ?m) } # ?n is not in-scope here, right?

[afs]

Just from this part:

?x :p ?n 
{ ?x :q ?m . FILTER(?n = ?m) } # ?n is not in-scope here, right?

This is not EXISTS specific.

The algebra is:

         (join
           (bgp (triple ?x :p ?n))
           (filter (= ?n ?m)
             (bgp (triple ?x :q ?m)
        )))

(using http://sparql.org)

NB the join. Only ?m is set when the filter is executed. ?n is undefined. It is not a syntax error.

[nkaralis]

I am sorry, there was a typo in the first example.

My question is whether, in the first example, ?n should be undefined or assigned the values from the outer graph pattern in the nested FILTER (FILTER(?n = ?m)).

[afs]

My apologies - I responded with a partial draft as I had step away from the keyboard.

Whole answer:

?x :p ?n 
{ ?x :q ?m . FILTER(?n = ?m) }

This is not EXISTS specific. The algebra is:

         (join
           (bgp (triple ?x :p ?n))
           (filter (= ?n ?m)
             (bgp (triple ?x :q ?m)
        )))

(using http://sparql.org)

NB the join. Only ?m is set when the filter is executed. ?n is undefined. It is not a syntax error.

Scoping affects when assignment with AS. These forms unconditionally give a variable a binding so don't make sense when the row over which FILTER is acting potentially already has a binding for a variable. SPARQL has not change a variable binding once one if decide in a row.

VALUES can be made to work because it joins with other elements, but changes the optimization possibilities change and having different optimization inside and outside would be an implementation cost.

Inside EXISTS

 {
  ?x :p ?n
  FILTER NOT EXISTS {
    ?x :q ?m .
    { ?y :v ?m . FILTER(?n = ?m) } #is ?n still in-scope?
  }

?n is available in all sub-patterns throughout the pattern of EXISTS. This is called "deep".

[nkaralis]

Thank you for the detailed response.

You can close the issue.