tools: implement v git-fmt-hook, v git-fmt-hook install, v git-fmt-hook remove + tests for them (#25855)

Author: spytheman

.github/workflows/tools_ci.yml

@@ -35,7 +35,7 @@ jobs:
     steps:
       - uses: actions/checkout@v6
       - name: Build V
-        run: make -j4 && ./v -showcc -o v cmd/v && ./v doctor
+        run: make && ./v -showcc -o v cmd/v && ./v symlink && ./v doctor
       - name: Code in cmd/ is formatted
         run: ./v fmt -verify cmd/
       - name: Check build-tools
@@ -75,7 +75,7 @@ jobs:
     steps:
       - uses: actions/checkout@v6
       - name: Build V
-        run: make -j4 && ./v -showcc -o v cmd/v && ./v doctor
+        run: make && ./v -showcc -o v cmd/v && ./v symlink && ./v doctor
       - name: Check build-tools
         run: ./v -silent -N -W -check build-tools
       - name: Test tools
@@ -95,7 +95,7 @@ jobs:
     steps:
       - uses: actions/checkout@v6
       - name: Build V
-        run: ./make.bat -${{ matrix.cc }} && ./v -o v2.exe cmd/v && ./v2 -showcc -o v.exe cmd/v && ./v doctor
+        run: ./make.bat -${{ matrix.cc }} && ./v -o v2.exe cmd/v && ./v2 -showcc -o v.exe cmd/v && ./v symlink && ./v doctor
       - name: Check build tools
         run: ./v build-tools
       - name: Test tools
@@ -119,7 +119,7 @@ jobs:
       - name: Checkout
         uses: actions/checkout@v6
       - name: Build V
-        run: make -j4 && ./v -cg -o v cmd/v
+        run: make && ./v -cg -o v cmd/v && ./v symlink
       - name: Ensure git commands can be used with no prompts on modern Git versions
         run: git config --global --add safe.directory /__w/v/v
       - name: Verify `v test` works

cmd/tools/vgit-fmt-hook.v

@@ -0,0 +1,126 @@
+import os
+import crypto.sha256
+
+const vexe = os.getenv_opt('VEXE') or { panic('missing VEXE env variable') }
+const vroot = os.to_slash(os.real_path(os.dir(vexe)))
+const horiginal = os.to_slash(os.join_path(vroot, 'cmd/tools/git_pre_commit_hook.vsh'))
+
+fn get_hook_target(git_folder string) string {
+	return os.to_slash(os.join_path(git_folder, 'hooks/pre-commit'))
+}
+
+fn main() {
+	git_folder := find_nearest_top_level_folder_with_a_git_subfolder(os.getwd()) or {
+		eprintln('This command has to be run inside a Git repository.')
+		exit(0)
+	}
+	os.chdir(git_folder)!
+	htarget := get_hook_target(git_folder)
+	cmd := os.args[2] or { 'status' }
+	match cmd {
+		'status' {
+			cmd_status(htarget)
+		}
+		'install' {
+			cmd_install(htarget)
+		}
+		'remove' {
+			cmd_remove(htarget)
+		}
+		else {
+			eprintln('Unknown command `${cmd}`. Known commands are: `status`, `install` or `remove`')
+			exit(1)
+		}
+	}
+}
+
+fn cmd_status(htarget string) {
+	report_status(htarget, true)
+}
+
+fn cmd_install(htarget string) {
+	report_status(htarget, false)
+	println('> Installing the newest version of ${horiginal} over ${htarget} ...')
+	os.cp(horiginal, htarget) or { err_exit('failed to copy to ${htarget}') }
+	println('> Done.')
+}
+
+fn cmd_remove(htarget string) {
+	report_status(htarget, false)
+	if !os.exists(htarget) {
+		err_exit('file ${htarget} has been removed already')
+	}
+	println('> Removing ${htarget} ...')
+	os.rm(htarget) or { err_exit('failed to remove ${htarget}') }
+	println('> Done.')
+}
+
+fn report_status(htarget string, show_instructions bool) {
+	ostat := os.stat(horiginal) or { os.Stat{} }
+	tstat := os.stat(htarget) or { os.Stat{} }
+	ohash := hash_file(horiginal) or { '' }
+	thash := hash_file(htarget) or { '' }
+	if os.exists(htarget) && os.is_file(htarget) {
+		println('>   CURRENT git repo pre-commit hook: size: ${tstat.size:6} bytes, sha256: ${thash}, ${htarget}')
+	} else {
+		println('>   CURRENT git repo pre-commit hook: missing ${htarget}')
+	}
+	if os.exists(horiginal) && os.is_file(horiginal) {
+		println('> Main V repo pre-commit hook script: size: ${ostat.size:6} bytes, sha256: ${ohash}, ${horiginal}')
+	}
+	if ohash == thash {
+		println('> Both files are exactly the same.')
+		if show_instructions {
+			show_msg_about_removing(htarget)
+		}
+		return
+	}
+	println('> Files have different hashes.')
+	if ohash != '' && thash != '' {
+		existing_content := os.read_file(htarget) or { '' }
+		if !existing_content.contains('hooks.stopCommitOfNonVfmtedVFiles') {
+			// both files do exist, but the current git repo hook, is not compatible (an older version of git_pre_commit_hook.vsh):
+			err_exit('the existing file ${htarget} , does not appear to be a compatible V formatting hook\nYou have to remove it manually')
+		}
+	}
+	if show_instructions {
+		println("> Use `v git-fmt-hook install` to update the CURRENT repository's pre-commit hook,")
+		println('> with the newest pre-commit formatting script from the main V repo.')
+		show_msg_about_removing(htarget)
+	}
+}
+
+fn show_msg_about_removing(htarget string) {
+	if os.exists(htarget) {
+		println("> Use `v git-fmt-hook remove` to remove the CURRENT repository's pre-commit hook.")
+	}
+}
+
+fn find_nearest_top_level_folder_with_a_git_subfolder(current string) ?string {
+	mut cfolder := os.to_slash(os.real_path(current))
+	for level := 0; level < 255; level++ {
+		if cfolder == '/' || cfolder == '' {
+			break
+		}
+		git_folder := os.join_path(cfolder, '.git')
+		if os.is_dir(git_folder) {
+			return git_folder
+		}
+		cfolder = os.dir(cfolder)
+	}
+	return none
+}
+
+fn hash_file(path string) !string {
+	fbytes := os.read_bytes(path)!
+	mut digest256 := sha256.new()
+	digest256.write(fbytes)!
+	mut sum256 := digest256.sum([])
+	return sum256.hex()
+}
+
+@[no_return]
+fn err_exit(msg string) {
+	eprintln('> error: ${msg} .')
+	exit(0) // note: this is important, since the command is ran in `v up` and during `make`
+}

cmd/tools/vgit-fmt-hook_test.v

@@ -0,0 +1,200 @@
+import os
+
+const vexe = @VEXE
+const tfolder = os.to_slash(os.join_path(os.vtmp_dir(), 'fmt_hook_test'))
+const unformatted_content = '   fn main() {\nprintln(   "hi" )\n println ( 123 )\n   }'
+const formatted_content = "fn main() {\n\tprintln('hi')\n\tprintln(123)\n}\n"
+const hook_file = '.git/hooks/pre-commit'
+const foreign_script = '#!/usr/bin/env -S v -raw-vsh-tmp-prefix tmp\nprintln("hello hello")'
+
+const git = os.to_slash(os.find_abs_path_of_executable('git') or {
+	eprintln('git is needed for this test, skipping...')
+	exit(0)
+})
+
+const v = os.to_slash(os.find_abs_path_of_executable('v') or {
+	eprintln('v needs to be installed and available on the path for this test, skipping...')
+	exit(0)
+})
+
+fn testsuite_begin() {
+	unbuffer_stdout()
+	eprintln('>>>>>> preparing tfolder: ${tfolder}')
+	full_remove(tfolder) or {}
+	os.mkdir_all(tfolder) or { panic('> could not create ${tfolder}, err: ${err}') }
+	os.chdir(tfolder)!
+	os.write_file('main.v', unformatted_content) or { panic(err) }
+	assert !os.is_dir('.git')
+	os.execute_or_exit('git init .')
+	os.execute_or_exit('git config core.eol lf')
+	os.execute_or_exit('git config core.autocrlf input')
+	os.execute_or_exit('git config user.email "me@example.com"')
+	os.execute_or_exit('git config user.name "Myself"')
+	assert os.is_dir('.git')
+	os.execute_or_exit('git add .')
+	os.execute_or_exit('git commit -m "start testing, initially unformatted"')
+	os.execute_or_exit('git checkout -b start') // use a known name, instead of master or main or who knows what else ...
+	assert read_file('main.v') == unformatted_content
+	// show_git_status()	
+}
+
+fn testsuite_end() {
+	reset_to_start_state()
+	show_git_status()
+	os.chdir(os.wd_at_startup)!
+	full_remove(tfolder)!
+	eprintln('>>>>>> deleted ${tfolder}')
+	assert true
+}
+
+fn test_commit_no_vfmt() {
+	eprintln('>>>> ${@FN}')
+	reset_to_start_state()
+	assert os.execute_or_exit('git checkout -b unformatted').exit_code == 0
+	append('main.v', '//') or { panic(err) }
+	assert os.execute_or_exit('git add .').exit_code == 0
+	assert os.execute_or_exit('git commit -m "unformatted change"').exit_code == 0
+	assert os.execute_or_exit('git diff start').exit_code == 0
+	assert read_file('main.v').starts_with(unformatted_content)
+}
+
+fn test_run_vfmt_manually() {
+	eprintln('>>>> ${@FN}')
+	reset_to_start_state()
+	assert os.execute_or_exit('git checkout -b formatted').exit_code == 0
+	os.write_file('README.md', 'some new content') or { panic(err) }
+	assert os.execute_or_exit('${os.quoted_path(vexe)} fmt -w .').exit_code == 0
+	assert os.execute_or_exit('git add .').exit_code == 0
+	assert os.execute_or_exit('git commit -m "formatted change"').exit_code == 0
+	assert os.execute_or_exit('git diff start').exit_code == 0
+	assert read_file('main.v') == formatted_content
+}
+
+fn test_run_git_fmt_hook() {
+	eprintln('>>>> ${@FN}')
+	reset_to_start_state()
+	res := os.execute_or_exit('${os.quoted_path(vexe)} git-fmt-hook')
+	assert res.exit_code == 0
+	assert res.output.contains('>   CURRENT git repo pre-commit hook: missing')
+	assert res.output.contains('> Main V repo pre-commit hook script: size:  ')
+	assert res.output.contains('cmd/tools/git_pre_commit_hook.vsh')
+	assert res.output.contains('> Files have different hashes.')
+	assert res.output.contains('> Use `v git-fmt-hook install`')
+}
+
+fn test_run_git_fmt_hook_status_explicit() {
+	eprintln('>>>> ${@FN}')
+	reset_to_start_state()
+	res := os.execute_or_exit('${os.quoted_path(vexe)} git-fmt-hook status')
+	assert res.exit_code == 0
+	assert res.output.contains('>   CURRENT git repo pre-commit hook: missing')
+	assert res.output.contains('> Main V repo pre-commit hook script: size:  ')
+	assert res.output.contains('cmd/tools/git_pre_commit_hook.vsh')
+	assert res.output.contains('> Files have different hashes.')
+	assert res.output.contains('> Use `v git-fmt-hook install`')
+}
+
+fn test_run_git_fmt_hook_install() {
+	eprintln('>>>> ${@FN}')
+	reset_to_start_state()
+	os.execute_or_exit('git checkout -b formatting_with_hook')
+	append('main.v', '\n') or { panic(err) }
+	assert read_file('main.v').starts_with(unformatted_content)
+	assert !os.is_file(hook_file)
+	assert os.execute_or_exit('${os.quoted_path(vexe)} git-fmt-hook install').exit_code == 0
+	assert os.is_file(hook_file)
+	res := os.execute_or_exit('${os.quoted_path(vexe)} git-fmt-hook status')
+	assert res.output.contains('>   CURRENT git repo pre-commit hook: size:  ')
+	assert res.output.contains('> Main V repo pre-commit hook script: size:  ')
+	assert res.output.contains('cmd/tools/git_pre_commit_hook.vsh')
+	assert res.output.contains(hook_file)
+	assert res.output.contains('> Both files are exactly the same.')
+	assert !res.output.contains('> Use `v git-fmt-hook install`')
+	assert res.output.contains('> Use `v git-fmt-hook remove`')
+	assert !res.output.contains('> Done.'), 'res:\n${res}'
+	os.execute_or_exit('git add -u')
+	os.execute_or_exit('git commit -m "this should be formatted"')
+	assert read_file('main.v') == formatted_content
+	dres := os.execute_or_exit('git diff start')
+	// dump(dres)
+	assert dres.exit_code == 0
+	assert dres.output.contains('+fn main() {')
+	assert dres.output.contains("+\tprintln('hi')")
+	second := os.execute_or_exit('${os.quoted_path(vexe)} git-fmt-hook install')
+	assert second.exit_code == 0
+	assert second.output.contains('> Done.'), 'second:\n${second}'
+}
+
+fn test_run_git_fmt_hook_remove() {
+	eprintln('>>>> ${@FN}')
+	reset_to_start_state()
+	os.execute_or_exit('git checkout start')
+	os.execute_or_exit('git checkout -b non_formatting_after_removing_hook')
+	assert os.execute_or_exit('${os.quoted_path(vexe)} git-fmt-hook install').exit_code == 0
+	assert os.is_file(hook_file)
+	assert os.execute_or_exit('${os.quoted_path(vexe)} git-fmt-hook remove').exit_code == 0
+	assert !os.is_file(hook_file)
+	append('main.v', '\n') or { panic(err) }
+	assert read_file('main.v').starts_with(unformatted_content)
+	os.execute_or_exit('git add -u')
+	os.execute_or_exit('git commit -m "this should NOT be formatted again"')
+	assert read_file('main.v').starts_with(unformatted_content)
+}
+
+fn test_run_git_fmt_hook_install_and_remove_on_foreign_hook_should_be_a_nop() {
+	eprintln('>>>> ${@FN}')
+	reset_to_start_state()
+	os.execute_or_exit('git checkout start')
+	os.execute_or_exit('git checkout -b install_and_remove_should_be_a_nop_on_a_foreign_hook')
+	os.write_file(hook_file, foreign_script) or { panic(err) }
+	os.chmod(hook_file, 0o0777) or { panic(err) }
+	assert read_file(hook_file) == foreign_script
+	assert os.execute_or_exit('${os.quoted_path(vexe)} git-fmt-hook install').exit_code == 0
+	assert read_file(hook_file) == foreign_script
+	assert os.execute_or_exit('${os.quoted_path(vexe)} git-fmt-hook remove').exit_code == 0
+	assert read_file(hook_file) == foreign_script
+	assert os.execute_or_exit('${os.quoted_path(vexe)} git-fmt-hook install').exit_code == 0
+	assert read_file(hook_file) == foreign_script
+	assert os.execute_or_exit('${os.quoted_path(vexe)} git-fmt-hook status').exit_code == 0
+	assert read_file(hook_file) == foreign_script
+	assert os.execute_or_exit('${os.quoted_path(vexe)} git-fmt-hook').exit_code == 0
+	assert read_file(hook_file) == foreign_script
+	append('main.v', '\n') or { panic(err) }
+	append('main.v', '\n') or { panic(err) }
+	assert read_file('main.v').starts_with(unformatted_content)
+	os.execute_or_exit('git add -u')
+	fcommiting := os.execute_or_exit('git commit -m "this should NOT be formatted 2"')
+	assert fcommiting.exit_code == 0
+	assert fcommiting.output.contains('hello hello')
+	assert read_file('main.v').starts_with(unformatted_content)
+}
+
+fn show_git_status() {
+	os.system('git log --graph --all --decorate')
+	os.system('git status')
+}
+
+fn append(path string, content string) ! {
+	mut f := os.open_append('main.v')!
+	f.write_string(content)!
+	f.close()
+}
+
+fn read_file(path string) string {
+	return os.read_file(path) or { panic(err) }
+}
+
+fn reset_to_start_state() {
+	os.execute('git checkout start')
+	os.rm('.git/hooks/pre-commit') or {}
+	assert read_file('main.v') == unformatted_content
+}
+
+fn full_remove(path string) ! {
+	// TODO: fix this on windows; the files inside .git/ are with read only permissions, and os.rmdir_all() can not delete them, until they are chmoded to writable
+	files := os.walk_ext(path + '/.git', '')
+	for f in files {
+		os.chmod(f, 0o777) or {}
+	}
+	os.rmdir_all(path)!
+}

cmd/v/v.v

@@ -30,6 +30,7 @@ const external_tools = [
 	'doctor',
 	'download',
 	'fmt',
+	'git-fmt-hook',
 	'gret',
 	'ls',
 	'missdoc',