Improve handling of dependencies

.github/workflows/cmake_ubuntu.yml

@@ -32,28 +32,25 @@ jobs:
     - name: Create default profile
       run: conan profile detect
 
-    - name: Create Build Environment
-      # Some projects don't allow in-source building, so create a separate build directory
-      # We'll use this as our working directory for all subsequent commands
-      run: cmake -E make_directory ${{github.workspace}}/build
-
     - name: Install conan dependencies
-      working-directory: ${{github.workspace}}/build
-      run: conan install ${{github.workspace}}/conanfile.txt -s build_type=${{env.BUILD_TYPE}} --build=missing
+      run: conan install conanfile.py -s build_type=${{env.BUILD_TYPE}} --build=missing
+
+    - name: Normalize build type
+      shell: bash
+      # The build type is Capitalized, e.g. Release, but the preset is all lowercase, e.g. release.
+      # There is no built in way to do string manipulations on GHA as far as I know.`
+      run: echo "BUILD_TYPE_LOWERCASE=$(echo "${BUILD_TYPE}" | tr '[:upper:]' '[:lower:]')" >> $GITHUB_ENV
 
     - name: Configure CMake
       shell: bash
-      working-directory: ${{github.workspace}}/build
-      run: cmake ${{github.workspace}} -DCMAKE_BUILD_TYPE=${{env.BUILD_TYPE}} -DCMAKE_TOOLCHAIN_FILE=conan_toolchain.cmake
+      run: cmake --preset conan-${{ env.BUILD_TYPE_LOWERCASE }}
 
     - name: Build
       shell: bash
-      working-directory: ${{github.workspace}}/build
-      run: cmake --build . --config ${{env.BUILD_TYPE}}
+      run: cmake --build --preset conan-${{ env.BUILD_TYPE_LOWERCASE }}
 
     - name: run test (Linux)
-      working-directory: ${{github.workspace}}/build/tests
-      run: ctest
+      run: ctest --test-dir build/${{env.BUILD_TYPE}}
 
     - name: Upload coverage reports to Codecov
       uses: codecov/codecov-action@v3

.github/workflows/cmake_windows.yml

@@ -32,24 +32,22 @@ jobs:
     - name: Create default profile
       run: conan profile detect
 
-    - name: Create Build Environment
-      # Some projects don't allow in-source building, so create a separate build directory
-      # We'll use this as our working directory for all subsequent commands
-      run: cmake -E make_directory ${{github.workspace}}/build
-
     - name: Install conan dependencies
-      working-directory: ${{github.workspace}}/build
-      run: conan install ${{github.workspace}}/conanfile.txt -s build_type=${{env.BUILD_TYPE}} --build=missing
+      run: conan install conanfile.py -s build_type=${{env.BUILD_TYPE}} --build=missing --settings:host compiler.cppstd=17
+
+    - name: Normalize build type
+      shell: bash
+      # The build type is Capitalized, e.g. Release, but the preset is all lowercase, e.g. release.
+      # There is no built in way to do string manipulations on GHA as far as I know.`
+      run: echo "BUILD_TYPE_LOWERCASE=$(echo "${BUILD_TYPE}" | tr '[:upper:]' '[:lower:]')" >> $GITHUB_ENV
 
     - name: Configure CMake
       shell: bash
-      working-directory: ${{github.workspace}}/build
-      run: cmake $GITHUB_WORKSPACE -DCMAKE_BUILD_TYPE=${{env.BUILD_TYPE}} -DCMAKE_TOOLCHAIN_FILE=conan_toolchain.cmake
+      run: cmake --preset conan-default
 
     - name: Build
-      working-directory: ${{github.workspace}}/build
       shell: bash
-      run: cmake --build . --config ${{env.BUILD_TYPE}}
+      run: cmake --build --preset conan-${{ env.BUILD_TYPE_LOWERCASE }}
 
     - name: run test (Windows)
       working-directory: ${{github.workspace}}/build

3rdparty/cppzmq/CMakeLists.txt

