feat: JetBrains plugin for ZModel

.github/workflows/build-test.yml

@@ -72,6 +72,20 @@ jobs:
             - name: Install dependencies
               run: pnpm install --frozen-lockfile
 
+            - name: Gradle Wrapper Validation
+              uses: gradle/wrapper-validation-action@v1.1.0
+
+            - name: Setup Java
+              uses: actions/setup-java@v4
+              with:
+                  distribution: zulu
+                  java-version: 17
+
+            - name: Setup Gradle
+              uses: gradle/gradle-build-action@v2
+              with:
+                  gradle-home-cache-cleanup: true
+
             - name: Build
               run: DEFAULT_NPM_TAG=latest pnpm run build
 

packages/ide/jetbrains/.gitignore

@@ -0,0 +1,18 @@
+.gradle
+build/
+!gradle/wrapper/gradle-wrapper.jar
+!**/src/main/**/build/
+!**/src/test/**/build/
+
+### IntelliJ IDEA ###
+.idea/modules.xml
+.idea/jarRepositories.xml
+.idea/compiler.xml
+.idea/libraries/
+*.iws
+*.iml
+*.ipr
+out/
+!**/src/main/**/out/
+!**/src/test/**/out/
+.sign

packages/ide/jetbrains/build.gradle.kts

@@ -0,0 +1,68 @@
+plugins {
+    id("java")
+    id("org.jetbrains.kotlin.jvm") version "1.9.21"
+    id("org.jetbrains.intellij") version "1.16.1"
+}
+
+group = "dev.zenstack"
+version = "0.5.0"
+
+repositories {
+    mavenCentral()
+}
+
+// Configure Gradle IntelliJ Plugin
+// Read more: https://plugins.jetbrains.com/docs/intellij/tools-gradle-intellij-plugin.html
+intellij {
+    version.set("2023.3.2")
+    type.set("IU") // Target IDE Platform
+
+    plugins.set(listOf("JavaScript", "org.jetbrains.plugins.textmate"))
+}
+
+tasks {
+    // Set the JVM compatibility versions
+    withType<JavaCompile> {
+        sourceCompatibility = "17"
+        targetCompatibility = "17"
+    }
+    withType<org.jetbrains.kotlin.gradle.tasks.KotlinCompile> {
+        kotlinOptions.jvmTarget = "17"
+    }
+
+    prepareSandbox {
+        doLast {
+            copy {
+                from("${project.projectDir}/../../schema/bundle/language-server/main.js")
+                into("${destinationDir.path}/zenstack/language-server/")
+            }
+            copy {
+                from("${project.projectDir}/../../schema/src/res/stdlib.zmodel")
+                into("${destinationDir.path}/zenstack/res/")
+            }
+            copy {
+                from("${project.projectDir}/src/main/textMate/zmodel.tmbundle")
+                into("${destinationDir.path}/zenstack/res/zmodel.tmbundle")
+            }
+            copy {
+                from("${project.projectDir}/../../language/syntaxes/zmodel.tmLanguage")
+                into("${destinationDir.path}/zenstack/res/zmodel.tmbundle/Syntaxes/")
+            }
+        }
+    }
+
+    patchPluginXml {
+        sinceBuild.set("231")
+        untilBuild.set("241.*")
+    }
+
+    signPlugin {
+        certificateChain.set(System.getenv("CERTIFICATE_CHAIN"))
+        privateKey.set(System.getenv("PRIVATE_KEY"))
+        password.set(System.getenv("PRIVATE_KEY_PASSWORD"))
+    }
+
+    publishPlugin {
+        token.set(System.getenv("PUBLISH_TOKEN"))
+    }
+}

packages/ide/jetbrains/gradle.properties

@@ -0,0 +1,6 @@
+# Opt-out flag for bundling Kotlin standard library -> https://jb.gg/intellij-platform-kotlin-stdlib
+kotlin.stdlib.default.dependency=false
+# Enable Gradle Configuration Cache -> https://docs.gradle.org/current/userguide/configuration_cache.html
+org.gradle.configuration-cache=false
+# Enable Gradle Build Cache -> https://docs.gradle.org/current/userguide/build_cache.html
+org.gradle.caching=true

packages/ide/jetbrains/gradle/wrapper/gradle-wrapper.properties

@@ -0,0 +1,5 @@
+distributionBase=GRADLE_USER_HOME
+distributionPath=wrapper/dists
+distributionUrl=https\://services.gradle.org/distributions/gradle-8.5-bin.zip
+zipStoreBase=GRADLE_USER_HOME
+zipStorePath=wrapper/dists