[BUG] Keyword in resource file do not recognize library imported in test case

[kivipe]

Describe the bug
If I import a library at test case level and use it in a keyword without importing it in the resource file, RobotCode does not recognize it.

I am using RESTinstance library. Because it needs API endpoint and headers, I import it in test suite and configure it in the suite setup. I have some common shared operations in resource files. Because REST is not imported into the resource file, RobotCode does not recognize its keywords.

To Reproduce

file1: testcase.robot

*** Settings ***
Library    REST    http://localhost:3000
Resource   keywords.resource

*** Test Cases ***
Hello
    GetInfo

file2: keywords.resource

*** Keywords ***
GetInfo
    GET     /info/5

[d-biehl]

This works as expected.
Since the resource file stands for itself, it does not know where it is imported and which libraries or resources are possible in this case.

To make this work, and this is a common approach by the way, define a shared resource file into which you import the REST library as follows:

file: common.resource

*** Settings ***
Library     REST    ${ENDPOINT}


*** Variables ***
${ENDPOINT}      http://localhost:3000

# you can add more variables with default values for the parameters here...

Then use it in your other resources files like:

file: keywords.resource

*** Settings ***
Resource    common.resource


*** Keywords ***
GetInfo
    GET    /info/5

and then in your suite:

file: testcases.robot

*** Settings ***
# Variables       defaults.yaml   # uncomment this, if you want to override the END_POINT from a variable file
Resource        common.resource
Resource        keywords.resource


*** Variables ***
# uncomment to override the ${END_POINT}
#${END_POINT}    http://localhost:3000    # robotcode: ignore


*** Test Cases ***
Hello
    GetInfo

At runtime the library is only loaded once, because the common.resource is only loaded once. This is handled by robotframework. This allows you to import the keywords where you need them.

You can override variables defined in common.robot in the suite file, from command line or from a variable file like:

file: default.yaml

{
  END_POINT:  http://anotherhost:3000
}

Because Suite Setup is called after loading the libraries and resources, you can call other initialization keywords from REST library in your normal Suite Setup.