@@ -0,0 +1,19 @@
+find_package(ZeroMQ REQUIRED)
+
+add_library(cppzmq INTERFACE)
+
+# This library doesn't use modern targets unfortunately.
+#add_library(cppzmq::cppzmq ALIAS cppzmq)
+
+target_include_directories(cppzmq
+    INTERFACE
+        ${CMAKE_CURRENT_SOURCE_DIR}
+)
+
+if(TARGET libzmq-static)
+    target_link_libraries(cppzmq INTERFACE libzmq-static)
+elseif(TARGET libzmq)
+    target_link_libraries(cppzmq INTERFACE libzmq)
+else()
+    message(FATAL_ERROR "Unknown zeromq target name")
+endif()

3rdparty/flatbuffers/CMakeLists.txt

@@ -0,0 +1,8 @@
+add_library(flatbuffers INTERFACE)
+
+add_library(flatbuffers::flatbuffers ALIAS flatbuffers)
+
+target_include_directories(flatbuffers
+    INTERFACE
+        ${CMAKE_CURRENT_SOURCE_DIR}
+)

3rdparty/minicoro/CMakeLists.txt

@@ -0,0 +1,8 @@
+add_library(minicoro INTERFACE)
+
+add_library(minicoro::minicoro ALIAS minicoro)
+
+target_include_directories(minicoro
+    INTERFACE
+        ${CMAKE_CURRENT_SOURCE_DIR}
+)

3rdparty/minitrace/CMakeLists.txt

@@ -0,0 +1,20 @@
+add_library(minitrace STATIC
+    minitrace.cpp
+)
+
+add_library(minitrace::minitrace ALIAS minitrace)
+
+target_include_directories(minitrace
+    PUBLIC
+        ${CMAKE_CURRENT_SOURCE_DIR}
+)
+
+target_compile_definitions(minitrace
+    PRIVATE
+        MTR_ENABLED=True
+)
+
+set_property(TARGET minitrace
+    PROPERTY
+        POSITION_INDEPENDENT_CODE ON
+)

3rdparty/tinyxml2/CMakeLists.txt

@@ -0,0 +1,15 @@
+add_library(tinyxml2 STATIC
+    tinyxml2.cpp
+)
+
+add_library(tinyxml2::tinyxml2 ALIAS tinyxml2)
+
+target_include_directories(tinyxml2
+    PUBLIC
+        ${CMAKE_CURRENT_SOURCE_DIR}
+)
+
+set_property(TARGET tinyxml2
+    PROPERTY
+        POSITION_INDEPENDENT_CODE ON
+)

CMakeLists.txt

@@ -19,6 +19,17 @@ option(USE_AFLPLUSPLUS "Use AFL++ instead of libFuzzer" OFF)
 option(ENABLE_DEBUG "Enable debug build with full symbols" OFF)
 option(FORCE_STATIC_LINKING "Force static linking of all dependencies" OFF)
 
+option(USE_VENDORED_CPPZMQ "Use the bundled version of cppzmq" ON)
+option(USE_VENDORED_FLATBUFFERS "Use the bundled version of flatbuffers" ON)
+option(USE_VENDORED_LEXY "Use the bundled version of lexy" ON)
+option(USE_VENDORED_MINICORO "Use the bundled version of minicoro" ON)
+option(USE_VENDORED_MINITRACE "Use the bundled version of minitrace" ON)
+option(USE_VENDORED_TINYXML2 "Use the bundled version of tinyxml2" ON)
+
+set(BTCPP_LIB_DESTINATION     lib)
+set(BTCPP_INCLUDE_DESTINATION include)
+set(BTCPP_BIN_DESTINATION     bin)
+
 set(BASE_FLAGS "")
 
 if(ENABLE_DEBUG)
@@ -61,12 +72,6 @@ if(USE_V3_COMPATIBLE_NAMES)
     add_definitions(-DUSE_BTCPP3_OLD_NAMES)
 endif()
 
-#---- Find other packages ----
-find_package(Threads REQUIRED)
-
-
-set(BEHAVIOR_TREE_LIBRARY ${PROJECT_NAME})
-
 # Update the policy setting to avoid an error when loading the ament_cmake package
 # at the current cmake version level
 if(POLICY CMP0057)
