chore(works): basic setup & test

Author: mydearxym

config/config.exs

@@ -69,14 +69,15 @@ config :groupher_server, :article,
   min_length: 10,
   max_length: 20_000,
   # NOTE: do not change unless you know what you are doing
-  threads: [:post, :job, :repo, :blog],
+  threads: [:post, :job, :repo, :blog, :works],
   # in this period, paged articles will sort front if non-article-author commented
   # 在此时间段内，一旦有非文章作者的用户评论，该文章就会排到前面
   active_period_days: %{
     post: 10,
     job: 10,
     repo: 10,
-    blog: 10
+    blog: 10,
+    works: 10
   },
 
   # NOTE: if you want to add/remove emotion, just edit the list below

lib/groupher_server/cms/models/works.ex

@@ -0,0 +1,52 @@
+defmodule GroupherServer.CMS.Model.Works do
+  @moduledoc false
+  alias __MODULE__
+
+  use Ecto.Schema
+  use Accessible
+
+  import Ecto.Changeset
+  import GroupherServer.CMS.Helper.Macros
+
+  alias GroupherServer.CMS
+  alias CMS.Model.Embeds
+
+  alias Helper.HTML
+
+  @timestamps_opts [type: :utc_datetime_usec]
+
+  @required_fields ~w(title digest)a
+  @article_cast_fields general_article_cast_fields()
+  @optional_fields @article_cast_fields
+
+  @type t :: %Works{}
+  schema "cms_works" do
+    article_tags_field(:works)
+    article_communities_field(:works)
+    general_article_fields(:works)
+  end
+
+  @doc false
+  def changeset(%Works{} = works, attrs) do
+    works
+    |> cast(attrs, @optional_fields ++ @required_fields)
+    |> validate_required(@required_fields)
+    |> cast_embed(:meta, required: false, with: &Embeds.ArticleMeta.changeset/2)
+    |> generl_changeset
+  end
+
+  @doc false
+  def update_changeset(%Works{} = works, attrs) do
+    works
+    |> cast(attrs, @optional_fields ++ @required_fields)
+    |> generl_changeset
+  end
+
+  defp generl_changeset(changeset) do
+    changeset
+    |> validate_length(:title, min: 3, max: 50)
+    |> cast_embed(:emotions, with: &Embeds.ArticleEmotion.changeset/2)
+    |> validate_length(:link_addr, min: 5, max: 400)
+    |> HTML.safe_string(:body)
+  end
+end

lib/groupher_server/cms/models/works_document.ex

@@ -0,0 +1,47 @@
+defmodule GroupherServer.CMS.Model.WorksDocument do
+  @moduledoc """
+  mainly for full-text search
+  """
+  alias __MODULE__
+
+  use Ecto.Schema
+  use Accessible
+
+  import Ecto.Changeset
+  import Helper.Utils, only: [get_config: 2]
+
+  alias GroupherServer.CMS
+  alias CMS.Model.Works
+
+  @timestamps_opts [type: :utc_datetime_usec]
+
+  @max_body_length get_config(:article, :max_length)
+  @min_body_length get_config(:article, :min_length)
+
+  @required_fields ~w(body body_html works_id)a
+  @optional_fields []
+
+  @type t :: %WorksDocument{}
+  schema "works_documents" do
+    belongs_to(:works, Works, foreign_key: :works_id)
+
+    field(:body, :string)
+    field(:body_html, :string)
+    field(:toc, :map)
+  end
+
+  @doc false
+  def changeset(%WorksDocument{} = works, attrs) do
+    works
+    |> cast(attrs, @optional_fields ++ @required_fields)
+    |> validate_required(@required_fields)
+    |> validate_length(:body, min: @min_body_length, max: @max_body_length)
+  end
+
+  @doc false
+  def update_changeset(%WorksDocument{} = works, attrs) do
+    works
+    |> cast(attrs, @optional_fields ++ @required_fields)
+    |> validate_length(:body, min: @min_body_length, max: @max_body_length)
+  end
+end

test/groupher_server/cms/articles/works_test.exs

