Add/fix caching on some configure checks

Author: petere

config/c-compiler.m4

@@ -126,13 +126,18 @@ fi])# PGAC_C_FUNCNAME_SUPPORT
 # Given a string, check if the compiler supports the string as a
 # command-line option. If it does, add the string to CFLAGS.
 AC_DEFUN([PGAC_PROG_CC_CFLAGS_OPT],
-[AC_MSG_CHECKING([if $CC supports $1])
-pgac_save_CFLAGS=$CFLAGS
+[define([Ac_cachevar], [AS_TR_SH([pgac_cv_prog_cc_cflags_$1])])dnl
+AC_CACHE_CHECK([whether $CC supports $1], [Ac_cachevar],
+[pgac_save_CFLAGS=$CFLAGS
 CFLAGS="$pgac_save_CFLAGS $1"
 _AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],
-                   AC_MSG_RESULT(yes),
-                   [CFLAGS="$pgac_save_CFLAGS"
-                    AC_MSG_RESULT(no)])
+                   [Ac_cachevar=yes],
+                   [Ac_cachevar=no])
+CFLAGS="$pgac_save_CFLAGS"])
+if test x"$Ac_cachevar" = x"yes"; then
+  CFLAGS="$CFLAGS $1"
+fi
+undefine([Ac_cachevar])dnl
 ])# PGAC_PROG_CC_CFLAGS_OPT
 
 
@@ -145,13 +150,17 @@ _AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],
 # you can link to a particular function, not just whether you can link.
 # In fact, we must actually check that the resulting program runs :-(
 AC_DEFUN([PGAC_PROG_CC_LDFLAGS_OPT],
-[AC_MSG_CHECKING([if $CC supports $1])
-pgac_save_LDFLAGS=$LDFLAGS
+[define([Ac_cachevar], [AS_TR_SH([pgac_cv_prog_cc_ldflags_$1])])dnl
+AC_CACHE_CHECK([whether $CC supports $1], [Ac_cachevar],
+[pgac_save_LDFLAGS=$LDFLAGS
 LDFLAGS="$pgac_save_LDFLAGS $1"
 AC_RUN_IFELSE([AC_LANG_PROGRAM([extern void $2 (); void (*fptr) () = $2;],[])],
-              AC_MSG_RESULT(yes),
-              [LDFLAGS="$pgac_save_LDFLAGS"
-               AC_MSG_RESULT(no)],
-              [LDFLAGS="$pgac_save_LDFLAGS"
-               AC_MSG_RESULT(assuming no)])
+              [Ac_cachevar=yes],
+              [Ac_cachevar=no],
+              [Ac_cachevar="assuming no"])
+LDFLAGS="$pgac_save_LDFLAGS"])
+if test x"$Ac_cachevar" = x"yes"; then
+  LDFLAGS="$LDFLAGS $1"
+fi
+undefine([Ac_cachevar])dnl
 ])# PGAC_PROG_CC_LDFLAGS_OPT

config/programs.m4

@@ -117,15 +117,14 @@ AC_SUBST(FLEXFLAGS)
 AC_DEFUN([PGAC_CHECK_READLINE],
 [AC_REQUIRE([AC_CANONICAL_HOST])
 
-AC_CACHE_VAL([pgac_cv_check_readline],
+AC_CACHE_CHECK([for library containing readline], [pgac_cv_check_readline],
 [pgac_cv_check_readline=no
 pgac_save_LIBS=$LIBS
 if test x"$with_libedit_preferred" != x"yes"
 then	READLINE_ORDER="-lreadline -ledit"
 else	READLINE_ORDER="-ledit -lreadline"
 fi
 for pgac_rllib in $READLINE_ORDER ; do
-  AC_MSG_CHECKING([for ${pgac_rllib}])
   for pgac_lib in "" " -ltermcap" " -lncurses" " -lcurses" ; do
     LIBS="${pgac_rllib}${pgac_lib} $pgac_save_LIBS"
     AC_TRY_LINK_FUNC([readline], [[
@@ -144,14 +143,11 @@ for pgac_rllib in $READLINE_ORDER ; do
     ]])
   done
   if test "$pgac_cv_check_readline" != no ; then
-    AC_MSG_RESULT([yes ($pgac_cv_check_readline)])
     break
-  else
-    AC_MSG_RESULT(no)
   fi
 done
 LIBS=$pgac_save_LIBS
-])[]dnl AC_CACHE_VAL
+])[]dnl AC_CACHE_CHECK
 
 if test "$pgac_cv_check_readline" != no ; then
   LIBS="$pgac_cv_check_readline $LIBS"
@@ -167,19 +163,21 @@ fi
 # Readline versions < 2.1 don't have rl_completion_append_character
 
 AC_DEFUN([PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER],
-[AC_MSG_CHECKING([for rl_completion_append_character])
-AC_TRY_LINK([#include <stdio.h>
+[AC_CACHE_CHECK([for rl_completion_append_character], pgac_cv_var_rl_completion_append_character,
+[AC_TRY_LINK([#include <stdio.h>
 #ifdef HAVE_READLINE_READLINE_H
 # include <readline/readline.h>
 #elif defined(HAVE_READLINE_H)
 # include <readline.h>
 #endif
 ],
 [rl_completion_append_character = 'x';],
-[AC_MSG_RESULT(yes)
+[pgac_cv_var_rl_completion_append_character=yes],
+[pgac_cv_var_rl_completion_append_character=no])])
+if test x"$pgac_cv_var_rl_completion_append_character" = x"yes"; then
 AC_DEFINE(HAVE_RL_COMPLETION_APPEND_CHARACTER, 1,
-          [Define to 1 if you have the global variable 'rl_completion_append_character'.])],
-[AC_MSG_RESULT(no)])])# PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
+          [Define to 1 if you have the global variable 'rl_completion_append_character'.])
+fi])# PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER