Please improve JSON.adept

[ghost]

Don't you think it's tired to do type casting all the time?

pragma default_stdlib '2.8' // In order to pin standard library version to 2.8

import basics
import JSON

func main {
    data *JSON = JSONFromFile("bookmarks.json")
    if data == null {
        fprintf(stderr, "Failed to open data.json file\n")
        return
    }
    defer data.destroyAndFree()

    if data.isObject() {
        object *JSONObject = data as *JSONObject
        test *JSONArray = (((object.get("foo") as *JSONObject).get("bar") as *JSONObject) as *JSONObject).get("test") as *JSONArray
        test_string String = (test.elements[0] as *JSONObject).getStringOtherwise("test_string", "")
        print(test_string)
    }
}

[IsaacShelton]

Yes JSON.adept sucks

[IsaacShelton]

I guess the easiest way to improve it in the short term would be some sort of monad so you can do chaining without error checking until the last get. I'll try to see what I can do to make JSON.adept not be such a pain to work with

[IsaacShelton]

JSON.adept is now improved. The old JSON.adept has been moved to 2.8/JSON_old.adept.

In the new version, JSON values now have runtime ownership, similar to String, List, Grid, etc.

These changes will be available in the nightly build after it completes CI/CD.

Here is an example of how to use the new JSON.adept.

---

data.json

{
    "firstname": "John",
    "lastname": "Smith",
    "age": 47,
    "married": true,
    "items": [1, 2, "hi", true, {"a": "b", "c": 431.324, "d": true, "e": ["x"]}]
}

main.adept

pragma compiler_version '2.8'

import basics
import JSON

func main {
    print("===================== CREATION0 (read from file test) =====================")
    json JSON = JSONFromFile("data.json")

    if json.kind() == ::UNDEFINED {
        print("Failed to load json")
    } else {
        print(json)
    }

    print("===================== CREATION1 (build json test) =====================")
    items JSON = JSON({
        JSON(1),
        JSON(2),
        JSON(3),
        JSON(false),
        JSON(true),
        JSON(null),
        JSON("Hi World"),
        JSON({
            AsymmetricPair("first", JSON(1)),
            AsymmetricPair("second", JSON(2)),
            AsymmetricPair("third", JSON(3))
        })
    })

    print(items)

    print("===================== CREATION3 (parse from string test) =====================")
    parsed JSON = JSONFromString("\"This is a string\"")
    print(parsed)

    print("===================== CREATION4 (dynamically generate json test) =====================")
    generated JSON = JSON\object()
    numbers <int> List = {1, 2, 3, 4, 5, 6}
    json_numbers JSON = JSON(numbers)
    generated.add("numbers", json_numbers.commit())
    generated.add("id", JSON(12345))
    print(generated)

    print("===================== CREATION5 (clone json test) =====================")
    cloned JSON = JSON\undefined()
    {
        big_object JSON = JSON\object()
        big_object.add("x", JSON("the x value"))
        big_object.add("y", JSON("the y value"))
        big_object.add("z", JSON("the z value"))
        big_object.add("w", JSON(null))
        big_object.add("is_ok", JSON(true))

        other JSON = JSON\array()
        other.add(JSON(1))
        other.add(JSON(10))
        other.add(JSON(100))
        other.add(JSON(1000))
        other.add(big_object.commit())

        // Normally we would commit() here, but we'll clone instead to demonstrate that it works
        cloned = other.clone()
    }
    print(cloned)

    usage1(json)
    usage2(items)
    usage3(json)
    usage4(json)
}

func usage1(json JSON) {
    print("===================== USAGE1 (field lookup test) =====================")

    firstname String = json.field("firstname").string().orElse("")
    lastname String = json.field("lastname").string().orElse("")
    age int = json.field("age").number().orElse(0.0) as int
    married bool = json.field("married").boolean().orElse(false)

    print("Firstname: " + firstname)
    print("Lastname: " + lastname)
    print("Age: " + age)
    print("Married: " + married)
}

func usage2(json JSON) {
    print("===================== USAGE2 (item iteration test) =====================")

    items <<JSON> List> Optional = json.array()

    if items.isSome() {
        print("Printing items array...")

        each JSON in items.get() {
            print(" - " + toString(it))
        }
    }
}

func usage3(json JSON) {
    print("===================== USAGE3 (field iteration test) =====================")

    maybe_fields <<String, JSON> LinearMap> Optional = json.object()

    if maybe_fields.isSome() {
        fields <String, JSON> LinearMap = maybe_fields.get()

        each <String, JSON> AsymmetricPair in fields {
            print(it.first + ": " + toString(it.second))
        }
    }
}

func usage4(json JSON){
    print("===================== USAGE4 (serialize test) =====================")
    print(json.serialize())
}

[ghost]

Thank you. Btw, this is my new Github account.