Berry script fails in aetoexec.be but works in console

[CyBaart]

Hi, I am new to Tasmota and berry script. I do have many years experience with C++, arduino etc.

I am making a controller for my hot tub using an ESP32 and Tasmota. There are 4 solid state relays, a DS18B20 temperature sensor and a DHT11 temperature and humidity sensor. I am trying to write a berry script to control it all but it is not finished yet.

One function sends the water temperature, the air temperature, and humidity levels to a Thingspeak channel. This is the code (actual api_key replaced).

def things_log()
    import json
    import string
    var sensors=json.load(tasmota.read_sensors())
    var wtemp=string.format("%3.1f",sensors['DS18B20']['Temperature'])
    var atemp=string.format("%3.1f",sensors['DHT11']['Temperature'])
    var hum=string.format("%3.1f",sensors['DHT11']['Humidity'])
    var webadr = "https://api.thingspeak.com/update?api_key=xxxxxxxxxxxxxxxx&field1="+wtemp+"&field2="+atemp+"&field3="+hum
    print(webadr)
    var cl = webclient()
    cl.begin(webadr)
    var r = cl.GET()
    print(r)
end

So, if I copy and paste the lines of code into the berry console, it works perfectly but in the autoexec.be file, it doesn't work.

First, the console output when I paste the code in

Welcome` to the Berry Scripting console. Check the documentation.
import json
import string
sensors=json.load(tasmota.read_sensors())
webadr = string.format("https://api.thingspeak.com/update?api_key=xxxxxxxxxxxxxxxx&field1=%5.2f&field2=%5.2f&field3=%5.2f",sensors['DS18B20']['Temperature'],sensors['DHT11']['Temperature'],sensors['DHT11']['Humidity'])
print(webadr)
cl = webclient()
cl.begin(webadr)
r = cl.GET()
print(r)
https://api.thingspeak.com/update?api_key=xxxxxxxxxxxxxxxx&field1=14.60&field2=14.40&field3=91.00
200

And the output on boot

Welcome to the Berry Scripting console. Check the documentation.
https://api.thingspeak.com/update?api_key=xxxxxxxxxxxxxxxx&field1=14.7&field2=&field3=
1

As you can see, there is only one of the sensor values within the webadr variable and the cl.GET returns a value of 1. My question is, why?

I don't think it is important but just in case, here is the full script. Ultimately, the things_log and main_loop will be on cron timers. Of course, if there is a better way of doing anything within my code, I would appreciate suggestions. Remember, it's not finished especially main_loop! Cheers, Steve

# heater solid state relay is GPIO26 (set in config as none)
# pump solid state relay is GPIO25 (set in config as none)
# Control Module solid state relay is GPIO27 (set in config as relay 1)
# lights solid state relay is GPIO12 (set in config as relay 2)
# master is GPIO12 (set as relay3 but no relay attached, just needed a button)
#DS18B20 connected to GPIO32
# DHT11 connected to GPIO33

def heater_on() # turn heater on if master is on. if pump not on, turn it on too
    if tasmota.get_power(2) == true
        gpio.digital_write(26,1)
        if gpio.digital_read(25) == 0
            gpio.digital_write(25,1)
        end
    end
end

def heater_off() # turn heater off and also recirc pump if not between 14:00 and 00:00
    import json
    gpio.digital_write(26,0)
    var mins = tasmota.time_dump(tasmota.rtc()['local'])['hour'] * 60 + tasmota.time_dump(tasmota.rtc()['local'])['min']
    if mins<960
        gpio.digital_write(25,0)
    end
end

def pump_on()
    if tasmota.get_power(2) == true
        gpio.digital_write(25,1)
    end
end

def pump_off() # turn pump off. if heater is on turn it off too
    gpio.digital_write(25,0)
    if gpio.digital_read(26) == 1
        gpio.digital_write(26,0)
    end
end

def initialise()
    pump_off()
    heater_off()
    tasmota.set_power(0, false)
    tasmota.set_power(1, false)
    tasmota.set_power(2, false)
end

def main_loop() # run circ pump from 16:00 until midnight. keep water temp at 36°C
    import json
    var mon = 0
    if tasmota.get_power(2) == true
        var mins = tasmota.time_dump(tasmota.rtc()['local'])['hour'] * 60 + tasmota.time_dump(tasmota.rtc()['local'])['min']
        if mins>960
            pump_on()
        else
            if gpio.digital_read(26) == 0
                pump_off()
            end
        end

        var sensors=json.load(tasmota.read_sensors())
        if (sensors['DS18B20']['Temperature'])<36
            if gpio.digital_read(26) == 0
                heater_on()
            end
        else
            if gpio.digital_read(26) == 1
                heater_off()
            end
        end
   else
        if mon == 0 # first loop since master turned off
            mon = 1
            gpio.digital_write(25,0) # pump off
            gpio.digital_write(26,0) # heater off
            tasmota.set_power(0, false) # console off
            tasmota.set_power(1, false) #lights off
        end
    end
end

def things_log()
    import json
    import string
    var sensors=json.load(tasmota.read_sensors())
    var wtemp=string.format("%3.1f",sensors['DS18B20']['Temperature'])
    var atemp=string.format("%3.1f",sensors['DHT11']['Temperature'])
    var hum=string.format("%3.1f",sensors['DHT11']['Humidity'])
    var webadr = "https://api.thingspeak.com/update?api_key=xxxxxxxxxxxxxxxx&field1="+wtemp+"&field2="+atemp+"&field3="+hum
    print(webadr)
    var cl = webclient()
    cl.begin(webadr)
    var r = cl.GET()
    print(r)
end


initialise()
things_log()

[barbudor]

On boot wifi is not yet connected, so you can't
use tasmota.wifi() to know if it's connected or not

[sfromis]

Since you see empty values:
https://api.thingspeak.com/update?api_key=xxxxxxxxxxxxxxxx&field1=14.7&field2=&field3=

To debug, you could add a print(sensors) after having parsed it. I suspect that your first read right after boot might have resulted in you getting a null/nil value, resulting in string.format giving you an empty string.

To delay things till Tasmota fully initialized, you could delay your exection like:
tasmota.add_rule('System#boot', .....)

Tip: This alwo works:
var wtemp=f"{sensors['DS18B20']['Temperature']:%3.1f}"

[CyBaart]

@barbudor, @sfromis, thanks.

I will put a do while loop in a separate function to check that the WiFi is connected before running that function after boot.

Also, it isn't a completely empty sensor value string, there is one sensor value of 14.7 which was the DS18B20 temperature - could it be that that sensor is ready to read quicker than the DHT11 and that some delay before running this function would fix that too? I'll know soon enough!

[sfromis]

Do not use a do while loop for spending time to wait for something. Berry code must return quickly, preferably within 50 ms. Tasmota is blocked until the Berry function gives up control.

Better use the specific suggestion I posted, to have your code delayed until Tasmota is fully initialized.