python312Packages.vapoursynth-havsfunc: init at 33.0.0; python312Packages.{stgpytools,vstools,vskernels,vsexprtools,vspyplugin,vsrgtools,vmasktools,vsaa,vsscale,vsdenoise},vs-removegrain,rgsf,akarin-expr,vapoursynth-{tcanny,tedgemask,awapsharp2},warpsharp: init

pkgs/by-name/ak/akarin-expr/package.nix

@@ -0,0 +1,49 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  meson,
+  llvm_18,
+  pkg-config,
+  vapoursynth,
+  ninja,
+  libxml2,
+}:
+
+stdenv.mkDerivation {
+  pname = "akarin-expr";
+  version = "0.95";
+
+  src = fetchFromGitHub {
+    owner = "Jaded-Encoding-Thaumaturgy";
+    repo = "vapoursynth-plugin";
+    rev = "6d7c733b3014a42be75299427b5c35f56f02a47a";
+    hash = "sha256-MlQ0iOYPMAGttOVD2yF4kyZE+cpQ240DC2TBJY8/pH4=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    pkg-config
+    ninja
+  ];
+
+  buildInputs = [
+    llvm_18
+    vapoursynth
+    libxml2
+  ];
+
+  postPatch = ''
+    substituteInPlace meson.build \
+      --replace-fail \
+        "install_dir: join_paths(vapoursynth_dep.get_pkgconfig_variable('libdir'), 'vapoursynth')," \
+        "install_dir: join_paths('${placeholder "out"}/lib/', 'vapoursynth'),"
+  '';
+
+  meta = {
+    description = "Experimental VapourSynth plugin";
+    homepage = "https://github.com/Jaded-Encoding-Thaumaturgy/akarin-vapoursynth-plugin";
+    maintainers = with lib.maintainers; [ sigmanificient ];
+    license = lib.licenses.lgpl3Only;
+  };
+}

pkgs/by-name/rg/rgsf/package.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "rgsf";
+  version = "5.0.0";
+
+  src = fetchFromGitHub {
+    owner = "IFeelBloated";
+    repo = "RGSF";
+    rev = "refs/tags/r${lib.versions.major finalAttrs.version}";
+    hash = "sha256-/w4z8cv4cl+6e8n+fA9axIRVuDo6gFahxM4Rghkpbv0=";
+  };
+
+  buildPhase = ''
+    runHook preBuild
+
+    for file in RGVS Clense RemoveGrain Repair VerticalCleaner; do
+      $CXX -c -iquote . -o $file.o $file.cpp
+    done;
+
+    $CXX -shared -o rgfs.so *.o
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 rgfs.so -t $out/lib/vapoursynth
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "RGVS Single Precision";
+    homepage = "https://github.com/IFeelBloated/RGSF";
+    maintainers = with lib.maintainers; [ sigmanificient ];
+    license = lib.licenses.unfree; # unclear license
+  };
+})

pkgs/by-name/va/vapoursynth-awarpsharp2/package.nix

@@ -0,0 +1,35 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  meson,
+  pkg-config,
+  vapoursynth,
+  ninja,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  name = "vapoursynth-awarpsharp2";
+  version = "4.0.0";
+
+  src = fetchFromGitHub {
+    owner = "dubhater";
+    repo = "vapoursynth-awarpsharp2";
+    rev = "refs/tags/v${lib.versions.major finalAttrs.version}";
+    hash = "sha256-wB70gj/WJf+/vLteO05dawPPnvr/22FsDWHOYooF35g=";
+  };
+
+  buildInputs = [ vapoursynth ];
+  nativeBuildInputs = [
+    meson
+    pkg-config
+    ninja # resolves: Could not detect Ninja
+  ];
+
+  meta = {
+    description = "Sharpens by warping";
+    homepage = "https://github.com/dubhater/vapoursynth-awarpsharp2";
+    maintainers = with lib.maintainers; [ sigmanificient ];
+    license = lib.licenses.isc;
+  };
+})

pkgs/by-name/va/vapoursynth-tcanny/package.nix

@@ -0,0 +1,46 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  meson,
+  pkg-config,
+  vapoursynth,
+  ninja,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "vapoursynth-tcanny";
+  version = "14.0.0";
+
+  src = fetchFromGitHub {
+    owner = "HomeOfVapourSynthEvolution";
+    repo = "VapourSynth-TCanny";
+    rev = "refs/tags/r${lib.versions.major finalAttrs.version}";
+    hash = "sha256-UUYb9UFZ3oB05hAW/FvvM0a8nyJlQnynZSSajF2l/U0=";
+  };
+
+  postPatch = ''
+    substituteInPlace meson.build \
+      --replace-fail \
+        "install_dir = get_option('libdir') / 'vapoursynth'" \
+        "install_dir = '${placeholder "out"}/lib/vapoursynth'" \
+      --replace-fail \
+        "install_dir = vapoursynth_dep.get_variable(pkgconfig: 'libdir') / 'vapoursynth'" \
+        "install_dir = '${placeholder "out"}/lib/vapoursynth'"
+  '';
+
+  buildInputs = [ vapoursynth ];
+
+  nativeBuildInputs = [
+    meson
+    pkg-config
+    ninja # resolves: Could not detect Ninja
+  ];
+
+  meta = {
+    description = "Filter for VapourSynth";
+    homepage = "https://github.com/HomeOfVapourSynthEvolution/VapourSynth-TCanny";
+    maintainers = with lib.maintainers; [ sigmanificient ];
+    license = lib.licenses.gpl3Only;
+  };
+})

