Enable automatic decoding

Adds functionality to more easily decode a *single* adjacent
entity/escape char, i.e.

  * optional settings to automatically decode the last entered
    entity/escape char, triggered by a space or return

  * decoding commands will now try to replace the adjacent
    entity/escape char when there's no active selection; the
    shortcuts for these commands behave like ALT+X in MS Word

  *Note*
    Selections will mostly decode the same as before; multi-byte
    glyphs can *only* be decoded or encoded when selected (for now)

Also improves handling of selections by:

  * encapsulating logic to clear selections after entity/escape char
    transformation; this prevents accidental deletion of text ranges
    by typing over them

  * only decoding selections of complete entities, i.e. the ';'
    must be included in the selection, which was not the case before!

Author: rdipardo

src/Common/Utf8IniFiles.pas

@@ -0,0 +1,84 @@
+unit Utf8IniFiles;
+
+(*
+  Copyright (c) 2022 Robert Di Pardo <dipardo.r@gmail.com>
+
+  This Source Code Form is subject to the terms of the Mozilla Public
+  License, v. 2.0. If a copy of the MPL was not distributed with this file,
+  You can obtain one at https://mozilla.org/MPL/2.0/.
+*)
+
+{$IFDEF FPC}{$mode delphi}{$ENDIF}
+
+interface
+
+uses SysUtils, IniFiles;
+
+type
+  EUtf8IniFileException = class(Exception);
+  TUtf8IniFile = class(TIniFile)
+{$IFNDEF FPC}
+    constructor Create(const FilePath: string); reintroduce;
+{$ELSE}
+    constructor Create(const FilePath: WideString;
+      Opts: TIniFileOptions = [ifoEscapeLineFeeds, ifoStripQuotes]);
+    destructor Destroy; override;
+{$ENDIF}
+  private
+    procedure MakeIniDir(const iniFileDir: WideString);
+  end;
+
+implementation
+
+{$IFDEF FPC}
+uses Classes;
+{$ENDIF}
+
+{$IFNDEF FPC}
+constructor TUtf8IniFile.Create(const FilePath: string);
+begin
+  MakeIniDir(ExtractFileDir(FilePath));
+  inherited Create(FilePath);
+end;
+
+{$ELSE}
+constructor TUtf8IniFile.Create(const FilePath: WideString; Opts: TIniFileOptions);
+var
+  hIniFile: THandle;
+begin
+  try
+    MakeIniDir(ExtractFileDir(FilePath));
+    hIniFile := FileOpen(FilePath, fmOpenReadWrite or fmShareExclusive);
+    if hIniFile = THandle(-1) then
+      hIniFile := FileCreate(FilePath);
+
+    inherited Create(THandleStream.Create(hIniFile), TEncoding.Utf8, Opts);
+  except
+    on E: Exception do
+    begin
+      FileClose(hIniFile);
+      raise EUtf8IniFileException.Create(E.message);
+    end;
+  end;
+end;
+
+destructor TUtf8IniFile.Destroy;
+begin
+  if Assigned(Self.Stream) then
+  begin
+    FileClose(THandleStream(Self.Stream).Handle);
+    Self.Stream.Free;
+  end;
+
+  inherited;
+end;
+{$ENDIF ~FPC}
+
+procedure TUtf8IniFile.MakeIniDir(const iniFileDir: WideString);
+begin
+  if (not DirectoryExists(iniFileDir)) and (not CreateDir(iniFileDir)) then
+    raise EUtf8IniFileException.Create(Format('Directory "%s" is not writable',
+      [UTF8Encode(iniFileDir)]));
+end;
+
+end.

src/LibNppPlugin/NppSimpleObjects.pas

@@ -37,6 +37,8 @@     TTextRange = class
         FStartPos:  Sci_Position;
         FEndPos:    Sci_Position;
 
+        function  GetAnchor(): Sci_Position;
+        procedure SetAnchor(const AValue: Sci_Position);
         function  GetStart(): Sci_Position; virtual;
         procedure SetStart(const AValue: Sci_Position); virtual;
         function  GetEnd(): Sci_Position; virtual;
@@ -57,10 +59,12 @@     TTextRange = class
         destructor  Destroy; override;
 
         procedure Select();
+        procedure ClearSelection;
         procedure Indent(const Levels: integer = 1);
         procedure Mark(const Style: integer; const DurationInMs: cardinal = 0);
 
         property Document: TActiveDocument  read FEditor;
+        property Anchor: Sci_Position       read GetAnchor        write SetAnchor;
         property StartPos: Sci_Position     read FStartPos        write SetStart;
         property EndPos: Sci_Position       read FEndPos          write SetEnd;
         property Length: Sci_Position       read GetLength        write SetLength;
@@ -75,8 +79,6 @@     TTextRange = class
     { -------------------------------------------------------------------------------------------- }
     TSelection = class(TTextRange)
       protected
