Request: a distinct face for `#_` forms

[Ramblurr]

Over the years I've found myself wanting to change the face used for #_ forms vs normal ; comments.

But since #_ forms are mapped to font-lock-comment-face this isn't straightforward.

Would it be acceptable to define a new clojure-reader-discard-face (or something like that) so that they can be distinguished?

Edit: if there is some standard emacs customization/config procedure that would allow me to achieve this without a code change here nor copying and modifying large parts of clojure-mode, please let me know!

[yuhan0]

I have a local monkey patch for this... I recall the issue was that the current logic was a bit complected trying to simultaneously handle both the #_ and (comment ..) macro identically, so I couldn't find a clean backward-compatible way of extending it either - here's the code (mostly I think a trimmed down copy of the current logic minus the comment handling)

(defface clojure-discard-face
  '((t :inherit font-lock-comment-face))
  "Face used for expressions discarded with the #_ form.")

(defun clojure--skip-past-discarded-forms ()
  "Move to the end of all forms discarded by #_ readers at point.
Multiple #_#_ can be stacked to discard consecutive forms."
  (save-match-data
    (when (looking-at "[ \r\n\t,]*#_")
      (let ((skip 1))
        (goto-char (match-end 0))
        (ignore-errors
          (while (< 0 skip)
            (skip-chars-forward " \r\n\t,")
            (if (looking-at-p "#_")
                (progn (forward-char 2)
                       (cl-incf skip))
              (clojure-forward-logical-sexp 1)
              (cl-decf skip))))))))

(defun clojure--search-discard-macro (limit)
  "Find #_ discard macros and set the match data.
Search from point up to LIMIT.  The discarded region
is between `(match-beginning 0)' and `(match-end 0)'."
  (and
   (search-forward-regexp "\\_<#_" limit 'noerror)
   (let ((state (syntax-ppss (match-beginning 0))))
     (and (not (nth 3 state))
          (not (nth 4 state))))
   (let ((md (match-data)))
     (clojure--skip-past-discarded-forms)
     (setf (elt md 1) (point))
     (set-match-data md)
     t)))

And then you'll have to replace the line at

clojure-mode/clojure-mode.el

Line 1148 in 28dc021

(clojure--search-comment-macro 1 font-lock-comment-face t)

with

      (clojure--search-discard-macro 0 'clojure-discard-face t)

Then you'll be able to tweak the face to your liking - here's my setup

[bbatsov]

I don't mind introducing a separate face for this, that's deriving from the comment face by default.

[Ramblurr]

I've made a small PR for this, unfortunately I'm having issues with eldev so I haven't managed to update the tests yet.

[yuhan0]

Oh I guess that's a reasonable change - for some reason I imagined this had to be accompanied with a deprecation / breaking change to the semantics of clojure-comment-regexp - because we'd now be applying the 'discard' face to (comment) forms for anyone who set that variable to clojure--reader-and-comment-regexp - which I think makes no sense as a customization option in the first place