Berry: can I pass parameters to a function that is called by tasmota.settimer?

[forumlw06]

Hello, I would like pass variables like in that pseudo code

def t(key) print(key) end

tasmota.set_timer(5000, t('hello' )) 

I get a type error.

Do I need to use global variables or is there a way to pass arguments?

Thanks!

[sfromis]

The 2nd argument to tasmota.set_timer (and other functions expecting a callback) has to be a function, not a function call (which would be executed right away). The type error is when the called function did not itself return the function to be called in the future.

The simple way of having parameters passed is a closure like this:
tasmota.set_timer(5000, / -> t('hello'))
This is short form for having an anonymous function definition
tasmota.set_timer(5000, def () t('hello') end)
Thus, you could also have a named function instead, but this would not work in what is the deeper meaning behind the closure concept (from functional programming), like when the callback function needs access to the context of where it is defined. This can be local variables, or importantly self for instance access within a class structure.

Passing a local variable in the short-form notation could be like this:
tasmota.set_timer(5000, /parm -> t('hello', parm))
This allows the called function access to the content at the time of execution, as it is pass by reference, not by content. This also allows the called function to modify the variable in the context of where it is defined.

[forumlw06]

Ok, i got that part. But i do not need the value of the variables at the time when t is called, but the values of the time when tasmota.set_timer is called. So i guess i have to somehow take care of that using a list (which probably is like your p1a/p1b suggestion).

I will further evaluate.

[sfromis]

No, you do not need any list structure, or something complicated. If you do not want the value to be from when the t function is called in the future, but instead from the time you are doing the tasmota.set_timer, you can follow my suggestion of making variables p1a and p1b (or whatever you want to call them. Like this:

var p1=2000
var p2=5
var p3=6
t(p1,p2,p3)

var p1a=p1
tasmota.set_timer(2000, /-> t(p1a,p2,p3))

p1=4000
var p1b=p1
tasmota.set_timer(4000, /-> t(p1b,p2,p3))

When you are not modifying the variable used in the t function call, you get the value which was set initially.

If you are doing the set_timer calls from different function having their own local variables (instead of series of statements which I assume was to illustrate instead of being realistic), things are even simpler. When you have a function with local variables, these will be created each time the function starts, and if you pass them to a future function, they will be available to the function without being overwritten (as long as your are not doing it in the same function).

[forumlw06]

Ah, now i see. Thanks for your help.

Here is my small test script as a whole. In my scenario t would be the sendmail part.

Test in Console via: newcmd {"P1":2000,"P2":5,"P3":6}; newcmd {"P1":4000,"P2":5,"P3":6}

def t(a,b,c) print(str(a)+' # '+ str(b) + ' # '+ str(c)) end

# define new tasmota command
# call via console: 
# - backlog newcmd {"P1":2000,"P2":5,"P3":6}; newcmd {"P1":4000,"P2":5,"P3":6}
def mycollect(cmd, idx, payload, payload_json)
	var p1=0
	var p2=0
	var p3=0

	# parse payload
	if payload_json != nil
		if payload_json.find("P1") != nil p1 = payload_json.find("P1") end
		if payload_json.find("P2") != nil p2 = payload_json.find("P2") end
		if payload_json.find("P3") != nil p3 = payload_json.find("P3") end
	end
	
	# some simple logic here

	tasmota.set_timer(0, /-> t(p1,p2,p3))

	# report the command as successful
	tasmota.resp_cmnd_done()
end

tasmota.add_cmd('newcmd', mycollect)

Thanks again!

[sfromis]

One small tip about how things can be done in an easier way. Instead of this:
if payload_json.find("P1") != nil p1 = payload_json.find("P1") end
You can do it shorter, like this:
p1 = payload_json.find("P1", p1)
The 2nd argument for the find function is a default value, if the key is not in the map.

This can can also be shorter and more readable:
def t(a,b,c) print(str(a)+' # '+ str(b) + ' # '+ str(c)) end
Using f-strings, you can get the same like this:
def t(a,b,c) print(f'{a} # {b} # {c}') end

[forumlw06]

Thank you for the additional tips. Was aware of the f-strings, but not of the find stuff.
Lot to learn in Berry space ;-)