1.0.7 cannot find opencl-clang on system

[tripzero]

find_library() for opencl-clang appears to be failing. I have libopencl-clang.so and libopencl-clang.so.8 on my system in /usr/lib64

[dbermond]

Same issue here on Arch Linux. It's caused by the following commit: 48ef207.

The problem is not the find_library cmake function. It detects fine libopencl-clang.so.

The problem is how the cmake conditional is testing if the library is found or not. The issue can be fixed by the following modification:

diff -Naurp a/IGC/BiFModule/CMakeLists.txt b/IGC/BiFModule/CMakeLists.txt
--- a/IGC/BiFModule/CMakeLists.txt	2019-06-03 17:27:09.604195718 +0000
+++ b/IGC/BiFModule/CMakeLists.txt	2019-06-03 16:41:52.000000000 +0000
@@ -60,7 +60,7 @@ endif()
 ###
 
 ### Check by order first available way to link with opencl-clang
-if(${CCLANG_FROM_SYSTEM})
+if(CCLANG_FROM_SYSTEM)
   message(STATUS "[IGC\\BiFModule] : opencl-clang will be taken from system")
 else()
   if(NOT DEFINED CCLANG_BUILD_PREBUILDS_DIR)
@@ -103,7 +103,7 @@ endif()
 ###
 
 #1. CCLANG_FROM_SYSTEM - use installed on system opencl-clang toolchain
-if(${CCLANG_FROM_SYSTEM})
+if(CCLANG_FROM_SYSTEM)
   find_library(SYSTEM_COMMON_CLANG ${COMMON_CLANG_LIBRARY_NAME})
   
   add_library(opencl-clang-lib SHARED IMPORTED GLOBAL)

[paigeale]

Thank you Kevron for reporting this issue and for Daniel for providing a suggested fix. @lwesiers could you please address this issue related to your commit?

[dbermond]

After fixing the issue with the above patch, another error appears at link time when using system opencl-clang:

[ 89%] Linking CXX shared library /build/intel-graphics-compiler/src/intel-graphics-compiler-1.0.7/igc-install/Release/libigdfcl.so
/usr/bin/ld: CMakeFiles/fcl_dll.dir/OCLFE/igd_fcl_mcl/source/clang_tb.cpp.o: in function `TC::CClangTranslationBlock::TranslateClang(TC::TranslateClangArgs const*, TC::STB_TranslateOutputArgs*, std::__cxx11::basic_string<char, std::char_traits<char>, std::allocator<char> >&, char const*)':
/build/intel-graphics-compiler/src/intel-graphics-compiler-1.0.7/IGC/OCLFE/igd_fcl_mcl/source/clang_tb.cpp:1437: undefined reference to `Compile'
collect2: error: ld returned 1 exit status
make[2]: *** [IGC/CMakeFiles/fcl_dll.dir/build.make:281: /build/intel-graphics-compiler/src/intel-graphics-compiler-1.0.7/igc-install/Release/libigdfcl.so.1.0.7] Error 1
make[1]: *** [CMakeFiles/Makefile2:206: IGC/CMakeFiles/fcl_dll.dir/all] Error 2
make: *** [Makefile:152: all] Error 2

A git bisect shows that the same commit 48ef207 is responsible for this error.

[tripzero]

confirmed @dbermond's fix and second error.

[dbermond]

@tripzero There is already a commit that fixes the link error: 55f558f. Applying it fixes linking for me.

But it shows even another error at make install time for me:

CMake Error at IGC/BiFModule/cmake_install.cmake:85 (file):
  file INSTALL cannot find "/usr/bin/clang-8-8".
Call Stack (most recent call first):
  IGC/cmake_install.cmake:231 (include)
  cmake_install.cmake:42 (include)


make: *** [Makefile:108: install] Error 1

It was building fine in version 1.0.6.

[dbermond]

Version 1.0.7 and the current git master builds fine for me using system opencl-clang with the following modifications. If the git master changes are acceptable by the developers I can open a pull request.

For 1.0.7:

diff -Naurp a/IGC/BiFModule/CMakeLists.txt b/IGC/BiFModule/CMakeLists.txt
--- a/IGC/BiFModule/CMakeLists.txt	2019-06-03 17:27:09.604195718 +0000
+++ b/IGC/BiFModule/CMakeLists.txt	2019-06-04 01:11:06.739758208 +0000
@@ -60,7 +60,7 @@ endif()
 ###
 
 ### Check by order first available way to link with opencl-clang