-        function  GetAnchor(): Sci_Position;
-        procedure SetAnchor(const AValue: Sci_Position);
         function  GetCurrentPos(): Sci_Position;
         procedure SetCurrentPos(const AValue: Sci_Position);
         function  GetStart(): Sci_Position; override;
@@ -90,7 +92,6 @@     TSelection = class(TTextRange)
       public
         constructor Create(const AEditor: TActiveDocument);
 
-        property Anchor: Sci_Position   read GetAnchor        write SetAnchor;
         property Position: Sci_Position read GetCurrentPos    write SetCurrentPos;
         property StartPos: Sci_Position read GetStart         write SetStart;
         property EndPos: Sci_Position   read GetEnd           write SetEnd;
@@ -143,6 +144,7 @@     TActiveDocument = class(TWindowedObject)
         procedure SetText(const AValue: WideString);
         function  GetLength(): Sci_Position;
         function  GetLineCount(): Sci_Position;
+        function  GetNextLineStart(): Sci_Position;
         function  GetLangType(): LangType;
         procedure SetLangType(const AValue: LangType);
 
@@ -174,6 +176,7 @@     TActiveDocument = class(TWindowedObject)
         property Text: WideString     read GetText      write SetText;
         property Length: Sci_Position read GetLength;
         property LineCount: Sci_Position read GetLineCount;
+        property NextLineStartPosition: Sci_Position read GetNextLineStart;
         property Language: LangType   read GetLangType  write SetLangType;
 
         property CurrentPosition:Sci_Position read GetCurrentPos  write SetCurrentPos;
@@ -301,6 +304,18 @@ destructor TTextRange.Destroy;
   inherited;
 end;
 
+{ ------------------------------------------------------------------------------------------------ }
+function TTextRange.GetAnchor: Sci_Position;
+begin
+  Result := FEditor.SendMessage(SCI_GETANCHOR);
+end;
+
+{ ------------------------------------------------------------------------------------------------ }
+procedure TTextRange.SetAnchor(const AValue: Sci_Position);
+begin
+  FEditor.SendMessage(SCI_SETANCHOR, AValue);
+end;
+
 { ------------------------------------------------------------------------------------------------ }
 
 function TTextRange.GetStart: Sci_Position;
@@ -467,6 +482,18 @@ procedure TTextRange.Select;
   FEditor.SendMessage(SCI_SCROLLCARET);
 end;
 
+{ ------------------------------------------------------------------------------------------------ }
+procedure TTextRange.ClearSelection();
+var
+  SciMsg: Cardinal;
+begin
+  if (Self.Anchor > FEditor.CurrentPosition) then
+    SciMsg := SCI_POSITIONBEFORE
+  else
+    SciMsg := SCI_POSITIONAFTER;
+  FEditor.CurrentPosition := FEditor.SendMessage(SciMsg, FEditor.CurrentPosition);
+end;
+
 { ================================================================================================ }
 { TSelection }
 
@@ -477,18 +504,6 @@ constructor TSelection.Create(const AEditor: TActiveDocument);
 
 { ------------------------------------------------------------------------------------------------ }
 
-function TSelection.GetAnchor: Sci_Position;
-begin
-  Result := FEditor.SendMessage(SCI_GETANCHOR);
-end;
-{ ------------------------------------------------------------------------------------------------ }
-procedure TSelection.SetAnchor(const AValue: Sci_Position);
-begin
-  FEditor.SendMessage(SCI_SETANCHOR, AValue);
-end;
-
-{ ------------------------------------------------------------------------------------------------ }
-
 function TSelection.GetCurrentPos: Sci_Position;
 begin
   Result := FEditor.SendMessage(SCI_GETCURRENTPOS);
@@ -864,6 +879,16 @@ function TActiveDocument.GetLineCount: Sci_Position;
 
 { ------------------------------------------------------------------------------------------------ }
 
+function TActiveDocument.GetNextLineStart(): Sci_Position;
+var
+  LineEndCurrent: Sci_Position;
+begin
+  LineEndCurrent := SendMessage(SCI_GETLINEENDPOSITION, SendMessage(SCI_LINEFROMPOSITION, CurrentPosition));
+  Result := SendMessage(SCI_POSITIONAFTER, LineEndCurrent);
+end;
+
+{ ------------------------------------------------------------------------------------------------ }
+
 function TActiveDocument.GetLines(const FirstLine: Sci_Position; const Count: Sci_Position): TTextRange;
 var
   LineCount: Sci_Position;

src/LibNppPlugin/nppplugin.pas

@@ -42,13 +42,13 @@ interface
 
   TNppPlugin = class(TObject)
   private
-    FuncArray: array of _TFuncItem;
     FClosingBufferID: THandle;
     FConfigDir: string;
     function IsDarkModeEnabled: Boolean;
     function MinSubsystemIsVista: Boolean;
   protected
     PluginName: nppString;
+    FuncArray: array of _TFuncItem;
     function SupportsBigFiles: Boolean;
     function HasV5Apis: Boolean;
     function HasFullRangeApis: Boolean;
