Various enhancements for DCMTK's CMake exports.

Removed the need for exploiting the old CMake policy CMP0103 behavior.
Removed DCMTK_BUILD_CMKDIR, which was just an alias for CMAKE_BINARY_DIR.
Added the DCMTK:: namespace for all exported targets.
Added include directory target properties for all exported targets.
Added config interface target for adding the include directory for the
generated osconfig.h etc. by linking it.
Added DCMTK interface target for linking all DCMTK libraries as DCMTK::DCMTK.

Thanks to Alex Reinking <alex_reinking@berkeley.edu> for all the helpful
suggestions.

Author: Jan Schlamelcher

CMake/GenerateCMakeExports.cmake

@@ -14,23 +14,22 @@
 # DCMTKConfigVersion.cmake provides checking of DCMTK version compatibility
 # DCMTKConfig.cmake will contain options used to build this DCMTK package
 
-if(COMMAND CMAKE_POLICY)
-    if (POLICY CMP0103)
-        # suppresses error related to the following export statement
-        cmake_policy(SET CMP0103 OLD)
-    endif()
-endif()
+# Start with clean DCMTKTargets.cmake and fill it by appending
+file(WRITE "${CMAKE_BINARY_DIR}/DCMTKTargets.cmake" "")
 
 # Get and store all executable targets to DCMTKTargets.cmake within build's main dir
 get_property(DCMTK_EXECUTABLE_TARGETS GLOBAL PROPERTY DCMTK_EXECUTABLE_TARGETS)
-export(TARGETS ${DCMTK_EXECUTABLE_TARGETS} FILE "${DCMTK_BUILD_CMKDIR}/DCMTKTargets.cmake")
+export(TARGETS ${DCMTK_EXECUTABLE_TARGETS} APPEND FILE "${CMAKE_BINARY_DIR}/DCMTKTargets.cmake" NAMESPACE DCMTK::)
 
 # Get and store libraries to DCMTKTargets.cmake within the build's main dir
 get_property(DCMTK_LIBRARY_TARGETS GLOBAL PROPERTY DCMTK_LIBRARY_TARGETS)
-export(TARGETS ${DCMTK_LIBRARY_TARGETS} APPEND FILE "${DCMTK_BUILD_CMKDIR}/DCMTKTargets.cmake")
+export(TARGETS config ${DCMTK_LIBRARY_TARGETS} APPEND FILE "${CMAKE_BINARY_DIR}/DCMTKTargets.cmake" NAMESPACE DCMTK::)
+
+# Add interface library for conveniently linking to all libraries via DCMTK::DCMTK
+export(TARGETS DCMTK APPEND FILE "${CMAKE_BINARY_DIR}/DCMTKTargets.cmake" NAMESPACE DCMTK::)
 
 # Create DCMTConfigVersion.cmake with basic DCMTK version information (build tree)
