Lesson 9: RaffleTest.t.sol not compiling Error (7407)

[trevorparks]

Here is my code:

//SPDX-License-Identifier: MIT

pragma solidity ^0.8.18;

import {DeployRaffle} from "../../script/DeployRaffle.s.sol";
import {Raffle} from "../../src/Raffle.sol";
import {Test, console} from "forge-std/Test.sol";
import {HelperConfig} from "../../script/HelperConfig.s.sol";
import {VRFCoordinatorV2Mock} from "@chainlink/contracts/src/v0.8/mocks/VRFCoordinatorV2Mock.sol";


contract RaffleTest is Test {
    /* Events */
    event EnteredRaffle(address indexed player);

    Raffle public raffle;
    HelperConfig public helperConfig;

        uint256 entranceFee;
        uint256 interval;
        address vrfCoordinator;
        bytes32 gasLane;
        uint64 subscriptionId;
        uint32 callbackGasLimit;

    address public PLAYER = makeAddr("player");
    uint256 public constant STARTING_USER_BALANCE = 10 ether;
    
    function setUp() external {
        DeployRaffle deployer = new DeployRaffle();
        (raffle, helperConfig) = deployer.run();
        vm.deal(PLAYER, STARTING_USER_BALANCE);

        (
        entranceFee,
         interval,
         vrfCoordinator,
         gasLane,
         subscriptionId,
         callbackGasLimit
  ) = helperConfig.activeNetworkConfig();
    
    }

    function testRaffleInitializesInOpenState() public view {
        assert(raffle.getRaffleState() == Raffle.RaffleState.OPEN);
    }

    ///////////////
    // enterRaffle ///
    //////////////////
    function testRaffleRevertsWhenYouDontPayEnough() public {
        //Arrange
        vm.prank(PLAYER);
        //Act
        vm.expectRevert(Raffle.Raffle__NotEnoughETHSent.selector);
        raffle.enterRaffle();
        //Assert
    }

    function testRaffleRecordPlayerWhenTheyEnter() public {
        vm.prank(PLAYER);
        raffle.enterRaffle{value: entranceFee}();
        address playerRecorded = raffle.getPlayer(0);
        assert(playerRecorded == PLAYER);
    }

    function emitsEventOnEntrance() public {
        vm.prank(PLAYER);
        vm.expectEmit(true, false, false, address(raffle));
        emit EnteredRaffle(PLAYER);
        raffle.enterRaffle{value: entranceFee}();
    }
}

and this is the error I keep getting.

Error:
Compiler run failed:
Error (7407): Type contract Raffle is not implicitly convertible to expected type tuple(contract Raffle,contract HelperConfig).
--> test/unit/RaffleTest.t.sol:28:34:
|
28 | (raffle, helperConfig) = deployer.run();
| ^^^^^^^^^^^^^^

Out of ideas on how to fix this. I can't move on to testing because it won't compile. Please Help!

[EngrPips]

Hello @trevorparks, Please show your helperConfig file.

[trevorparks]

Hey thanks for the quick reply. Here's what i've got:

//SPDX-License-Identifier: MIT

import {Script} from "forge-std/Script.sol";
import {VRFCoordinatorV2Mock} from "@chainlink/contracts/src/v0.8/mocks/VRFCoordinatorV2Mock.sol";

pragma solidity ^0.8.18;

