Read Extend Frame Format

[bertrand-sifre]

I try to read extended format with the example file.
My arduino receive the SFF, but never the EFF is displayed on serial console.
It's necessary a particular coniguration ?

[bertrand-sifre]

I find how to do it.
It is necessary to configure the filters in 0x0000000, moreover to have the good ID it is necessary to use a binary mask.

#include <SPI.h>
#include <mcp2515.h>

struct can_frame canMsg;
MCP2515::ERROR error;
MCP2515 mcp2515(10);


void setup() {
  Serial.begin(115200);
  SPI.begin();
  
  mcp2515.reset();
  mcp2515.setBitrate(CAN_500KBPS, MCP_8MHZ);
  mcp2515.setConfigMode();
  mcp2515.setFilterMask(MCP2515::MASK0, true, 0x00000000);
  mcp2515.setFilter(MCP2515::RXF0, true, 0x00000000);
  mcp2515.setFilter(MCP2515::RXF1, true, 0x00000000);
  mcp2515.setFilterMask(MCP2515::MASK1, true, 0x00000000);
  mcp2515.setFilter(MCP2515::RXF2, true, 0x00000000);
  mcp2515.setFilter(MCP2515::RXF3, true, 0x00000000);
  mcp2515.setFilter(MCP2515::RXF4, true, 0x00000000);
  mcp2515.setFilter(MCP2515::RXF5, true, 0x00000000);
  mcp2515.setNormalMode();
  
  Serial.println("------- CAN Read ----------");
  Serial.println("ID  DLC   DATA");
}

void loop() {
  error = mcp2515.readMessage(&canMsg);
  if (error == MCP2515::ERROR_OK) {
      
    Serial.print(canMsg.can_id & 0x1FFFFFFF, HEX); // print ID
    Serial.print(" "); 
    Serial.print(canMsg.can_dlc, HEX); // print DLC
    Serial.print(" ");
    
    for (int i = 0; i<canMsg.can_dlc; i++)  {  // print the data
        
      Serial.print(canMsg.data[i],HEX);
      Serial.print(" ");

    }

    Serial.println();      
  } else if(error != MCP2515::ERROR_NOMSG) {
    Serial.println(error);
  }

}