Refactored with Andrew's amazing Elixir skillz

Author: npendery

web/controllers/organization_membership_controller.ex

@@ -1,56 +1,15 @@
 defmodule CodeCorps.OrganizationMembershipController do
   use CodeCorps.Web, :controller
 
-  import CodeCorps.ControllerHelpers
-
   alias JaSerializer.Params
   alias CodeCorps.OrganizationMembership
 
   plug :scrub_params, "data" when action in [:create, :update]
 
   def index(conn, params) do
     memberships =
-      case params do
-        %{"organization_id" => organization_id, "role" => roles, "filter" => id_list} ->
-          roles = roles |> coalesce_string
-          ids = id_list |> coalesce_id_string
-          OrganizationMembership
-            |> where([om], om.organization_id == ^organization_id)
-            |> where([om], om.member_id in ^ids)
-            |> where([om], om.role in ^roles)
-        %{"organization_id" => organization_id, "role" => roles} ->
-          roles = roles |> coalesce_string
-          OrganizationMembership
-            |> where([om], om.organization_id == ^organization_id)
-            |> where([om], om.role in ^roles)
-        %{"organization_id" => organization_id, "filter" => id_list} ->
-          id_list = id_list |> coalesce_id_string
-          OrganizationMembership
-            |> where([om], om.organization_id == ^organization_id)
-            |> where([om], om.id in ^id_list)
-        %{"role" => roles, "filter" => id_list} ->
-          roles = roles |> coalesce_string
-          ids = id_list |> coalesce_id_string
-          OrganizationMembership
-            |> where([om], om.member_id in ^ids)
-            |> where([om], om.role in ^roles)
-        %{"organization_id" => organization_id} ->
-          OrganizationMembership
-            |> where([om], om.organization_id == ^organization_id)
-        %{"filter" => id_list} ->
-          ids = id_list |> coalesce_id_string
-          OrganizationMembership
-            |> where([om], om.member_id in ^ids)
-        %{"role" => roles} ->
-          roles = roles |> coalesce_string
-          OrganizationMembership
-            |> where([om], om.role in ^roles)
-        _ ->
-          OrganizationMembership
-      end
-
-    memberships =
-      memberships
+      OrganizationMembership
+      |> OrganizationMembership.add_filters(params)
       |> preload([:organization, :member])
       |> Repo.all
 

web/models/model_helpers.ex

@@ -1,5 +1,7 @@
 defmodule CodeCorps.ModelHelpers do
-  import Ecto.Changeset
+  use CodeCorps.Web, :model
+
+  import CodeCorps.ControllerHelpers
 
   def generate_slug(changeset, value_key, slug_key) do
     case changeset do
@@ -10,4 +12,21 @@ defmodule CodeCorps.ModelHelpers do
         changeset
     end
   end
+
+  def member_filter(query, %{"filter" => id_list}) do
+    ids = id_list |> coalesce_id_string
+    query |> where([om], om.member_id in ^ids)
+  end
+  def member_filter(query, _), do: query
+
+  def organization_filter(query, %{"organization_id" => organization_id}) do
+    query |> where([om], om.organization_id == ^organization_id)
+  end
+  def organization_filter(query, _), do: query
+
+  def role_filter(query, %{"role" => roles}) do
+    roles = roles |> coalesce_string
+    query |> where([om], om.role in ^roles)
+  end
+  def role_filter(query, _), do: query
 end

web/models/organization_membership.ex

@@ -5,6 +5,8 @@ defmodule CodeCorps.OrganizationMembership do
 
   use CodeCorps.Web, :model
 
+  import CodeCorps.ModelHelpers
+
   alias CodeCorps.Organization
   alias CodeCorps.User
 
@@ -47,6 +49,13 @@ defmodule CodeCorps.OrganizationMembership do
     |> changeset(params)
   end
 
+  def add_filters(query, params) do
+    query
+    |> organization_filter(params)
+    |> role_filter(params)
+    |> member_filter(params)
+  end
+
   defp roles do
     ~w{ pending contributor admin owner }
   end