-set(DCMTK_CONFIG_VERSION "${DCMTK_BUILD_CMKDIR}/DCMTKConfigVersion.cmake")
+set(DCMTK_CONFIG_VERSION "${CMAKE_BINARY_DIR}/DCMTKConfigVersion.cmake")
 WRITE_BASIC_PACKAGE_VERSION_FILE(
     ${DCMTK_CONFIG_VERSION}
     VERSION ${DCMTK_MAJOR_VERSION}.${DCMTK_MINOR_VERSION}.${DCMTK_BUILD_VERSION}
@@ -43,7 +42,7 @@ WRITE_BASIC_PACKAGE_VERSION_FILE(
 # build and install tree versions of the file.
 
 # Case 1: Configure 'DCMTKConfig.cmake' for a build tree.
-set(DCMTK_CMKDIR_CONFIG "${DCMTK_BUILD_CMKDIR}")
+set(DCMTK_CMKDIR_CONFIG "${CMAKE_BINARY_DIR}")
 # Collect include paths
 set(DCMTK_INCLUDE_DIR_CONFIGS
     "SET_AND_CHECK(DCMTK_config_INCLUDE_DIR \"${DCMTK_BINARY_DIR}/config/include/dcmtk/config\")")
@@ -57,7 +56,7 @@ foreach(module ${DCMTK_MODULES})
     set(DCMTK_CONFIG_CODE "${DCMTK_CONFIG_CODE}list(APPEND DCMTK_INCLUDE_DIRS \"${DCMTK_SOURCE_DIR}/${module}/include\")\n")
 endforeach()
 set(DCMTK_CONFIG_CODE "${DCMTK_CONFIG_CODE}##################################################")
-set(dcmtk_config "${DCMTK_BUILD_CMKDIR}/DCMTKConfig.cmake")
+set(dcmtk_config "${CMAKE_BINARY_DIR}/DCMTKConfig.cmake")
 # Actually configure file and write it to build's main directory
 CONFIGURE_PACKAGE_CONFIG_FILE(
     ${DCMTK_SOURCE_DIR}/CMake/DCMTKConfig.cmake.in

CMake/dcmtkAfterModules.cmake

@@ -16,6 +16,7 @@ if(BUILD_SINGLE_SHARED_LIBRARY)
 
   # Export target for build tree
   set_property(GLOBAL APPEND PROPERTY DCMTK_LIBRARY_TARGETS dcmtk)
+  target_link_libraries(DCMTK INTERFACE dcmtk)
 
   # Declare installation files. Also export libs and executables to DCMTKTargets.cmake.
   install(TARGETS dcmtk

CMake/dcmtkMacros.cmake

@@ -90,16 +90,24 @@ macro(DCMTK_ADD_LIBRARY LIBRARY)
         set_target_properties(${LIBRARY}${DCMTK_LIBRARY_SUFFIX} PROPERTIES COMPILE_DEFINITIONS "${LIBRARY}_EXPORTS")
     endif()
 
+    get_filename_component(DCMTK_ADD_LIBRARY_PARENT_DIR "${CMAKE_CURRENT_SOURCE_DIR}" PATH)
+    target_include_directories(${LIBRARY}${DCMTK_LIBRARY_SUFFIX} PUBLIC
+      $<BUILD_INTERFACE:${DCMTK_ADD_LIBRARY_PARENT_DIR}/include>
+      $<INSTALL_INTERFACE:include>
+    )
+
     if(NOT BUILD_SINGLE_SHARED_LIBRARY)
         # Remember export target for writing it to build tree later
         set_property(GLOBAL APPEND PROPERTY DCMTK_LIBRARY_TARGETS ${LIBRARY}${DCMTK_LIBRARY_SUFFIX})
+        target_link_libraries(DCMTK INTERFACE ${LIBRARY}${DCMTK_LIBRARY_SUFFIX})
 
         # Declare installation files
         install(TARGETS ${LIBRARY}${DCMTK_LIBRARY_SUFFIX}
           EXPORT DCMTKTargets
           RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}" COMPONENT bin
           LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}" COMPONENT shlib
-          ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}" COMPONENT lib)
+          ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}" COMPONENT lib
+        )
     endif()
 endmacro()
 
@@ -186,3 +194,52 @@ function(DCMTK_UPPER_BOUND LIST COMP VAR)
   endforeach()
   set("${VAR}" ${N} PARENT_SCOPE)
 endfunction()