@@ -84,19 +89,57 @@ if ( ament_cmake_FOUND )
     include(cmake/ament_build.cmake)
 else()
     message(STATUS "------------------------------------------")
-    message(STATUS "BehaviorTree is being built with conan.")
+    message(STATUS "BehaviorTree is being built without AMENT.")
     message(STATUS "------------------------------------------")
     include(cmake/conan_build.cmake)
 endif()
 
 #############################################################
-# LIBRARY
+# Handle dependencies
+
+find_package(Threads REQUIRED)
+
+if(BTCPP_GROOT_INTERFACE)
+    if(USE_VENDORED_CPPZMQ)
+        add_subdirectory(3rdparty/cppzmq)
+    else()
+        find_package(cppzmq REQUIRED)
+    endif()
+endif()
+
+if(BTCPP_SQLITE_LOGGING)
+    find_package(SQLite3 REQUIRED)
+endif()
+
+if(USE_VENDORED_FLATBUFFERS)
+    add_subdirectory(3rdparty/flatbuffers)
+else()
+    find_package(flatbuffers REQUIRED)
+endif()
 
-add_subdirectory(3rdparty/lexy)
+if(USE_VENDORED_LEXY)
+    add_subdirectory(3rdparty/lexy)
+else()
+    find_package(lexy REQUIRED)
+endif()
 
