Skip to content
Intellisense engine for Vim8 & Neovim, full language server protocol support as VSCode
TypeScript Vim script Other
Branch: master
Clone or download

Latest commit

Files

Permalink
Type Name Latest commit message Commit time
Failed to load latest commit information.
.github chore(ci): checkout@v2 for better performance Mar 4, 2020
.vim chore(config): fix coc-settings.json Jan 7, 2020
autoload fix(util): remove unused variable Mar 31, 2020
bin fix(plugin): fix temp folder not removed Mar 6, 2020
data chore(schema): separateRelatedInformationAsDiagnostics Mar 26, 2020
doc chore(doc): improve doc tag Apr 1, 2020
plugin feat(plugin): add CocNotify function Mar 23, 2020
src feat(util): add mutex module Mar 31, 2020
.gitignore Update .gitignore (#1042) Jul 30, 2019
.ignore fix diagnostic, lint issues Jun 29, 2018
.npmignore refactor(extensions): support install taged extension Jul 5, 2019
Backers.md chore(backers): add yatli to backers Nov 27, 2019
CONTRIBUTING.md docs: add CONTRIBUTING.md Jun 7, 2019
LICENSE.md refactor compltetion Jun 16, 2018
README.md chore(README): badges Feb 20, 2020
history.md Fix typos (#1426) Dec 26, 2019
install.cmd refactor(install): new publish logic Jun 15, 2019
install.sh refactor(util): install script not needed for release code Jul 11, 2019
jest.js feat(util): add g:coc_data_home (#1529) Feb 10, 2020
package.json chore(plugin): use vscode-languageserver-textdocument for TextDocument Mar 21, 2020
release.sh fix(util): fix release script Jul 11, 2019
tsconfig.json chore(tsconfig): set noUnusedLocals to false Jun 20, 2019
tslint.json chore(language-client): use vscode-languageserver-textdocument Mar 21, 2020
webpack.config.js feat(plugin): add REVISION to CocInfo Apr 3, 2019
yarn.lock chore(plugin): use vscode-languageserver-textdocument for TextDocument Mar 21, 2020

README.md

Coc Logo

Make your Vim/Neovim as smart as VSCode.

Software License Bountysource Actions Doc Gitter


Coc is an intellisense engine for Vim/Neovim.

Gif

True snippet and additional text editing support

Check out Wiki, or doc/coc.txt for the Vim interface.

Quick Start

Install nodejs when necessary:

curl -sL install-node.now.sh/lts | bash

For vim-plug users:

" Use release branch (Recommend)
Plug 'neoclide/coc.nvim', {'branch': 'release'}

" Or build from source code by use yarn: https://yarnpkg.com
Plug 'neoclide/coc.nvim', {'do': 'yarn install --frozen-lockfile'}

in your .vimrc or init.vim, then restart Vim and run :PlugInstall. Checkout Install coc.nvim Wiki for more info.

Note: The first time building from source code may be slow.

Example vim configuration

Configuration is required to make coc.nvim easier to work with, since it doesn't change your key-mappings or Vim options. This is done as much as possible to avoid conflict with your other plugins.

❗️Important: Some Vim plugins could change key mappings. Please use :verbose imap <tab> to make sure that your keymap has taken effect.

" TextEdit might fail if hidden is not set.
set hidden

" Some servers have issues with backup files, see #649.
set nobackup
set nowritebackup

" Give more space for displaying messages.
set cmdheight=2

" Having longer updatetime (default is 4000 ms = 4 s) leads to noticeable
" delays and poor user experience.
set updatetime=300

" Don't pass messages to |ins-completion-menu|.
set shortmess+=c

" Always show the signcolumn, otherwise it would shift the text each time
" diagnostics appear/become resolved.
set signcolumn=yes

" Use tab for trigger completion with characters ahead and navigate.
" NOTE: Use command ':verbose imap <tab>' to make sure tab is not mapped by
" other plugin before putting this into your config.
inoremap <silent><expr> <TAB>
      \ pumvisible() ? "\<C-n>" :
      \ <SID>check_back_space() ? "\<TAB>" :
      \ coc#refresh()
inoremap <expr><S-TAB> pumvisible() ? "\<C-p>" : "\<C-h>"

function! s:check_back_space() abort
  let col = col('.') - 1
  return !col || getline('.')[col - 1]  =~# '\s'
endfunction

" Use <c-space> to trigger completion.
inoremap <silent><expr> <c-space> coc#refresh()

" Use <cr> to confirm completion, `<C-g>u` means break undo chain at current
" position. Coc only does snippet and additional edit on confirm.
if has('patch8.1.1068')
  " Use `complete_info` if your (Neo)Vim version supports it.
  inoremap <expr> <cr> complete_info()["selected"] != "-1" ? "\<C-y>" : "\<C-g>u\<CR>"
else
  imap <expr> <cr> pumvisible() ? "\<C-y>" : "\<C-g>u\<CR>"
endif

" Use `[g` and `]g` to navigate diagnostics
nmap <silent> [g <Plug>(coc-diagnostic-prev)
nmap <silent> ]g <Plug>(coc-diagnostic-next)

" GoTo code navigation.
nmap <silent> gd <Plug>(coc-definition)
nmap <silent> gy <Plug>(coc-type-definition)
nmap <silent> gi <Plug>(coc-implementation)
nmap <silent> gr <Plug>(coc-references)

" Use K to show documentation in preview window.
nnoremap <silent> K :call <SID>show_documentation()<CR>

function! s:show_documentation()
  if (index(['vim','help'], &filetype) >= 0)
    execute 'h '.expand('<cword>')
  else
    call CocAction('doHover')
  endif
endfunction

" Highlight the symbol and its references when holding the cursor.
autocmd CursorHold * silent call CocActionAsync('highlight')

" Symbol renaming.
nmap <leader>rn <Plug>(coc-rename)

" Formatting selected code.
xmap <leader>f  <Plug>(coc-format-selected)
nmap <leader>f  <Plug>(coc-format-selected)

augroup mygroup
  autocmd!
  " Setup formatexpr specified filetype(s).
  autocmd FileType typescript,json setl formatexpr=CocAction('formatSelected')
  " Update signature help on jump placeholder.
  autocmd User CocJumpPlaceholder call CocActionAsync('showSignatureHelp')
augroup end

" Applying codeAction to the selected region.
" Example: `<leader>aap` for current paragraph
xmap <leader>a  <Plug>(coc-codeaction-selected)
nmap <leader>a  <Plug>(coc-codeaction-selected)

" Remap keys for applying codeAction to the current line.
nmap <leader>ac  <Plug>(coc-codeaction)
" Apply AutoFix to problem on the current line.
nmap <leader>qf  <Plug>(coc-fix-current)

" Introduce function text object
" NOTE: Requires 'textDocument.documentSymbol' support from the language server.
xmap if <Plug>(coc-funcobj-i)
xmap af <Plug>(coc-funcobj-a)
omap if <Plug>(coc-funcobj-i)
omap af <Plug>(coc-funcobj-a)

" Use <TAB> for selections ranges.
" NOTE: Requires 'textDocument/selectionRange' support from the language server.
" coc-tsserver, coc-python are the examples of servers that support it.
nmap <silent> <TAB> <Plug>(coc-range-select)
xmap <silent> <TAB> <Plug>(coc-range-select)

" Add `:Format` command to format current buffer.
command! -nargs=0 Format :call CocAction('format')

" Add `:Fold` command to fold current buffer.
command! -nargs=? Fold :call     CocAction('fold', <f-args>)

" Add `:OR` command for organize imports of the current buffer.
command! -nargs=0 OR   :call     CocAction('runCommand', 'editor.action.organizeImport')

" Add (Neo)Vim's native statusline support.
" NOTE: Please see `:h coc-status` for integrations with external plugins that
" provide custom statusline: lightline.vim, vim-airline.
set statusline^=%{coc#status()}%{get(b:,'coc_current_function','')}

" Mappings using CoCList:
" Show all diagnostics.
nnoremap <silent> <space>a  :<C-u>CocList diagnostics<cr>
" Manage extensions.
nnoremap <silent> <space>e  :<C-u>CocList extensions<cr>
" Show commands.
nnoremap <silent> <space>c  :<C-u>CocList commands<cr>
" Find symbol of current document.
nnoremap <silent> <space>o  :<C-u>CocList outline<cr>
" Search workspace symbols.
nnoremap <silent> <space>s  :<C-u>CocList -I symbols<cr>
" Do default action for next item.
nnoremap <silent> <space>j  :<C-u>CocNext<CR>
" Do default action for previous item.
nnoremap <silent> <space>k  :<C-u>CocPrev<CR>
" Resume latest coc list.
nnoremap <silent> <space>p  :<C-u>CocListResume<CR>

Articles

Trouble shooting

Try these steps when you have problem with coc.nvim.

  • Make sure your Vim version >= 8.0 by command :version.
  • If service failed to start, use command :CocInfo or :checkhealth on Neovim.
  • Checkout the log of coc.nvim by command :CocOpenLog.
  • When you have issues with the language server, it's recommended to checkout the output.

Feedback

License

MIT

You can’t perform that action at this time.