@@ -81,6 +81,7 @@   TNppPlugin = class(TObject)
     procedure DoNppnShutdown; virtual;
     procedure DoNppnBufferActivated(const BufferID: THandle); virtual;
     procedure DoNppnFileClosed(const BufferID: THandle); virtual;
+    procedure DoCharAdded(const hwnd: HWND; const ch: Integer); virtual;
     procedure DoUpdateUI(const hwnd: HWND; const updated: Integer); virtual;
     procedure DoModified(const hwnd: HWND; const modificationType: Integer); virtual;
 
@@ -214,6 +215,10 @@ procedure TNppPlugin.BeNotified(sn: PSCNotification);
       end;
     end else begin
       case sn.nmhdr.code of
+        SCN_CHARADDED: begin
+          if (sn.characterSource = SC_CHARACTERSOURCE_DIRECT_INPUT) then
+            Self.DoCharAdded(HWND(sn.nmhdr.hwndFrom), sn.ch);
+        end;
         SCN_MODIFIED: begin
           Self.DoModified(HWND(sn.nmhdr.hwndFrom), sn.modificationType);
         end;
@@ -260,6 +265,10 @@ procedure TNppPlugin.DoNppnFileClosed(const BufferID: THandle);
   // override these
 end;
 
+procedure TNppPlugin.DoCharAdded(const hwnd: HWND; const ch: Integer);
+begin
+end;
+
 procedure TNppPlugin.DoModified(const hwnd: HWND; const modificationType: Integer);
 begin
   // override these

src/U_Entities.pas

@@ -23,7 +23,7 @@ interface
 procedure EncodeEntities(const Scope: TEntityReplacementScope = ersSelection; const Options: TEntityReplacementOptions = []);
 function  DoEncodeEntities(var Text: WideString; const Entities: TStringList; const Options: TEntityReplacementOptions): Integer;
 
-procedure DecodeEntities(const Scope: TEntityReplacementScope = ersSelection);
+function DecodeEntities(const Scope: TEntityReplacementScope = ersSelection): Integer;
 
 ////////////////////////////////////////////////////////////////////////////////////////////////////
 implementation
@@ -158,6 +158,7 @@ procedure EncodeEntities(const Scope: TEntityReplacementScope; const Options: TE
       Text := doc.Selection.Text;
       if DoEncodeEntities(Text, FetchEntities, Options) > 0 then begin
         doc.Selection.Text := Text;
+        doc.Selection.ClearSelection;
       end;
     end;
   end{case};
@@ -203,7 +204,7 @@ function DoEncodeEntities(var Text: WideString; const Entities: TStringList; con
 end;
 
 { ------------------------------------------------------------------------------------------------ }
-procedure DecodeEntities(const Scope: TEntityReplacementScope = ersSelection);
+function DecodeEntities(const Scope: TEntityReplacementScope = ersSelection): Integer;
 const
   scDigits = '0123456789';
   scHexLetters = 'ABCDEFabcdef';
@@ -233,8 +234,12 @@ procedure DecodeEntities(const Scope: TEntityReplacementScope = ersSelection);
     Exit;
 
   Text := doc.Selection.Text;
-
   CharIndex := Pos('&', Text);
+
+  // make sure the selection includes the semicolon
+  if not (Pos(';', Text) > CharIndex) then
+    Exit;
+
   while CharIndex > 0 do begin
     FirstPos := CharIndex;
     LastPos := FirstPos;
@@ -324,7 +329,10 @@ procedure DecodeEntities(const Scope: TEntityReplacementScope = ersSelection);
 
   if EntitiesReplaced > 0 then begin
     doc.Selection.Text := Text;
+    doc.Selection.ClearSelection;
   end;
+
+  Result := EntitiesReplaced;
 end;
 
 ////////////////////////////////////////////////////////////////////////////////////////////////////

src/U_JSEncode.pas

@@ -23,7 +23,6 @@ function  DecodeJS(Scope: TEntityReplacementScope = ersSelection): Integer;
 ////////////////////////////////////////////////////////////////////////////////////////////////////
 implementation
 uses
-  Windows,
   SysUtils,
   NppPlugin;
 
@@ -100,6 +99,7 @@ function DoEncodeJS(const Range: TTextRange): Integer; overload;
   Result := DoEncodeJS(Text);
   if Result > 0 then begin
     Range.Text := Text;
+    Range.ClearSelection;
   end;
 end{DoEncodeJS};
 
@@ -162,8 +162,7 @@ function DecodeJS(Scope: TEntityReplacementScope = ersSelection): Integer;
       end;
     until Match.Length = 0;
 
-    if ((Result > 1) and (Target.StartPos > 0)) then
-      doc.SendMessage(SCI_SETSEL, doc.Selection.StartPos, doc.SendMessage(SCI_POSITIONBEFORE, doc.Selection.EndPos));
+    if Result > 0 then doc.Selection.ClearSelection;
   finally
     Target.Free;
     Match.Free;