+
+function(DCMTK_CREATE_INSTALL_EXPORTS)
+    # DCMTKTargets.cmake will contain list of executables and libraries produced
+    # DCMTKConfigVersion.cmake will contain DCMTK version information
+    # DCMTKConfig.cmake will contain options used to build DCMTK
+    #
+    # All three files are created within the build tree's main directory (handled in
+    # CMake/GenerateCMakeExports.cmake, and are installed to locations (OS-specific
+    # under the main install dir (handled directly below).
+
+    # Only create fully-fledged CMake export files if we have the related commands
+    include("${DCMTK_MACROS_DIR}/CheckCMakeCommandExists.cmake")
+    include(CMakePackageConfigHelpers OPTIONAL)
+    CHECK_CMAKE_COMMAND_EXISTS("CONFIGURE_PACKAGE_CONFIG_FILE")
+    CHECK_CMAKE_COMMAND_EXISTS("WRITE_BASIC_PACKAGE_VERSION_FILE")
+
+    if(HAVE_CONFIGURE_PACKAGE_CONFIG_FILE AND HAVE_WRITE_BASIC_PACKAGE_VERSION_FILE)
+
+      # Create and configure CMake export files
+      include("${DCMTK_MACROS_DIR}/GenerateCMakeExports.cmake")
+
+      # ${DCMTK_INSTALL_CONFIG} and ${DCMTK_CONFIG_VERSION} are
+      # defined within CMake/GenerateCMakeExports.cmake.
+      # Install DCMTKTargets.cmake to install tree
+      install(EXPORT DCMTKTargets FILE DCMTKTargets.cmake NAMESPACE DCMTK::
+              DESTINATION "${DCMTK_INSTALL_CMKDIR}" COMPONENT cmake)
+
+      # Install DCMTKConfig.cmake and DCMTKConfigVersion.cmake
+      install(FILES "${DCMTK_INSTALL_CONFIG}" "${DCMTK_CONFIG_VERSION}"
+              DESTINATION "${DCMTK_INSTALL_CMKDIR}" COMPONENT cmake)
+
+    else()
+
+      # Warning that we use old "configure_file" command
+      message(STATUS "Warning: Using old configure_file() mechanism to produce DCMTKConfig.cmake")
+
+      # Actually configure file
+      configure_file("${DCMTK_MACROS_DIR}/DCMTKConfig.old_cmake.in"
+                     "${DCMTK_BINARY_DIR}/DCMTKConfig.cmake" @ONLY)
+
+      # Install DCMTKConfig.cmake and DCMTKConfigVersion.cmake
+      install(FILES "${DCMTK_BINARY_DIR}/DCMTKConfig.cmake" "${DCMTK_BINARY_DIR}/DCMTKConfigVersion.cmake"
+              DESTINATION "${DCMTK_INSTALL_CMKDIR}"
+              COMPONENT cmake)
+
+    endif()
+endfunction()
+
+set(DCMTK_MACROS_DIR "${CMAKE_CURRENT_LIST_DIR}" CACHE INTERNAL "")

CMake/dcmtkPrepare.cmake

@@ -250,14 +250,11 @@ elseif(WIN32)
 endif()
 
 #-----------------------------------------------------------------------------
-# Build directories
+# Interface target to collect all DCMTK libraries
 #-----------------------------------------------------------------------------
-set(DCMTK_BUILD_CMKDIR "${CMAKE_BINARY_DIR}")
-
-#-----------------------------------------------------------------------------
-# Start with clean DCMTKTargets.cmake, filled in GenerateCMakeExports.cmake
-#-----------------------------------------------------------------------------
-file(WRITE "${DCMTK_BUILD_CMKDIR}/DCMTKTargets.cmake" "")
+add_library(DCMTK INTERFACE)
+install(TARGETS DCMTK EXPORT DCMTKTargets)
+target_link_libraries(DCMTK INTERFACE config)
 
 #-----------------------------------------------------------------------------
 # Platform-independent settings

CMakeLists.txt

@@ -35,6 +35,14 @@ set(DCMTK_MODULES ofstd oflog dcmdata dcmimgle
   dcmseg dcmtract dcmpmap dcmect
   CACHE STRING "List of modules that should be built.")
 
+# Provide an interface target to elegantly include the config directory
+add_library(config INTERFACE)
+target_include_directories(config INTERFACE
+  $<BUILD_INTERFACE:${DCMTK_BINARY_DIR}/config/include>
+  $<INSTALL_INTERFACE:include>
+)
+install(TARGETS config EXPORT DCMTKTargets)
+
 # Include directories
 set(DCMTK_INCLUDE_DIR "${DCMTK_BINARY_DIR}/config/include")
 foreach(inc ${DCMTK_MODULES})
