Add backup script and defined type for using it

Prior to this commit, there was no backup script.

After this commit, there is a backup script that will iterate
through an array of database names to produce a script to backup
each database.

Using the defined type, you can backup an arbitrary set of
databases on a different cron schedule.

Author: npwalker

manifests/backup.pp

@@ -1,37 +1,44 @@
 define pe_databases::backup (
-  $db_name          = $title,
-  $pg_dump_command  = '/opt/puppetlabs/server/bin/pg_dump -Fc''  
-  $dump_path        = '/opt/puppetlabs/server/data/postgresql/9.4/backups/',
-  $script_directory = '/usr/local/bin',
-  $minute           = '30',
-  $hour             = '23',
-  $monthday         = '*',
+  Array[String] $databases_to_backup = [ 'pe-activity', 'pe-classifier', 'pe-postgres', 'pe-puppetdb', 'pe-rbac', 'pe-orchestrator' ],
+  String $backup_directory           = '/opt/puppetlabs/server/data/postgresql/9.4/backups',
+  String $script_directory           = '/opt/puppetlabs/pe_databases/scripts',
+  String $minute                     = '30',
+  String $hour                       = '23',
+  String $weekday                    = '*',
+  String $logging_directory          = '/var/log/puppetlabs/pe_databases_backup',
 ) {
 
-  validate_string($pg_dump_command)
-  validate_absolute_path($dump_path)
-  validate_absolute_path($script_directory)
-  validate_string($minute)
-  validate_string($hour)
-  validate_string($monthday)
+  ensure_resource( 'file', [ '/opt/puppetlabs/pe_databases', $script_directory, $backup_directory ],
+    { 'ensure' => 'directory' }
+  )
 
-  file { "${script_directory}/dump_${db_name}.sh":
+  ensure_resource( 'file', $logging_directory,
+    { 'ensure' => 'directory',
+       'owner' => 'pe-postgres',
+       'group' => 'pe-postgres', }
+  )
+
+  $script_path = "${script_directory}/puppet_enterprise_database_${databases_to_backup}_backup.sh"
+
+  file { $script_path :
     ensure  => file,
-    content => template('pe_databases/backup/db_dump.sh.erb'),
+    content => epp('pe_databases/puppet_enterprise_database_backup.sh.epp',
+                   { databases_to_backup => $databases_to_backup,
+                     logging_directory   => $logging_directory,
+                     backup_directory    => $backup_directory,
+                   }),
     owner   => 'pe-postgres',
     group   => 'pe-postgres',
     mode    => '0750',
-    before  => Cron["${db_name}_db_dump"],
+    before  => Cron["puppet_enterprise_database_backup_${databases_to_backup}"],
   }
 
-  cron { "${db_name}_db_dump":
+  cron { "puppet_enterprise_database_backup_${databases_to_backup}":
     ensure   => present,
-    command  => "${script_directory}/dump_${db_name}.sh",
+    command  => $script_path,
     user     => 'pe-postgres',
     minute   => $minute,
     hour     => $hour,
-    monthday => $monthday,
-    require  => File['dump_directory'],
+    weekday  => $weekday,
   }
-
 }

manifests/init.pp

@@ -1,5 +1,23 @@
 class pe_databases (
-  Array[String] $databases_to_backup   = [ 'pe-activity', 'pe-classifier', 'pe-postgres', 'pe-puppetdb', 'pe-rbac', 'pe-orchestrator' ],
+  Array[Hash] $databases_and_backup_schedule = [
+    {
+      'databases' => ['pe-activity', 'pe-classifier', 'pe-postgres', 'pe-rbac', 'pe-orchestrator'],
+      'schedule'  =>
+      {
+        'minute' => '30',
+        'hour'   => '22',
+      },
+    },
+    {
+      'databases' => ['pe-puppetdb'],
+      'schedule'  =>
+      {
+        'minute'  => '0',
+        'hour'    => '2',
+        'weekday' => '7',
+      },
+    }
+  ],
   Boolean $manage_database_maintenance = true,
   Boolean $manage_postgresql_settings  = true,
 ) {
@@ -12,9 +30,14 @@
     include pe_databases::postgresql_settings
   }
 
-  if !empty($databases_to_backup) {
-    $databases_to_backup.each | String $db | {
-      pe_databases::backup{ $db :}
+  if !empty($databases_and_backup_schedule) {
+    $databases_and_backup_schedule.each | Hash $dbs_and_schedule | {
+      pe_databases::backup{ "${dbs_and_schedule['databases']}" :
+        databases_to_backup => $dbs_and_schedule['databases'],
+        minute              => $dbs_and_schedule['schedule']['minute'],
+        hour                => $dbs_and_schedule['schedule']['hour'],
+        weekday             => $dbs_and_schedule['schedule']['weekday'],
+      }
     }
   }
 }

templates/puppet_enterprise_database_backup.sh.epp

@@ -0,0 +1,25 @@
+<%- | Array[String]  $databases_to_backup,
+      String $logging_directory,
+      String $backup_directory,
+| -%>
+
+#!/bin/bash
+# This file is managed by Puppet
+
+<% $databases_to_backup.each | String $database | { -%>
+  echo "Starting dump of database: <%= $database -%>" >> <%= $logging_directory -%>/<%= $database -%>.log
+
+  <% if $database == 'pe-classifier' { -%>
+    #Save space before backing up
+    /opt/puppetlabs/server/bin/psql -d pe-classifier -c 'TRUNCATE TABLE node_check_ins'
+  <% } -%>
+
+  /opt/puppetlabs/server/bin/pg_dump -Fc <%= $database %> -f <%= $backup_directory %>/<%= $database %>_`date +'%m_%d_%y_%R'`.bin
+
+  result="$?"
+  if [[ $result -eq 0 ]]; then
+    echo "Completed dump of database: <%= $database -%>" >> <%= $logging_directory -%>/<%= $database -%>.log
+  else
+    echo "Failed to dump database <%= $database -%>. Exit code is: ${result}" >> <%= $logging_directory -%>/<%= $database -%>.log
+  fi
+<% } -%>