Bug 1802163: Improve dragging of file URLs on macOS. r=mac-reviewers,mstange

This patch fixes dragging of images to Photos.app and Pages.app (possibly others, more testing necessary). It is also the first time that we support dragging of images into Apple's drag & drop test app at https://developer.apple.com/documentation/appkit/supporting-drag-and-drop-through-file-promises?language=objc, which resolves bug 1450419 without actually implementing NSFilePromiseProvider. NSFilePromiseProvider is not easily implemented since it expects to be the only data provider for a drag session, which means that we wouldn't be able to write out other pasteboard types to the pasteboard like we have traditionally done and that third-party apps are relying on.

If the set of Gecko dragging transferables contains a transferable with flavor kFilePromiseMime, we will now create a file even if the pasteboard that's passed to -[NSPasteboardItemDataProvider pasteboard:item:provideDataForType:] does not come with a "paste location". Additionally, we will now write the path of the paste location into the pasteboard for type kUTTypeFileURL. In the past, we would only create a file for such transferables if the pasteboard provided the location to store the file, and we would not write a kUTTypeFileURL value - instead, we would write two empty strings for the types kPasteboardTypeFileURLPromise and kPasteboardTypeFilePromiseContent. We no longer write those empty strings.

Differential Revision: https://phabricator.services.mozilla.com/D260021

Author: sapohl

widget/cocoa/nsClipboard.mm

@@ -748,6 +748,17 @@
                                forKey:urlPromise];
       [pasteboardOutputDict setObject:[NSArray arrayWithObject:@""]
                                forKey:urlPromiseContent];
