How to pass this fd command to consult?

[rieje]

Disclaimer: not a programmer (only use Emacs for org-mode)

How to pass the following fd command to consult?

fd -d 1 .el$ ~/.config/emacs ~/.config/emacs/elisp

Basically, I want to trigger a key to fuzzy select list of matching files (important Emacs config files) to open as file buffer. I believe consult-fd-args seems to be relevant here but I'm not able to construct a proper argument for it and/or consult-fd.

Any help is much appreciated. I might also want to combine the results of this command and another fd command together as one set of files to select with consult.

[mohittguptaa]

consult-fd is designed for interactive searching, where what you type becomes the fd pattern. For a fixed command like yours, it's simpler to run fd once and hand the results to completing-read. Consult/Vertico (or whatever completion UI you use) gives you fuzzy selection automatically.

Put this in your config:

(defun my/config-files ()
  "Return a list of my important Emacs config files."
  (mapcar #'abbreviate-file-name
          (process-lines "fd" "-d" "1" "\\.el$"
                         (expand-file-name "~/.config/emacs")
                         (expand-file-name "~/.config/emacs/elisp"))))

(defun my/open-config-file ()
  "Fuzzy-pick one of my config files and open it."
  (interactive)
  (find-file (completing-read "Config file: " (my/config-files) nil t)))

(keymap-global-set "C-c e" #'my/open-config-file)

Now C-c e shows the list and opens the file you pick.

Notes:

• In elisp the regex .el$ is written "\\.el$". The escaped dot matches only a literal ..
• expand-file-name turns ~ into a full path, because fd doesn't expand ~ when called from Emacs.

Combining several fd commands, as you mentioned: just append the lists:

(defun my/config-files ()
  (mapcar #'abbreviate-file-name
          (append
           (process-lines "fd" "-d" "1" "\\.el$"
                          (expand-file-name "~/.config/emacs")
                          (expand-file-name "~/.config/emacs/elisp"))
           (process-lines "fd" "-e" "org" "." (expand-file-name "~/org")))))

(If you're on Emacs older than 29, use (global-set-key (kbd "C-c e") #'my/open-config-file) instead of keymap-global-set.)