contract HelperConfig is Script {
    NetworkConfig public activeNetworkConfig;

  struct NetworkConfig{
         uint256 entranceFee;
        uint256 interval;
        address vrfCoordinatorV2;
        bytes32 gasLane;
        uint64 subscriptionId;
        uint32 callbackGasLimit;
  }

    constructor(){
        if(block.chainid == 11155111){
            activeNetworkConfig = getSepoliaEthConfig();
        }
        else {
            activeNetworkConfig = getOrCreateAnvilConfig();
        }
    }
  function getSepoliaEthConfig() public pure returns (NetworkConfig memory) {
    return 
    NetworkConfig({
        entranceFee: 0.01 ether,
        interval: 30,
        vrfCoordinatorV2: 0x271682DEB8C4E0901D1a1550aD2e64D568E69909,
        gasLane: 0x9fe0eebf5e446e3c998ec9bb19951541aee00bb90ea201ae456421a2ded86805,
        subscriptionId: 0,
        callbackGasLimit: 500000
    });
  }

  function getOrCreateAnvilConfig() public returns (NetworkConfig memory) {
    if (activeNetworkConfig.vrfCoordinatorV2 != address(0)){
        return activeNetworkConfig;
    }
  uint96 baseFee = 0.25 ether;
  uint96 gasPriceLink = 1e9;

  vm.startBroadcast();
    VRFCoordinatorV2Mock vrfCoordinatorV2Mock = new VRFCoordinatorV2Mock(
         baseFee,
        gasPriceLink
    );
  vm.stopBroadcast();

  return NetworkConfig({
        entranceFee: 0.01 ether,
        interval: 30,
        vrfCoordinatorV2: address(vrfCoordinatorV2Mock),
        gasLane: 0x474e34a077df58807dbe9c96d3c009b23b3c6d0cce433e59bbf5b34f823bc56c,
        subscriptionId: 0, // script will add this
        callbackGasLimit: 500000 //500k gas
  });
  }
}

[EngrPips]

Thanks. Could you show your deployment script, too?

[trevorparks]

`import {Script} from "forge-std/Script.sol";
import {Raffle} from "../src/Raffle.sol";
import {HelperConfig} from "./HelperConfig.s.sol";
import {CreateSubscription} from "./Interactions.s.sol";

pragma solidity ^0.8.19;

contract DeployRaffle is Script {
function run() external override returns (Raffle) {
HelperConfig helperConfig = new HelperConfig();
(
uint256 entranceFee,
uint256 interval,
address vrfCoordinator,
bytes32 gasLane,
uint64 subscriptionId,
uint32 callbackGasLimit,
address additionalAddress
) = helperConfig.activeNetworkConfig();

    if (subscriptionId == 0) {
        CreateSubscription createSubscription = new CreateSubscription();
        subscriptionId = createSubscription.createSubscription(
            vrfCoordinator
        );
    }
    vm.startBroadcast();
    Raffle raffle = new Raffle(
        entranceFee,
        interval,
        vrfCoordinator,
        gasLane,
        subscriptionId,
        callbackGasLimit,
        additionalAddress
    );
    vm.stopBroadcast();
    return raffle;
}

}
`

[EngrPips]

import {Script} from "forge-std/Script.sol";
import {Raffle} from "../src/Raffle.sol";
import {HelperConfig} from "./HelperConfig.s.sol";
import {CreateSubscription} from "./Interactions.s.sol";

pragma solidity ^0.8.19;

contract DeployRaffle is Script {
function run() external override returns (Raffle) {
HelperConfig helperConfig = new HelperConfig();
(
uint256 entranceFee,
uint256 interval,
address vrfCoordinator,
bytes32 gasLane,
uint64 subscriptionId,
uint32 callbackGasLimit,
address additionalAddress
) = helperConfig.activeNetworkConfig();

    if (subscriptionId == 0) {
        CreateSubscription createSubscription = new CreateSubscription();
        subscriptionId = createSubscription.createSubscription(
            vrfCoordinator
        );
    }
    vm.startBroadcast();
    Raffle raffle = new Raffle(
        entranceFee,
        interval,
        vrfCoordinator,
        gasLane,
        subscriptionId,
        callbackGasLimit,
        additionalAddress
    );
    vm.stopBroadcast();
    return raffle;
}
}

[EngrPips]

In this Deployment Script, you are returning only raffle, so why is it that when you used the Deployment script in your RaffleTest, you were trying to get back raffle and helperConfig from the script as shown below?

(raffle, helperConfig) = deployer.run();

[PhasedNorth]

I had the same problem.
Added HelperConfig to "function run() external returns (Raffle, HelperConfig)"
and to "return (raffle, helperConfig);"

Solved the problem

[EngrPips]

Awesome, I like that you unblocked yourself. Keep crushing it, @PhasedNorth.