-add_library(minitrace STATIC 3rdparty/minitrace/minitrace.cpp)
-target_compile_definitions(minitrace PRIVATE MTR_ENABLED=True)
-set_property(TARGET minitrace PROPERTY POSITION_INDEPENDENT_CODE ON)
+if(USE_VENDORED_MINICORO)
+    add_subdirectory(3rdparty/minicoro)
+else()
+    find_package(minicoro REQUIRED)
+endif()
+
+if(USE_VENDORED_MINITRACE)
+    add_subdirectory(3rdparty/minitrace)
+else()
+    find_package(minitrace REQUIRED)
+endif()
+
+if(USE_VENDORED_TINYXML2)
+    add_subdirectory(3rdparty/tinyxml2)
+else()
+    find_package(tinyxml2 REQUIRED)
+endif()
 
 list(APPEND BT_SOURCE
     src/action_node.cpp
@@ -140,8 +183,6 @@ list(APPEND BT_SOURCE
     src/loggers/bt_file_logger_v2.cpp
     src/loggers/bt_minitrace_logger.cpp
     src/loggers/bt_observer.cpp
-
-    3rdparty/tinyxml2/tinyxml2.cpp
     )
 
 
@@ -179,8 +220,13 @@ target_link_libraries(${BTCPP_LIBRARY}
     PRIVATE
         Threads::Threads
         ${CMAKE_DL_LIBS}
-        $<BUILD_INTERFACE:foonathan::lexy>
-        $<BUILD_INTERFACE:minitrace>
+        foonathan::lexy
+        minitrace::minitrace
+        tinyxml2::tinyxml2
+        minicoro::minicoro
+        flatbuffers::flatbuffers
+        $<$<BOOL:${BTCPP_GROOT_INTERFACE}>:cppzmq>
+        $<$<BOOL:${BTCPP_SQLITE_LOGGING}>:SQLite::SQLite3>
     PUBLIC
         ${BTCPP_EXTRA_LIBRARIES}
 )
@@ -190,8 +236,6 @@ target_include_directories(${BTCPP_LIBRARY}
         $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
         $<INSTALL_INTERFACE:include>
     PRIVATE
-        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/3rdparty>
-        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/3rdparty/lexy/include>
         ${BTCPP_EXTRA_INCLUDE_DIRS}
     )
 

README.md

@@ -61,13 +61,15 @@ Three build systems are supported:
 
 Compiling with [conan](https://conan.io/):
 
-Assuming that you are in the **parent** directory of `BehaviorTree.CPP`:
+> [!NOTE]
+> Conan builds require CMake 3.23 or newer.
+
+Assuming that you are in the **root** directory of `BehaviorTree.CPP`:
 
 ```
-mkdir build_release
-conan install . -of build_release -s build_type=Release
-cmake -S . -B build_release -DCMAKE_TOOLCHAIN_FILE="build_release/conan_toolchain.cmake"
-cmake --build build_release --parallel
+conan install . -s build_type=Release --build=missing
+cmake --preset conan-release
+cmake --build --preset conan-release
 ```
 
 If you have dependencies such as ZeroMQ and SQlite already installed and you don't want to

cmake/FindZeroMQ.cmake

@@ -63,5 +63,13 @@ else (ZeroMQ_LIBRARIES AND ZeroMQ_INCLUDE_DIRS)
   # show the ZeroMQ_INCLUDE_DIRS and ZeroMQ_LIBRARIES variables only in the advanced view
   mark_as_advanced(ZeroMQ_INCLUDE_DIRS ZeroMQ_LIBRARIES)
 
+  if(ZeroMQ_FOUND AND NOT TARGET libzmq)
+    add_library(libzmq UNKNOWN IMPORTED)
+    set_target_properties(libzmq PROPERTIES
+      IMPORTED_LOCATION "${ZeroMQ_LIBRARY}"
+      INTERFACE_INCLUDE_DIRECTORIES "${ZeroMQ_INCLUDE_DIRS}"
+    )
+  endif()
+
 endif (ZeroMQ_LIBRARIES AND ZeroMQ_INCLUDE_DIRS)
 endif(ZeroMQ_FOUND)

cmake/ament_build.cmake

@@ -2,14 +2,6 @@
 set(CMAKE_CONFIG_PATH ${CMAKE_MODULE_PATH}  "${PROJECT_SOURCE_DIR}/cmake")
 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CONFIG_PATH}")
 
-if(BTCPP_GROOT_INTERFACE)
-    find_package(ZeroMQ REQUIRED)
-endif()
-
-if(BTCPP_SQLITE_LOGGING)
-    find_package(SQLite3 REQUIRED)
-endif()
-
 find_package(ament_index_cpp REQUIRED)
 
 set(BTCPP_EXTRA_INCLUDE_DIRS ${ZeroMQ_INCLUDE_DIRS}
@@ -23,10 +15,6 @@ set( BTCPP_EXTRA_LIBRARIES
 
 ament_export_dependencies(ament_index_cpp)
 
-set( BTCPP_LIB_DESTINATION     lib )
-set( BTCPP_INCLUDE_DESTINATION include )
-set( BTCPP_BIN_DESTINATION     bin )
-
 mark_as_advanced(
     BTCPP_EXTRA_LIBRARIES
     BTCPP_EXTRA_INCLUDE_DIRS

cmake/conan_build.cmake

@@ -1,24 +1,19 @@
 list(APPEND CMAKE_PREFIX_PATH "${CMAKE_BINARY_DIR}")
 
 if(BTCPP_GROOT_INTERFACE)
-    find_package(ZeroMQ REQUIRED)
+#    find_package(ZeroMQ REQUIRED)
     list(APPEND BTCPP_EXTRA_LIBRARIES ${ZeroMQ_LIBRARIES})
     list(APPEND BTCPP_EXTRA_INCLUDE_DIRS ${ZeroMQ_INCLUDE_DIRS})
     message(STATUS "ZeroMQ_LIBRARIES: ${ZeroMQ_LIBRARIES}")
 endif()
 
 if(BTCPP_SQLITE_LOGGING)
-    find_package(SQLite3 REQUIRED)
+#    find_package(SQLite3 REQUIRED)
     list(APPEND BTCPP_EXTRA_LIBRARIES ${SQLite3_LIBRARIES})
     list(APPEND BTCPP_EXTRA_INCLUDE_DIRS ${SQLite3_INCLUDE_DIRS})
     message(STATUS "SQLite3_LIBRARIES: ${SQLite3_LIBRARIES}")
 endif()
 
-
-set( BTCPP_LIB_DESTINATION     lib )
-set( BTCPP_INCLUDE_DESTINATION include )
-set( BTCPP_BIN_DESTINATION     bin )
-
 mark_as_advanced(
     BTCPP_EXTRA_LIBRARIES
     BTCPP_LIB_DESTINATION