+      NSString* fileUTType =
+          [UTIHelper stringFromPboardType:(NSString*)kUTTypeFileURL];
+      // Ideally, we would make use of `NSFilePromiseProvider` for file
+      // promises. However, we cannot easily support this since
+      // `NSFilePromiseProvider` expects to be the only data provider for the
+      // drag session. This means that no other data types could be written out
+      // to the drag pasteboard simultaneously without major rework. We work
+      // around this by setting an empty string here for `kUTTypeFileURL` as our
+      // signal to create the file once the drag completes, replicating the file
+      // promise behavior.
+      [pasteboardOutputDict setObject:@"" forKey:fileUTType];
     } else if (flavorStr.EqualsLiteral(kURLMime)) {
       nsCOMPtr<nsISupports> genericURL;
       rv = aTransferable->GetTransferData(flavorStr.get(),

widget/cocoa/nsCocoaWindow.mm

@@ -162,6 +162,7 @@ static void RollUpPopups(nsIRollupListener::AllowAnimations aAllowAnimations =
 }
 
 extern nsIArray* gDraggedTransferables;
+extern bool gCreatedPromisedFile;
 ChildView* ChildViewMouseTracker::sLastMouseEventView = nil;
 NSEvent* ChildViewMouseTracker::sLastMouseMoveEvent = nil;
 NSWindow* ChildViewMouseTracker::sWindowUnderMouse = nil;
@@ -3706,8 +3707,6 @@ - (void)draggingSession:(NSDraggingSession*)aSession
   MOZ_RELEASE_ASSERT(NS_IsMainThread());
 #endif
 
-  gDraggedTransferables = nullptr;
-
   NSEvent* currentEvent = [NSApp currentEvent];
   gUserCancelledDrag = ([currentEvent type] == NSEventTypeKeyDown &&
                         [currentEvent keyCode] == kVK_Escape);
@@ -3801,20 +3800,20 @@ - (void)draggingSession:(NSDraggingSession*)aSession
   NS_OBJC_END_TRY_IGNORE_BLOCK;
 }
 
-// Get the paste location from the low level pasteboard.
-static CFTypeRefPtr<CFURLRef> GetPasteLocation(NSPasteboard* aPasteboard) {
-  PasteboardRef pboardRef = nullptr;
-  PasteboardCreate((CFStringRef)[aPasteboard name], &pboardRef);
-  if (!pboardRef) {
-    return nullptr;
+static NSURL* GetPasteLocation() {
+  // First, attempt to get the paste location from the pasteboard.
+  NSPasteboard* pasteboard =
+      [NSPasteboard pasteboardWithName:NSPasteboardNameDrag];
+  NSString* pasteLocation =
+      [pasteboard stringForType:@"com.apple.pastelocation"];
+  if (pasteLocation) {
+    return [NSURL fileURLWithPath:pasteLocation];
   }
-
-  auto pasteBoard = CFTypeRefPtr<PasteboardRef>::WrapUnderCreateRule(pboardRef);
-  PasteboardSynchronize(pasteBoard.get());
-
-  CFURLRef urlRef = nullptr;
-  PasteboardCopyPasteLocation(pasteBoard.get(), &urlRef);
-  return CFTypeRefPtr<CFURLRef>::WrapUnderCreateRule(urlRef);
+  // If no paste location was present on the pasteboard, fall back to a temp
+  // directory instead.
+  return [NSURL
+      fileURLWithPath:[NSTemporaryDirectory()
+                          stringByAppendingPathComponent:@"mozDraggedFiles"]];
 }
 
 // NSPasteboardItemDataProvider
@@ -3862,47 +3861,20 @@ - (void)pasteboard:(NSPasteboard*)aPasteboard
                                   stringFromPboardType:kPublicUrlPboardType]] ||
           [curType isEqualToString:[UTIHelper stringFromPboardType:
                                                   kPublicUrlNamePboardType]] ||
-          [curType
-              isEqualToString:[UTIHelper
-                                  stringFromPboardType:(NSString*)
-                                                           kUTTypeFileURL]]) {
+          ([curType
+               isEqualToString:[UTIHelper
+                                   stringFromPboardType:(NSString*)
+                                                            kUTTypeFileURL]] &&
+           ![[pasteboardOutputDict valueForKey:curType] isEqualToString:@""])) {
         [aPasteboard setString:[pasteboardOutputDict valueForKey:curType]
                        forType:curType];
       } else if ([curType isEqualToString:[UTIHelper
                                               stringFromPboardType:
-                                                  kUrlsWithTitlesPboardType]]) {
-        [aPasteboard setPropertyList:[pasteboardOutputDict valueForKey:curType]
-                             forType:curType];
-      } else if ([curType
-                     isEqualToString:[UTIHelper stringFromPboardType:
-                                                    NSPasteboardTypeHTML]]) {
-        [aPasteboard setString:(nsClipboard::WrapHtmlForSystemPasteboard(
-                                   [pasteboardOutputDict valueForKey:curType]))
-                       forType:curType];
-      } else if ([curType
-                     isEqualToString:[UTIHelper stringFromPboardType:
-                                                    NSPasteboardTypeTIFF]] ||
-                 [curType isEqualToString:[UTIHelper
-                                              stringFromPboardType:
-                                                  kMozCustomTypesPboardType]]) {
-        [aPasteboard setData:[pasteboardOutputDict valueForKey:curType]
-                     forType:curType];
-      } else if ([curType
-                     isEqualToString:[UTIHelper stringFromPboardType:
-                                                    kMozFileUrlsPboardType]]) {
-        [aPasteboard writeObjects:[pasteboardOutputDict valueForKey:curType]];
-      } else if ([curType
-                     isEqualToString:
-                         [UTIHelper
-                             stringFromPboardType:
-                                 (NSString*)kPasteboardTypeFileURLPromise]]) {
-        CFTypeRefPtr<CFURLRef> url = GetPasteLocation(aPasteboard);
-        if (!url) {
-          continue;
-        }
-
+                                                  (NSString*)kUTTypeFileURL]] &&
+                 !gCreatedPromisedFile) {
+        NSURL* url = GetPasteLocation();
         nsCOMPtr<nsILocalFileMac> macLocalFile;
-        if (NS_FAILED(NS_NewLocalFileWithCFURL(url.get(),
+        if (NS_FAILED(NS_NewLocalFileWithCFURL((__bridge CFURLRef)url,
                                                getter_AddRefs(macLocalFile)))) {
           NS_ERROR("failed NS_NewLocalFileWithCFURL");
           continue;
@@ -3931,12 +3903,46 @@ - (void)pasteboard:(NSPasteboard*)aPasteboard
           // Now request the kFilePromiseMime data, which will invoke the data
           // provider. If successful, the file will have been created.
           nsCOMPtr<nsISupports> fileDataPrimitive;
-          Unused << item->GetTransferData(kFilePromiseMime,
-                                          getter_AddRefs(fileDataPrimitive));
+          if (NS_FAILED(item->GetTransferData(
+                  kFilePromiseMime, getter_AddRefs(fileDataPrimitive)))) {
+            continue;
+          }
+          nsCOMPtr<nsIFile> file = do_QueryInterface(fileDataPrimitive);
+          if (!file) {
+            continue;
+          }
+          nsAutoCString finalPath;
+          file->GetNativePath(finalPath);
+          NSString* filePath =
+              [NSString stringWithUTF8String:(const char*)finalPath.get()];
+          [aPasteboard
+              setString:[[NSURL fileURLWithPath:filePath] absoluteString]
+                forType:curType];
+          gCreatedPromisedFile = true;
         }
-
+      } else if ([curType isEqualToString:[UTIHelper
+                                              stringFromPboardType:
+                                                  kUrlsWithTitlesPboardType]]) {
         [aPasteboard setPropertyList:[pasteboardOutputDict valueForKey:curType]
                              forType:curType];
+      } else if ([curType
+                     isEqualToString:[UTIHelper stringFromPboardType:
+                                                    NSPasteboardTypeHTML]]) {
+        [aPasteboard setString:(nsClipboard::WrapHtmlForSystemPasteboard(
+                                   [pasteboardOutputDict valueForKey:curType]))
+                       forType:curType];
+      } else if ([curType
+                     isEqualToString:[UTIHelper stringFromPboardType:
+                                                    NSPasteboardTypeTIFF]] ||
+                 [curType isEqualToString:[UTIHelper
+                                              stringFromPboardType:
+                                                  kMozCustomTypesPboardType]]) {
+        [aPasteboard setData:[pasteboardOutputDict valueForKey:curType]
+                     forType:curType];
+      } else if ([curType
+                     isEqualToString:[UTIHelper stringFromPboardType:
+                                                    kMozFileUrlsPboardType]]) {
+        [aPasteboard writeObjects:[pasteboardOutputDict valueForKey:curType]];
       }
     }
   }

widget/cocoa/nsDragService.mm

@@ -43,6 +43,9 @@
 // This global makes the transferable array available to Cocoa's promised
 // file destination callback.
 mozilla::StaticRefPtr<nsIArray> gDraggedTransferables;
+// This global ensures that file promises only resolve once and that the
+// associated file is only created once on disk per drag session.
+bool gCreatedPromisedFile;
 
 already_AddRefed<nsIDragSession> nsDragService::CreateDragSession() {
   RefPtr<nsIDragSession> sess = new nsDragSession();
@@ -200,6 +203,7 @@
 
   // Save the transferables away in case a promised file callback is invoked.
   gDraggedTransferables = aTransferableArray;
+  gCreatedPromisedFile = false;
 
   // We need to retain the view and the event during the drag in case either
   // gets destroyed.