File I/O support is missing

[JohnLamontagne1996]

When Is File I/O coming, as I have a few errors

[JohnLamontagne1996]

All of these errors are nonexistent in my Visual Basic 6 application, but it seems for Twinbasic they're problems :(

[dmrvb]

I don't think Wayne has implemented any of the File Handling stuff yet. Wayne, can you do this before you get bogged down in the GUI and Form Designer???? .......Dave

…

On 19/07/2021 01:45, JohnLamontagne1996 wrote: All of these errors are nonexistent in my Visual Basic 6 application, but it seems for Twinbasic they're problems :( — You are receiving this because you are subscribed to this thread. Reply to this email directly, view it on GitHub <#279 (comment)>, or unsubscribe <https://github.com/notifications/unsubscribe-auth/AT752Y2EFOMLEZS2AUMF4FLTYNYSTANCNFSM5ASVK4CQ>.

-- ----------------------------------------------- Dave Rhodes Bespoke Software, Instrumentation and Technology for Engineering Sound and Vibration.

------------------------------------------------

-- This email has been checked for viruses by AVG. https://www.avg.com

[WaynePhillipsEA]

Thanks for opening the issue. Indeed, as noted in the preview information page (https://www.twinbasic.com/preview.html), we haven't implemented any of the file I/O part of the language yet. That's the only major part of the language that is significantly missing at the moment. For now please consider using the FSO alternatives.

After we've released the first part of the GUI support over the next couple of weeks, we'll be looking at the file I/O support.

I'll leave this issue open, since I don't think we've got another issue that covers it.

[KarlSevenSeven]

The missing file support makes headaches to me.
I can't try some certain DLL code I want to play with without heavily modifying the file parts in it.
The answer "after we support forms" is known.
Before we have file support I can't do some tests, therefore too vague for a preorder.
So my question is when the file stuff will be really available.

[WaynePhillipsEA]

All I can say at the moment is that this is very high on the list of things to be done now.

We'll be updating the roadmap (#75) on or before Monday 9th August with more information.

I appreciate that this feature is heavily used by many, and is preventing testing/adoption of twinBASIC. Good things come to those who wait 😉

[Kr00l]

I just want to share my Dir() unicode replacement function which aims to be 100% compatible. Maybe it can help..

' (VB-Overwrite)
Public Function Dir(Optional ByVal PathMask As String, Optional ByVal Attributes As VbFileAttribute = vbNormal) As String
Const INVALID_HANDLE_VALUE As Long = (-1)
Const FILE_ATTRIBUTE_NORMAL As Long = &H80
Static hFindFile As Long, AttributesCache As VbFileAttribute
If Attributes = vbVolume Then ' Exact match
    ' If any other attribute is specified, vbVolume is ignored.
    If hFindFile <> 0 Then
        FindClose hFindFile
        hFindFile = 0
    End If
    Dim VolumePathBuffer As String, VolumeNameBuffer As String
    If Len(PathMask) = 0 Then
        VolumeNameBuffer = String$(MAX_PATH, vbNullChar)
        If GetVolumeInformation(0, StrPtr(VolumeNameBuffer), Len(VolumeNameBuffer), ByVal 0, ByVal 0, ByVal 0, 0, 0) <> 0 Then Dir = Left$(VolumeNameBuffer, InStr(VolumeNameBuffer, vbNullChar) - 1)
    Else
        VolumePathBuffer = String$(MAX_PATH, vbNullChar)
        If Left$(PathMask, 2) = "\\" Then PathMask = "UNC\" & Mid$(PathMask, 3)
        If GetVolumePathName(StrPtr("\\?\" & PathMask), StrPtr(VolumePathBuffer), Len(VolumePathBuffer)) <> 0 Then
            VolumePathBuffer = Left$(VolumePathBuffer, InStr(VolumePathBuffer, vbNullChar) - 1)
            VolumeNameBuffer = String$(MAX_PATH, vbNullChar)
            If GetVolumeInformation(StrPtr(VolumePathBuffer), StrPtr(VolumeNameBuffer), Len(VolumeNameBuffer), ByVal 0, ByVal 0, ByVal 0, 0, 0) <> 0 Then Dir = Left$(VolumeNameBuffer, InStr(VolumeNameBuffer, vbNullChar) - 1)
        End If
    End If
Else
    Dim FD As WIN32_FIND_DATA, dwMask As Long
    If Len(PathMask) = 0 Then
        If hFindFile <> 0 Then
            If FindNextFile(hFindFile, FD) = 0 Then
                FindClose hFindFile
                hFindFile = 0
                Exit Function
            End If
        Else
            Err.Raise 5
            Exit Function
        End If
    Else
        If hFindFile <> 0 Then
            FindClose hFindFile
            hFindFile = 0
        End If
        Select Case Right$(PathMask, 1)
            Case "\", ":", "/"
                PathMask = PathMask & "*.*"
        End Select
        AttributesCache = Attributes
        If Left$(PathMask, 2) = "\\" Then PathMask = "UNC\" & Mid$(PathMask, 3)
        hFindFile = FindFirstFile(StrPtr("\\?\" & PathMask), FD)
        If hFindFile = INVALID_HANDLE_VALUE Then
            hFindFile = 0
            If Err.LastDllError > 12 Then Err.Raise 52
            Exit Function
        End If
    End If
    Do
        If FD.dwFileAttributes = FILE_ATTRIBUTE_NORMAL Then
            dwMask = 0 ' Found
        Else
            dwMask = FD.dwFileAttributes And (Not AttributesCache) And &H16
        End If
        If dwMask = 0 Then
            Dir = Left$(FD.lpszFileName(), InStr(FD.lpszFileName(), vbNullChar) - 1)
            If FD.dwFileAttributes And vbDirectory Then
                If Dir <> "." And Dir <> ".." Then Exit Do ' Exclude self and relative path aliases
            Else
                Exit Do
            End If
        End If
        If FindNextFile(hFindFile, FD) = 0 Then
            FindClose hFindFile
            hFindFile = 0
            Exit Do
        End If
    Loop
End If
End Function

[WaynePhillipsEA]

Fantastic @Kr00l. I will test it later this week. Would you allow me to incorporate it into tB?

[Kr00l]

Sure @WaynePhillipsEA you can use it.

Something to think about is the FileLen function. It returns in VBx a 'Long'.
The API is..
LoDWord = GetFileSize(hFile, HiDWord)

So TB could make a 'FileLen2' function (or whatever name is better) to return a 'LongLong' which joins LoDWord and HiDWord.

[Kr00l]

Here another few functions which may help and you can look at/use.

' (VB-Overwrite)
Public Function GetAttr(ByVal PathName As String) As VbFileAttribute
Const INVALID_FILE_ATTRIBUTES As Long = (-1)
Const FILE_ATTRIBUTE_NORMAL As Long = &H80
If Left$(PathName, 2) = "\\" Then PathName = "UNC\" & Mid$(PathName, 3)
Dim dwAttributes As Long
dwAttributes = GetFileAttributes(StrPtr("\\?\" & PathName))
If dwAttributes = INVALID_FILE_ATTRIBUTES Then
    Err.Raise 53
ElseIf dwAttributes = FILE_ATTRIBUTE_NORMAL Then
    GetAttr = vbNormal
Else
    GetAttr = dwAttributes
End If
End Function

' (VB-Overwrite)
Public Sub SetAttr(ByVal PathName As String, ByVal Attributes As VbFileAttribute)
Const FILE_ATTRIBUTE_NORMAL As Long = &H80
Dim dwAttributes As Long
If Attributes = vbNormal Then
    dwAttributes = FILE_ATTRIBUTE_NORMAL
Else
    If (Attributes And (vbVolume Or vbDirectory Or vbAlias)) <> 0 Then Err.Raise 5
    dwAttributes = Attributes
End If
If Left$(PathName, 2) = "\\" Then PathName = "UNC\" & Mid$(PathName, 3)
If SetFileAttributes(StrPtr("\\?\" & PathName), dwAttributes) = 0 Then Err.Raise 53
End Sub

' (VB-Overwrite)
Public Sub MkDir(ByVal PathName As String)
If Left$(PathName, 2) = "\\" Then PathName = "UNC\" & Mid$(PathName, 3)
If CreateDirectory(StrPtr("\\?\" & PathName), 0) = 0 Then
    Const ERROR_PATH_NOT_FOUND As Long = 3
    If Err.LastDllError = ERROR_PATH_NOT_FOUND Then
        Err.Raise 76
    Else
        Err.Raise 75
    End If
End If
End Sub

' (VB-Overwrite)
Public Sub RmDir(ByVal PathName As String)
If Left$(PathName, 2) = "\\" Then PathName = "UNC\" & Mid$(PathName, 3)
If RemoveDirectory(StrPtr("\\?\" & PathName)) = 0 Then
    Const ERROR_FILE_NOT_FOUND As Long = 2
    If Err.LastDllError = ERROR_FILE_NOT_FOUND Then
        Err.Raise 76
    Else
        Err.Raise 75
    End If
End If
End Sub

[dmrvb]

Rather than including this code directly into twinBASIC an option might be to put it into a module, in fact the entire File system could be a module with the source code available. Hence the file system becomes an extension to twinBASIC written in twinBASIC (with API calls) which is rather nice. Making extensions open source means that others could help with code development with Wayne still keeping control of the core code. A new module would be needed for each cross platform target which again could be contributed from the community. Could probably do the same with the VB graphics system???