sprintf ("%d",...) works faulty for mega2560

[dsyleixa]

hello,
building a composed string by integers using sprintf works faulty for the Mega2560.
the same code works correctly for the DUE.

Tested on 2 platforms:
Arduino IDE 1.8.8,(Windows PC), 1.8.9 (RaspberryPi 2v1, Raspbian Stretch)

int32_t i0, i1, i2, i3, i4, i5, i6;             // int (common)

char    mbuf[1024];  // cstring msg buffer


//==================================================================
// setup
//==================================================================
void setup() {
  Serial.begin(115200);
  
  i0=0;
  i1=1;
  i2=-22;
  i3=33;
  i4=-444;
  i5=5555;
  i6= B10101010*256;
  i6+=B10101010;
}


//==================================================================
// loop
//==================================================================

void loop() {
  static bool stringComplete = false;  

  //-------------------------------------------------------------
  // Serial send  
 
  char formatstr[1024];
  strcpy(formatstr, "§");                               // initial key
  strcat(formatstr, "&i0=%d;&i1=%d;&i2=%d;&i3=%d;&i4=%d;&i5=%d;&i6=%d;");

  sprintf(mbuf, formatstr, i0,i1,i2,i3,i4,i5,i6);        
         
  for (int i=0; i<strlen(mbuf); i++ ) Serial.print(mbuf[i]);
  Serial.println();  

  i0++;

  //delay
  delay(1000); 
}

Serial output:

§&i0=0;&i1=0;&i2=1;&i3=0;&i4=-22;&i5=-1;&i6=33;
§&i0=1;&i1=0;&i2=1;&i3=0;&i4=-22;&i5=-1;&i6=33;
§&i0=2;&i1=0;&i2=1;&i3=0;&i4=-22;&i5=-1;&i6=33;
§&i0=3;&i1=0;&i2=1;&i3=0;&i4=-22;&i5=-1;&i6=33;
§&i0=4;&i1=0;&i2=1;&i3=0;&i4=-22;&i5=-1;&i6=33;
§&i0=5;&i1=0;&i2=1;&i3=0;&i4=-22;&i5=-1;&i6=33;
§&i0=6;&i1=0;&i2=1;&i3=0;&i4=-22;&i5=-1;&i6=33;
§&i0=7;&i1=0;&i2=1;&i3=0;&i4=-22;&i5=-1;&i6=33;
§&i0=8;&i1=0;&i2=1;&i3=0;&i4=-22;&i5=-1;&i6=33;
§&i0=9;&i1=0;&i2=1;&i3=0;&i4=-22;&i5=-1;&i6=33;
§&i0=10;&i1=0;&i2=1;&i3=0;&i4=-22;&i5=-1;&i6=33;
§&i0=11;&i1=0;&i2=1;&i3=0;&i4=-22;&i5=-1;&i6=33;
...

instead, the correct output is expected to be like the following:

§&i0=0;&i1=1;&i2=-22;&i3=33;&i4=-444;&i5=5555;&i6=43690;
§&i0=1;&i1=1;&i2=-22;&i3=33;&i4=-444;&i5=5555;&i6=43690;
§&i0=2;&i1=1;&i2=-22;&i3=33;&i4=-444;&i5=5555;&i6=43690;
§&i0=3;&i1=1;&i2=-22;&i3=33;&i4=-444;&i5=5555;&i6=43690;
§&i0=4;&i1=1;&i2=-22;&i3=33;&i4=-444;&i5=5555;&i6=43690;
...

as stated, the last output is the correct one produced by a DUE by the same code.

[matthijskooijman]

The problem is that you're mixing up the types. %d accepts an int, but you're passing it int32_t's. On the Due, which is a 32-bit platform, int32_t equals int, but on AVR, which is a 16-bit platform, int equals int16_t. Since printf is inherently type unsafe, the compiler cannot automatically convert this for you, and printf ends up breaking up on int32_t argument and applying it to two %d format specifiers.

To do this portably, either cast the arguments to the right type (long in this case, since that should, at least on AVR and Due, fit an int32_t) and use the corresponding specifier (%ld), or use constants for the specifiers (e.g. PRId32, see http://www.cplusplus.com/reference/cinttypes/).

I'm closing this, since everything seems to be working as intended.