Chandelier Exit

[DaveSkender]

Community discussion about Chandelier Exit

[overstartup]

It seems difficult to use. Why you separated long and short? There are different indicators in trading view.
It will be great if you make another one to adjust it automatically.

It is a great indicator to use. Please make it easier to use.

I found this code great.it is available in trading view:

//@version=4
// Copyright (c) 2019-present, Alex Orekhov (everget)
// Chandelier Exit script may be freely distributed under the terms of the GPL-3.0 license.
study("Chandelier Exit", shorttitle="CE", overlay=true)

length = input(title="ATR Period", type=input.integer, defval=22)
mult = input(title="ATR Multiplier", type=input.float, step=0.1, defval=3.0)
showLabels = input(title="Show Buy/Sell Labels ?", type=input.bool, defval=true)
useClose = input(title="Use Close Price for Extremums ?", type=input.bool, defval=true)
highlightState = input(title="Highlight State ?", type=input.bool, defval=true)

atr = mult * atr(length)

longStop = (useClose ? highest(close, length) : highest(length)) - atr
longStopPrev = nz(longStop[1], longStop) 
longStop := close[1] > longStopPrev ? max(longStop, longStopPrev) : longStop

shortStop = (useClose ? lowest(close, length) : lowest(length)) + atr
shortStopPrev = nz(shortStop[1], shortStop)
shortStop := close[1] < shortStopPrev ? min(shortStop, shortStopPrev) : shortStop

var int dir = 1
dir := close > shortStopPrev ? 1 : close < longStopPrev ? -1 : dir

var color longColor = color.green
var color shortColor = color.red

longStopPlot = plot(dir == 1 ? longStop : na, title="Long Stop", style=plot.style_linebr, linewidth=2, color=longColor)
buySignal = dir == 1 and dir[1] == -1
plotshape(buySignal ? longStop : na, title="Long Stop Start", location=location.absolute, style=shape.circle, size=size.tiny, color=longColor, transp=0)
plotshape(buySignal and showLabels ? longStop : na, title="Buy Label", text="Buy", location=location.absolute, style=shape.labelup, size=size.tiny, color=longColor, textcolor=color.white, transp=0)

shortStopPlot = plot(dir == 1 ? na : shortStop, title="Short Stop", style=plot.style_linebr, linewidth=2, color=shortColor)
sellSignal = dir == -1 and dir[1] == 1
plotshape(sellSignal ? shortStop : na, title="Short Stop Start", location=location.absolute, style=shape.circle, size=size.tiny, color=shortColor, transp=0)
plotshape(sellSignal and showLabels ? shortStop : na, title="Sell Label", text="Sell", location=location.absolute, style=shape.labeldown, size=size.tiny, color=shortColor, textcolor=color.white, transp=0)

midPricePlot = plot(ohlc4, title="", style=plot.style_circles, linewidth=0, display=display.none, editable=false)

longFillColor = highlightState ? (dir == 1 ? longColor : na) : na
shortFillColor = highlightState ? (dir == -1 ? shortColor : na) : na
fill(midPricePlot, longStopPlot, title="Long State Filling", color=longFillColor)
fill(midPricePlot, shortStopPlot, title="Short State Filling", color=shortFillColor)

changeCond = dir != dir[1]
alertcondition(changeCond, title="Alert: CE Direction Change", message="Chandelier Exit has changed direction!")
alertcondition(buySignal, title="Alert: CE Buy", message="Chandelier Exit Buy!")
alertcondition(sellSignal, title="Alert: CE Sell", message="Chandelier Exit Sell!")

[DaveSkender]

You're saying this is "difficult to use", but what I think you really mean is that there's a customized variant of this out there that you like better. I can't imagine that this is hard to use:

// usage
var results = quotes.GetChandelier(22, 3, ChandelierType.Long);

Can you explain your recommendation here? Happy to explore and at least learn a bit more about your suggestion.

It will be great if you make another one to adjust it automatically.

[DaveSkender]

Generally speaking, we don't make a lot of creative decision on these indicators since we almost always source them from the mathematical descriptions written by the original author, who is a recognized expert in the field. If it's difficult to use, blame them 😃. If you really want a difficult one, try Ichimoku Cloud.

For Chandlier Exit, the original author is Charles Le Beau, a recognized expert in exit strategies. We're using his formula. Anecdotally, we're using the same approach as StockCharts.com, a more reputable charting platform.

We also never write indicators based on other people's code, since it's often incorrect. This is especially common with community contributed indicators on platforms like TradingView where amateurs just dream stuff up with little or no expertise to rationalize their choices.

[overstartup]

I mean, using the result is difficult. I checked the result for long, it is always under the price. So there is no direction change to find the trend is changed.it will be great if you just combine long and Short together like this photo:

maybe it is possible to return the result same as super trend.

i know you are doing a great job, :) I just found a new strategy to use this indicator to find great signals.

[DaveSkender]

Looks like what he’s doing is simply hiding the values when they cross the price. This is what long and short look like together normally. Neither will stay on one side of the price.

This similar to ATR Trailing Stop too. What you’re depicting is a good candidate for a custom indicator.

[overstartup]

It seems they are same. Thanks.
I will test it.

I didn't know we can have custom indicator. That is really useful.