@@ -0,0 +1,197 @@
+defmodule GroupherServer.Test.Articles.Works do
+  use GroupherServer.TestTools
+
+  alias GroupherServer.{CMS, Repo}
+  alias Helper.Converter.{EditorToHTML, HtmlSanitizer}
+
+  alias EditorToHTML.{Class, Validator}
+  alias CMS.Model.{Author, Works, Community, ArticleDocument, WorksDocument}
+  alias Helper.ORM
+
+  @root_class Class.article()
+  @last_year Timex.shift(Timex.beginning_of_year(Timex.now()), days: -3, seconds: -1)
+
+  setup do
+    {:ok, user} = db_insert(:user)
+    {:ok, user2} = db_insert(:user)
+    {:ok, community} = db_insert(:community)
+
+    works_attrs = mock_attrs(:works, %{community_id: community.id})
+
+    {:ok, ~m(user user2 community works_attrs)a}
+  end
+
+  describe "[cms workss curd]" do
+    test "can create works with valid attrs", ~m(user community works_attrs)a do
+      assert {:error, _} = ORM.find_by(Author, user_id: user.id)
+      {:ok, works} = CMS.create_article(community, :works, works_attrs, user)
+      works = Repo.preload(works, :document)
+
+      body_map = Jason.decode!(works.document.body)
+
+      assert works.meta.thread == "WORKS"
+
+      assert works.title == works_attrs.title
+      assert body_map |> Validator.is_valid()
+
+      assert works.document.body_html
+             |> String.contains?(~s(<div class="#{@root_class["viewer"]}">))
+
+      assert works.document.body_html |> String.contains?(~s(<p id="block-))
+
+      paragraph_text = body_map["blocks"] |> List.first() |> get_in(["data", "text"])
+      assert works.digest == paragraph_text |> HtmlSanitizer.strip_all_tags()
+    end
+
+    test "created works should have a acitve_at field, same with inserted_at",
+         ~m(user community works_attrs)a do
+      {:ok, works} = CMS.create_article(community, :works, works_attrs, user)
+
+      assert works.active_at == works.inserted_at
+    end
+
+    test "read works should update views and meta viewed_user_list",
+         ~m(works_attrs community user user2)a do
+      {:ok, works} = CMS.create_article(community, :works, works_attrs, user)
+      {:ok, _} = CMS.read_article(:works, works.id, user)
+      {:ok, _created} = ORM.find(Works, works.id)
+
+      # same user duplicate case
+      {:ok, _} = CMS.read_article(:works, works.id, user)
+      {:ok, created} = ORM.find(Works, works.id)
+
+      assert created.meta.viewed_user_ids |> length == 1
+      assert user.id in created.meta.viewed_user_ids
+
+      {:ok, _} = CMS.read_article(:works, works.id, user2)
+      {:ok, created} = ORM.find(Works, works.id)
+
+      assert created.meta.viewed_user_ids |> length == 2
+      assert user.id in created.meta.viewed_user_ids
+      assert user2.id in created.meta.viewed_user_ids
+    end
+
+    test "read works should contains viewer_has_xxx state",
+         ~m(works_attrs community user user2)a do
+      {:ok, works} = CMS.create_article(community, :works, works_attrs, user)
+      {:ok, works} = CMS.read_article(:works, works.id, user)
+
+      assert not works.viewer_has_collected
+      assert not works.viewer_has_upvoted
+      assert not works.viewer_has_reported
+
+      {:ok, works} = CMS.read_article(:works, works.id)
+
+      assert not works.viewer_has_collected
+      assert not works.viewer_has_upvoted
+      assert not works.viewer_has_reported
+
+      {:ok, works} = CMS.read_article(:works, works.id, user2)
+
+      assert not works.viewer_has_collected
+      assert not works.viewer_has_upvoted
+      assert not works.viewer_has_reported
+
+      {:ok, _} = CMS.upvote_article(:works, works.id, user)
+      {:ok, _} = CMS.collect_article(:works, works.id, user)
+      {:ok, _} = CMS.report_article(:works, works.id, "reason", "attr_info", user)
+
+      {:ok, works} = CMS.read_article(:works, works.id, user)
+
+      assert works.viewer_has_collected
+      assert works.viewer_has_upvoted
+      assert works.viewer_has_reported
+    end
+
+    test "create works with an exsit community fails", ~m(user)a do
+      invalid_attrs = mock_attrs(:works, %{community_id: non_exsit_id()})
+      ivalid_community = %Community{id: non_exsit_id()}
+
+      assert {:error, _} = CMS.create_article(ivalid_community, :works, invalid_attrs, user)
+    end
+  end
+
+  describe "[cms works sink/undo_sink]" do
+    test "if a works is too old, read works should update can_undo_sink flag",
+         ~m(user community works_attrs)a do
+      {:ok, works} = CMS.create_article(community, :works, works_attrs, user)
+
+      assert works.meta.can_undo_sink
+
+      {:ok, works_last_year} = db_insert(:works, %{title: "last year", inserted_at: @last_year})
+      {:ok, works_last_year} = CMS.read_article(:works, works_last_year.id)
+      assert not works_last_year.meta.can_undo_sink
+
+      {:ok, works_last_year} = CMS.read_article(:works, works_last_year.id, user)
+      assert not works_last_year.meta.can_undo_sink
+    end
+
+    test "can sink a works", ~m(user community works_attrs)a do
+      {:ok, works} = CMS.create_article(community, :works, works_attrs, user)
+      assert not works.meta.is_sinked
+
+      {:ok, works} = CMS.sink_article(:works, works.id)
+      assert works.meta.is_sinked
+      assert works.active_at == works.inserted_at
+    end
+
+    test "can undo sink works", ~m(user community works_attrs)a do
+      {:ok, works} = CMS.create_article(community, :works, works_attrs, user)
+      {:ok, works} = CMS.sink_article(:works, works.id)
+      assert works.meta.is_sinked
+      assert works.meta.last_active_at == works.active_at
+
+      {:ok, works} = CMS.undo_sink_article(:works, works.id)
+      assert not works.meta.is_sinked
+      assert works.active_at == works.meta.last_active_at
+    end
+
+    test "can not undo sink to old works", ~m()a do
+      {:ok, works_last_year} = db_insert(:works, %{title: "last year", inserted_at: @last_year})
+
+      {:error, reason} = CMS.undo_sink_article(:works, works_last_year.id)
+      is_error?(reason, :undo_sink_old_article)
+    end
+  end
+
+  describe "[cms works document]" do
+    test "will create related document after create", ~m(user community works_attrs)a do
+      {:ok, works} = CMS.create_article(community, :works, works_attrs, user)
+      {:ok, works} = CMS.read_article(:works, works.id)
+      assert not is_nil(works.document.body_html)
+      {:ok, works} = CMS.read_article(:works, works.id, user)
+      assert not is_nil(works.document.body_html)
+
+      {:ok, article_doc} = ORM.find_by(ArticleDocument, %{article_id: works.id, thread: "WORKS"})
+      {:ok, works_doc} = ORM.find_by(WorksDocument, %{works_id: works.id})
+
+      assert works.document.body == works_doc.body
+      assert article_doc.body == works_doc.body
+    end
+
+    test "delete works should also delete related document", ~m(user community works_attrs)a do
+      {:ok, works} = CMS.create_article(community, :works, works_attrs, user)
+      {:ok, _article_doc} = ORM.find_by(ArticleDocument, %{article_id: works.id, thread: "WORKS"})
+      {:ok, _works_doc} = ORM.find_by(WorksDocument, %{works_id: works.id})
+
+      {:ok, _} = CMS.delete_article(works)
+
+      {:error, _} = ORM.find(Works, works.id)
+      {:error, _} = ORM.find_by(ArticleDocument, %{article_id: works.id, thread: "WORKS"})
+      {:error, _} = ORM.find_by(WorksDocument, %{works_id: works.id})
+    end
+
+    test "update works should also update related document", ~m(user community works_attrs)a do
+      {:ok, works} = CMS.create_article(community, :works, works_attrs, user)
+
+      body = mock_rich_text(~s(new content))
+      {:ok, works} = CMS.update_article(works, %{body: body})
+
+      {:ok, article_doc} = ORM.find_by(ArticleDocument, %{article_id: works.id, thread: "WORKS"})
+      {:ok, works_doc} = ORM.find_by(WorksDocument, %{works_id: works.id})
+
+      assert String.contains?(works_doc.body, "new content")
+      assert String.contains?(article_doc.body, "new content")
+    end
+  end
+end

test/support/factory.ex

@@ -219,6 +219,26 @@ defmodule GroupherServer.Support.Factory do
     }
   end
 
+  defp mock_meta(:works) do
+    text = Faker.Lorem.sentence(%Range{first: 80, last: 120})
+
+    %{
+      meta: @default_article_meta |> Map.merge(%{thread: "BLOG"}),
+      title: String.slice(text, 1, 49),
+      body: mock_rich_text(),
+      digest: String.slice(text, 1, 150),
+      # length: String.length(text),
+      author: mock(:author),
+      views: Enum.random(0..2000),
+      original_community: mock(:community),
+      communities: [
+        mock(:community)
+      ],
+      emotions: @default_emotions,
+      active_at: Timex.shift(Timex.now(), seconds: +1)
+    }
+  end
+
   defp mock_meta(:comment) do
     # text = Faker.Lorem.sentence(%Range{first: 30, last: 80})