Write some tests for device controller

Author: angelsl

test/cadet_web/controllers/devices_controller_test.exs

@@ -0,0 +1,97 @@
+defmodule DevicesControllerTest do
+  use CadetWeb.ConnCase
+
+  alias Cadet.Devices.DeviceRegistration
+  alias Cadet.Repo
+
+  setup do
+    device = insert(:device)
+    %{device: device}
+  end
+
+  describe "GET /devices" do
+    @tag authenticate: :student
+    test "succeeds if authenticated", %{conn: conn, device: device} do
+      registration = insert_registration(conn, device)
+
+      assert [
+               %{
+                 "id" => registration.id,
+                 "secret" => device.secret,
+                 "title" => registration.title,
+                 "type" => device.type
+               }
+             ] ==
+               conn
+               |> get("/v1/devices")
+               |> json_response(200)
+    end
+
+    test "401 if unauthenticated", %{conn: conn} do
+      assert conn
+             |> get("/v1/devices")
+             |> response(401)
+    end
+  end
+
+  describe "POST /devices" do
+    @tag authenticate: :student
+    test "succeeds if authenticated", %{conn: conn, device: device} do
+      registration = make_json_registration(device)
+
+      assert response =
+               conn
+               |> post("/v1/devices", registration)
+               |> json_response(200)
+
+      assert registration["title"] == response["title"]
+      assert device.secret == response["secret"]
+      assert device.type == response["type"]
+    end
+
+    @tag authenticate: :student
+    test "fails if conflicting type", %{conn: conn, device: device} do
+      registration = %{make_json_registration(device) | "type" => "installation 00"}
+
+      assert conn
+             |> post("/v1/devices", registration)
+             |> response(400)
+    end
+
+    @tag authenticate: :student
+    test "fails if invalid", %{conn: conn, device: device} do
+      registration = %{make_json_registration(device) | "secret" => ""}
+
+      assert conn
+             |> post("/v1/devices", registration)
+             |> response(400)
+    end
+
+    test "401 if unauthenticated", %{conn: conn, device: device} do
+      registration = make_json_registration(device)
+
+      assert conn
+             |> post("/v1/devices", registration)
+             |> response(401)
+    end
+  end
+
+  defp make_json_registration(device) do
+    %{
+      "title" => Faker.App.name(),
+      "type" => device.type,
+      "secret" => device.secret
+    }
+  end
+
+  defp insert_registration(conn, device) do
+    %DeviceRegistration{}
+    |> DeviceRegistration.changeset(%{
+      title: Faker.App.name(),
+      user_id: conn.assigns.current_user.id,
+      device_id: device.id
+    })
+    |> Repo.insert()
+    |> elem(1)
+  end
+end