-if(${CCLANG_FROM_SYSTEM})
+if(CCLANG_FROM_SYSTEM)
   message(STATUS "[IGC\\BiFModule] : opencl-clang will be taken from system")
 else()
   if(NOT DEFINED CCLANG_BUILD_PREBUILDS_DIR)
@@ -103,7 +103,7 @@ endif()
 ###
 
 #1. CCLANG_FROM_SYSTEM - use installed on system opencl-clang toolchain
-if(${CCLANG_FROM_SYSTEM})
+if(CCLANG_FROM_SYSTEM)
   find_library(SYSTEM_COMMON_CLANG ${COMMON_CLANG_LIBRARY_NAME})
   
   add_library(opencl-clang-lib SHARED IMPORTED GLOBAL)
@@ -127,12 +127,6 @@ elseif(${CCLANG_BUILD_PREBUILDS})
   add_library(opencl-clang-lib SHARED IMPORTED GLOBAL)
   set_property(TARGET opencl-clang-lib PROPERTY "IMPORTED_LOCATION" "${CCLANG_BUILD_PREBUILDS_DIR}/${COMMON_CLANG_LIB_FULL_NAME}")
   
-  if(${LLVM_VERSION_MINOR} EQUAL 0 AND ${LLVM_VERSION_PATCH} EQUAL 0)
-    set_property(TARGET opencl-clang-lib PROPERTY "IMPORTED_SONAME" "${COMMON_CLANG_LIB_FULL_NAME}.${LLVM_VERSION_MAJOR}")
-  else()
-    set_property(TARGET opencl-clang-lib PROPERTY "IMPORTED_SONAME" "${COMMON_CLANG_LIB_FULL_NAME}.${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}")
-  endif()
-
   add_executable(clang-tool IMPORTED GLOBAL)
   set_property(TARGET clang-tool PROPERTY "IMPORTED_LOCATION" "${CCLANG_BUILD_PREBUILDS_DIR}/clang${CMAKE_EXECUTABLE_SUFFIX}")
 
@@ -146,13 +140,20 @@ elseif(${CCLANG_BUILD_INTREE_LLVM})
 endif()
 ###
 
-if(UNIX AND NOT ${CCLANG_FROM_SYSTEM})
-  install(FILES $<TARGET_FILE:opencl-clang-lib> DESTINATION ${CMAKE_INSTALL_FULL_LIBDIR} COMPONENT igc-opencl)
-  install(FILES $<TARGET_SONAME_FILE:opencl-clang-lib> DESTINATION ${CMAKE_INSTALL_FULL_LIBDIR} COMPONENT igc-opencl)
-  
-  install(FILES $<TARGET_FILE:clang-tool> DESTINATION ${CMAKE_INSTALL_FULL_BINDIR} COMPONENT igc-opencl-devel)
-  install(FILES $<TARGET_FILE:clang-tool>-${LLVM_VERSION_MAJOR} DESTINATION ${CMAKE_INSTALL_FULL_BINDIR} COMPONENT igc-opencl-devel)
-  install(FILES ${opencl-header} DESTINATION ${CMAKE_INSTALL_FULL_INCLUDEDIR} COMPONENT igc-opencl-devel)
+if(UNIX)
+  if(${LLVM_VERSION_MINOR} EQUAL 0 AND ${LLVM_VERSION_PATCH} EQUAL 0)
+    set_property(TARGET opencl-clang-lib PROPERTY "IMPORTED_SONAME" "${COMMON_CLANG_LIB_FULL_NAME}.${LLVM_VERSION_MAJOR}")
+  else()
+    set_property(TARGET opencl-clang-lib PROPERTY "IMPORTED_SONAME" "${COMMON_CLANG_LIB_FULL_NAME}.${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}")
+  endif()
+  if (NOT CCLANG_FROM_SYSTEM)
+    install(FILES $<TARGET_FILE:opencl-clang-lib> DESTINATION ${CMAKE_INSTALL_FULL_LIBDIR} COMPONENT igc-opencl)
+    install(FILES $<TARGET_SONAME_FILE:opencl-clang-lib> DESTINATION ${CMAKE_INSTALL_FULL_LIBDIR} COMPONENT igc-opencl)
+    
+    install(FILES $<TARGET_FILE:clang-tool> DESTINATION ${CMAKE_INSTALL_FULL_BINDIR} COMPONENT igc-opencl-devel)
+    install(FILES $<TARGET_FILE:clang-tool>-${LLVM_VERSION_MAJOR} DESTINATION ${CMAKE_INSTALL_FULL_BINDIR} COMPONENT igc-opencl-devel)
+    install(FILES ${opencl-header} DESTINATION ${CMAKE_INSTALL_FULL_INCLUDEDIR} COMPONENT igc-opencl-devel)
+  endif()
 endif()
 
 #NEO needs to change the target name

For the current git master:

diff -Naurp a/IGC/BiFModule/CMakeLists.txt b/IGC/BiFModule/CMakeLists.txt
--- a/IGC/BiFModule/CMakeLists.txt	2019-06-04 01:26:39.000000000 +0000
+++ b/IGC/BiFModule/CMakeLists.txt	2019-06-04 01:28:34.673446248 +0000
@@ -60,7 +60,7 @@ endif()
 ###
 
 ### Check by order first available way to link with opencl-clang
-if(${CCLANG_FROM_SYSTEM})
+if(CCLANG_FROM_SYSTEM)
   message(STATUS "[IGC\\BiFModule] : opencl-clang will be taken from system")
 else()
   if(NOT DEFINED CCLANG_BUILD_PREBUILDS_DIR)
@@ -103,7 +103,7 @@ endif()
 ###
 
 #1. CCLANG_FROM_SYSTEM - use installed on system opencl-clang toolchain
-if(${CCLANG_FROM_SYSTEM})
+if(CCLANG_FROM_SYSTEM)
   find_library(SYSTEM_COMMON_CLANG ${COMMON_CLANG_LIBRARY_NAME})
   
   add_library(opencl-clang-lib SHARED IMPORTED GLOBAL)
@@ -140,19 +140,20 @@ elseif(${CCLANG_BUILD_INTREE_LLVM})
 endif()
 ###
 
-if(UNIX AND NOT ${CCLANG_FROM_SYSTEM})
+if(UNIX)
   if(${LLVM_VERSION_MINOR} EQUAL 0 AND ${LLVM_VERSION_PATCH} EQUAL 0)
     set_property(TARGET opencl-clang-lib PROPERTY "IMPORTED_SONAME" "${COMMON_CLANG_LIB_FULL_NAME}.${LLVM_VERSION_MAJOR}")
   else()
     set_property(TARGET opencl-clang-lib PROPERTY "IMPORTED_SONAME" "${COMMON_CLANG_LIB_FULL_NAME}.${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}")
   endif()
-
-  install(FILES $<TARGET_FILE:opencl-clang-lib> DESTINATION ${CMAKE_INSTALL_FULL_LIBDIR} COMPONENT igc-opencl)
-  install(FILES $<TARGET_SONAME_FILE:opencl-clang-lib> DESTINATION ${CMAKE_INSTALL_FULL_LIBDIR} COMPONENT igc-opencl)
-  
-  install(FILES $<TARGET_FILE:clang-tool> DESTINATION ${CMAKE_INSTALL_FULL_BINDIR} COMPONENT igc-opencl-devel)
-  install(FILES $<TARGET_FILE:clang-tool>-${LLVM_VERSION_MAJOR} DESTINATION ${CMAKE_INSTALL_FULL_BINDIR} COMPONENT igc-opencl-devel)
-  install(FILES ${opencl-header} DESTINATION ${CMAKE_INSTALL_FULL_INCLUDEDIR} COMPONENT igc-opencl-devel)
+  if (NOT CCLANG_FROM_SYSTEM)
+    install(FILES $<TARGET_FILE:opencl-clang-lib> DESTINATION ${CMAKE_INSTALL_FULL_LIBDIR} COMPONENT igc-opencl)
+    install(FILES $<TARGET_SONAME_FILE:opencl-clang-lib> DESTINATION ${CMAKE_INSTALL_FULL_LIBDIR} COMPONENT igc-opencl)
+    
+    install(FILES $<TARGET_FILE:clang-tool> DESTINATION ${CMAKE_INSTALL_FULL_BINDIR} COMPONENT igc-opencl-devel)
+    install(FILES $<TARGET_FILE:clang-tool>-${LLVM_VERSION_MAJOR} DESTINATION ${CMAKE_INSTALL_FULL_BINDIR} COMPONENT igc-opencl-devel)
+    install(FILES ${opencl-header} DESTINATION ${CMAKE_INSTALL_FULL_INCLUDEDIR} COMPONENT igc-opencl-devel)
+  endif()
 endif()
 
 #NEO needs to change the target name

[lwesiers]

@dbermond yes, please open PR with proposed fix for git master - I will approve it. Sorry for the build issue in latest code. We are currently in process of upgrading our build system - such issues will be caught more quickly in our pre-commit process and will not reach the github.

[dbermond]

@lwesiers Thank you for the answer. Pull request created.