wasm: add basic for x in start .. end { support (#26248)

Author: SheatNoisette

vlib/v/gen/wasm/gen.v

@@ -1039,6 +1039,49 @@ pub fn (mut g Gen) expr(node ast.Expr, expected ast.Type) {
 	}
 }
 
+pub fn (mut g Gen) for_in_stmt(node ast.ForInStmt) {
+	loop_var_type := unpack_literal_int(node.val_type)
+	block := g.func.c_block([], [])
+	{
+		mut loop_var := Var{}
+		loop_var = g.new_local(node.val_var, loop_var_type)
+
+		g.expr(node.cond, loop_var_type)
+		g.set(loop_var)
+
+		loop := g.func.c_loop([], [])
+		{
+			g.loop_breakpoint_stack << LoopBreakpoint{
+				c_continue: loop
+				c_break:    block
+				name:       node.label
+			}
+
+			g.get(loop_var)
+			g.expr(node.high, loop_var_type)
+			wtyp := g.as_numtype(g.get_wasm_type(loop_var_type))
+			g.func.lt(wtyp, loop_var_type.is_signed())
+			g.func.eqz(.i32_t)
+			g.func.c_br_if(block)
+
+			g.expr_stmts(node.stmts, ast.void_type)
+
+			g.set_prepare(loop_var)
+			{
+				g.get(loop_var)
+				g.literalint(1, loop_var_type)
+				g.func.add(wtyp)
+			}
+			g.set(loop_var)
+
+			g.func.c_br(loop)
+			g.loop_breakpoint_stack.pop()
+		}
+		g.func.c_end(loop)
+	}
+	g.func.c_end(block)
+}
+
 pub fn (g &Gen) file_pos(pos token.Pos) string {
 	return '${g.file_path}:${pos.line_nr + 1}:${pos.col + 1}'
 }
@@ -1123,6 +1166,9 @@ pub fn (mut g Gen) expr_stmt(node ast.Stmt, expected ast.Type) {
 			}
 			g.func.c_end(block)
 		}
+		ast.ForInStmt {
+			g.for_in_stmt(node)
+		}
 		ast.BranchStmt {
 			mut bp := g.loop_breakpoint_stack.last()
 			if node.label != '' {

vlib/v/gen/wasm/tests/for_in_range.vv

@@ -0,0 +1,77 @@
+fn simple_range() int {
+	mut sum := 0
+	for i in 0 .. 5 {
+		sum += i
+	}
+	return sum
+}
+
+fn negative_range() int {
+	mut sum := 0
+	for i in -99 .. -2 {
+		sum += i
+	}
+	return sum
+}
+
+fn inverted_range() int {
+	mut sum := 0
+	// Should be skipped
+	for i in 5 .. 0 {
+		sum += i
+	}
+	return sum
+}
+
+fn range_with_string() int {
+	strc := 'This is a test!'
+	mut sum := 0
+	for i in 0 .. strc.len {
+		sum += i
+	}
+	return sum
+}
+
+fn range_with_expr() int {
+	start := 2
+	end := 7
+	mut sum := 0
+	for i in start .. end {
+		sum += i
+	}
+	return sum
+}
+
+fn range_dual() int {
+	a := 128
+	mut sum := 0
+	for i in 0 .. a {
+		sum += i
+		for j in -20 .. a {
+			sum += j
+		}
+	}
+	return sum
+}
+
+fn main() {
+	println('--- inverted_range()')
+	println(inverted_range())
+
+	println('--- negative_range()')
+	println(negative_range())
+
+	println('--- simple_range()')
+	println(simple_range())
+
+	println('--- range_with_string()')
+	println(range_with_string())
+
+	println('--- range_with_expr()')
+	println(range_with_expr())
+
+	println('--- range_dual()')
+	println(range_dual())
+
+	// Currently, the backend doesn't support maps, list etc. iteration is not possible
+}

vlib/v/gen/wasm/tests/for_in_range.vv.out

@@ -0,0 +1,12 @@
+--- inverted_range()
+0
+--- negative_range()
+-4947
+--- simple_range()
+10
+--- range_with_string()
+105
+--- range_with_expr()
+20
+--- range_dual()
+1021632