@@ -115,50 +123,9 @@ install(DIRECTORY docs/ DESTINATION "${CMAKE_INSTALL_DOCDIR}"
 #-----------------------------------------------------------------------------
 # Create an install configuration files for external projects
 #-----------------------------------------------------------------------------
-#
-# DCMTKTargets.cmake will contain list of executables and libraries produced
-# DCMTKConfigVersion.cmake will contain DCMTK version information
-# DCMTKConfig.cmake will contain options used to build DCMTK
-#
-# All three files are created within the build tree's main directory (handled in
-# CMake/GenerateCMakeExports.cmake, and are installed to locations (OS-specific
-# under the main install dir (handled directly below).
-
-# Only create fully-fledged CMake export files if we have the related commands
-include(CMake/CheckCMakeCommandExists.cmake)
-include(CMakePackageConfigHelpers OPTIONAL)
-CHECK_CMAKE_COMMAND_EXISTS("CONFIGURE_PACKAGE_CONFIG_FILE")
-CHECK_CMAKE_COMMAND_EXISTS("WRITE_BASIC_PACKAGE_VERSION_FILE")
-
-if(HAVE_CONFIGURE_PACKAGE_CONFIG_FILE AND HAVE_WRITE_BASIC_PACKAGE_VERSION_FILE)
-
-  # Create and configure CMake export files
-  include(CMake/GenerateCMakeExports.cmake)
-
-  # ${DCMTK_INSTALL_CONFIG} and ${DCMTK_CONFIG_VERSION} are
-  # defined within CMake/GenerateCMakeExports.cmake.
-  # Install DCMTKTargets.cmake to install tree
-  install(EXPORT DCMTKTargets FILE DCMTKTargets.cmake
-          DESTINATION "${DCMTK_INSTALL_CMKDIR}" COMPONENT cmake)
-
-  # Install DCMTKConfig.cmake and DCMTKConfigVersion.cmake
-  install(FILES "${DCMTK_INSTALL_CONFIG}" "${DCMTK_CONFIG_VERSION}"
-          DESTINATION "${DCMTK_INSTALL_CMKDIR}" COMPONENT cmake)
-
-else()
-
-  # Warning that we use old "configure_file" command
-  message(STATUS "Warning: Using old configure_file() mechanism to produce DCMTKConfig.cmake")
-
-  # Actually configure file
-  configure_file("${DCMTK_SOURCE_DIR}/CMake/DCMTKConfig.old_cmake.in"
-                 "${DCMTK_BINARY_DIR}/DCMTKConfig.cmake" @ONLY)
-
-  # Install DCMTKConfig.cmake and DCMTKConfigVersion.cmake
-  install(FILES "${DCMTK_BINARY_DIR}/DCMTKConfig.cmake" "${DCMTK_BINARY_DIR}/DCMTKConfigVersion.cmake"
-          DESTINATION "${DCMTK_INSTALL_CMKDIR}"
-          COMPONENT cmake)
 
+if(NOT DCMTK_NO_EXPORT)
+    dcmtk_create_install_exports()
 endif()
 
 #-----------------------------------------------------------------------------

ofstd/libsrc/CMakeLists.txt

@@ -1,4 +1,4 @@
 # create library from source files
 DCMTK_ADD_LIBRARY(ofstd ofchrenc ofcmdln ofconapp ofcond ofconfig ofconsol ofcrc32 ofdate ofdatime oferror offile offilsys offname oflist ofstd ofstring ofstrutl ofthread oftime oftimer oftempf ofxml ofuuid ofmath ofsockad ofrand)
 
-DCMTK_TARGET_LINK_LIBRARIES(ofstd ${CHARSET_CONVERSION_LIBS} ${SOCKET_LIBS} ${THREAD_LIBS} ${WIN32_STD_LIBRARIES})
+DCMTK_TARGET_LINK_LIBRARIES(ofstd config ${CHARSET_CONVERSION_LIBS} ${SOCKET_LIBS} ${THREAD_LIBS} ${WIN32_STD_LIBRARIES})