pkgs/by-name/va/vapoursynth-tedgemask/package.nix

@@ -0,0 +1,37 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  meson,
+  cmake,
+  pkg-config,
+  vapoursynth,
+  ninja,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "vapoursynth-tedgemask";
+  version = "1.0.0";
+
+  src = fetchFromGitHub {
+    owner = "dubhater";
+    repo = "vapoursynth-tedgemask";
+    rev = "refs/tags/v${lib.versions.major finalAttrs.version}";
+    hash = "sha256-7ODhuW6UAG6TltuNNOWUWE9JbB6rXYcoGp/j7okXS5I=";
+  };
+
+  buildInputs = [ vapoursynth ];
+  nativeBuildInputs = [
+    meson
+    cmake
+    pkg-config
+    ninja # resolves: Could not detect Ninja
+  ];
+
+  meta = {
+    description = "Edge detection filter";
+    homepage = "https://github.com/dubhater/vapoursynth-tedgemask";
+    maintainers = with lib.maintainers; [ sigmanificient ];
+    license = lib.licenses.gpl2Only;
+  };
+})

pkgs/by-name/vs/vs-removegrain/package.nix

@@ -0,0 +1,42 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  meson,
+  pkg-config,
+  vapoursynth,
+  ninja,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  name = "vs-removegrain";
+  version = "1.0.0-unstable-2022-10-28";
+
+  src = fetchFromGitHub {
+    owner = "vapoursynth";
+    repo = "vs-removegrain";
+    rev = "89ca38a6971e371bdce2778291393258daa5f03b";
+    hash = "sha256-UcS8EjZGCX00Pt5pAxBTzCiveTKS5yeFT+bQgXKnJ+k=";
+  };
+
+  postPatch = ''
+    substituteInPlace meson.build \
+      --replace-fail \
+        "install_dir : join_paths(vapoursynth_dep.get_pkgconfig_variable('libdir'), 'vapoursynth')," \
+        "install_dir : join_paths('${placeholder "out"}/lib/', 'vapoursynth'),"
+  '';
+
+  buildInputs = [ vapoursynth ];
+  nativeBuildInputs = [
+    meson
+    pkg-config
+    ninja # resolves: Could not detect Ninja
+  ];
+
+  meta = {
+    description = "VapourSynth port of RemoveGrain and Repair plugins from Avisynth";
+    homepage = "https://github.com/vapoursynth/vs-removegrain";
+    maintainers = with lib.maintainers; [ sigmanificient ];
+    license = lib.licenses.wtfpl;
+  };
+})

pkgs/by-name/wa/warpsharp/package.nix

@@ -0,0 +1,40 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  name = "warpsharp";
+  version = "1.0.0";
+
+  src = fetchFromGitHub {
+    owner = "IFeelBloated";
+    repo = "warpsharp";
+    rev = "refs/tags/r${lib.versions.major finalAttrs.version}";
+    hash = "sha256-ar3Dg7SpW42AEZy3H9lnj9oNQO70e6M/s+TDvcofFCg=";
+  };
+
+  buildPhase = ''
+    runHook preBuild
+
+    $CXX -shared -o warpsharp.so -iquote . Source.cpp
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 warpsharp.so -t $out/lib/
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "fp32 warpsharp for vaporsynth";
+    homepage = "https://github.com/IFeelBloated/warpsharp";
+    maintainers = with lib.maintainers; [ sigmanificient ];
+    license = lib.licenses.unfree;
+  };
+})

pkgs/development/python-modules/stgpytools/default.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  setuptools,
+}:
+
+buildPythonPackage rec {
+  pname = "stgpytools";
+  version = "1.0.0";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "Setsugennoao";
+    repo = "stgpytools";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-YxDQmtyJgYDUcvMxQ4KqA4yYLO8N4fzCyayyBnuZjf0=";
+  };
+
+  build-system = [ setuptools ];
+
+  pythonImportsCheck = [
+    "stgpytools"
+    "stgpytools.enums"
+    "stgpytools.exceptions"
+    "stgpytools.functions"
+    "stgpytools.types"
+    "stgpytools.utils"
+  ];
+
+  doCheck = false; # no tests
+
+  meta = {
+    description = "Collection of stuff that's useful in general python programming";
+    homepage = "https://github.com/Setsugennoao/stgpytools";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ sigmanificient ];
+  };
+}

pkgs/development/python-modules/vapoursynth-havsfunc/default.nix

@@ -0,0 +1,45 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  hatchling,
+  vapoursynth,
+  vsdenoise,
+  vsexprtools,
+  vsmasktools,
+  vsrgtools,
+  vstools,
+}:
+
+buildPythonPackage {
+  pname = "havsfunc";
+  version = "33.0.0";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "HomeOfVapourSynthEvolution";
+    repo = "havsfunc";
+    rev = "8707846664a692108c579780e27061ca593559f8";
+    hash = "sha256-BYcjfKHv5qgN2mjIg3jzuck0lYzTy25WvrO7S40oZdc=";
+  };
+
+  build-system = [ hatchling ];
+
+  dependencies = [
+    vapoursynth
+    vsdenoise
+    vsexprtools
+    vsmasktools
+    vsrgtools
+    vstools
+  ];
+
+  pythonRelaxDeps = [ "vapoursynth" ];
+
+  meta = {
+    description = "Holy's ported AviSynth functions for VapourSynth";
+    homepage = "https://github.com/HomeOfVapourSynthEvolution/havsfunc";
+    license = lib.licenses.unlicense;
+    maintainers = with lib.maintainers; [ sigmanificient ];
+  };
+}