CMake linking: Issue using Fortran include paths

[lte678]

Description
When linking the library including Fortran bindings with CMake, the HDF5_INCLUDE_DIR_FORTRAN is incorrectly set.

This means that the Fortran compiler will throw warnings when looking for the non-existent directory, and .mod files cannot be linked.

I might do something like this:

find_package(HDF5 NAMES hdf5 COMPONENTS C Fortran shared)
include_directories(${HDF5_INCLUDE_DIR_FORTRAN})

Expected behavior
I expect the HDF5_INCLUDE_DIR_FORTRAN to be one of /usr/include/mod/{shared, static}, but instead it is /usr/include/{shared, static}

Platform

• HDF5 version: 1.14.6-4
• Arch Linux, Kernel 6.14.4-arch1-1
• gfortran 15.1.1
• CMake 4.0.1 using Makefiles

[byrnHDF]

I'm not seeing this is my local testing of develop. Will need to inspect 1.14.6 release code. Compare of CMake config files do not show the issue.
I guess I will need more info, maybe the hdf5-config.cmake file?

[byrnHDF]

Looking at a recent build of develop - the fortran mod files are in HDF5_ROOT/mod/{static,shared} by default. Using the GNU option shows them in include/mod/{shared, static}.
These were obtained from the hdf5-targets.cmake file and the hdf5::hdf5_fortran-shared(static) target properties.

[byrnHDF]

Also looking at the released version of 1.14.6 the files location and the refs in the hdf5-targets.cmake file are correct.
Looking at hdf5-config.cmake file HDF5_INCLUDE_DIR_FORTRAN setting is likely unset.

The only way the mod files end up under include is if the HDF5_INSTALL_MOD_FORTRAN is set to "STATIC" or "SHARED", in the release hdf5-config.cmake it is set to "NO". Only if it is not "NO" would HDF5_INCLUDE_DIR_FORTRAN be definitely set.

So the bug is that there is not a default setting for HDF5_INCLUDE_DIR_FORTRAN.

[byrnHDF]

This will be fixed in develop, but as a workaround simply replace the following section in hdf-config.cmake:

foreach (comp IN LISTS ${HDF5_PACKAGE_NAME}_FIND_COMPONENTS)
  if (comp STREQUAL "shared")
    list (REMOVE_ITEM ${HDF5_PACKAGE_NAME}_FIND_COMPONENTS ${comp})
    set (${HDF5_PACKAGE_NAME}_LIB_TYPE ${${HDF5_PACKAGE_NAME}_LIB_TYPE} ${comp})

    if (${HDF5_PACKAGE_NAME}_BUILD_FORTRAN AND ${HDF5_PACKAGE_NAME}_INSTALL_MOD_FORTRAN STREQUAL "SHARED")
      set (${HDF5_PACKAGE_NAME}_INCLUDE_DIR_FORTRAN "${PACKAGE_PREFIX_DIR}/include/shared")
    endif ()
  elseif (comp STREQUAL "static")
    list (REMOVE_ITEM ${HDF5_PACKAGE_NAME}_FIND_COMPONENTS ${comp})
    set (${HDF5_PACKAGE_NAME}_LIB_TYPE ${${HDF5_PACKAGE_NAME}_LIB_TYPE} ${comp})

    if (${HDF5_PACKAGE_NAME}_BUILD_FORTRAN AND ${HDF5_PACKAGE_NAME}_INSTALL_MOD_FORTRAN STREQUAL "STATIC")
      set (${HDF5_PACKAGE_NAME}_INCLUDE_DIR_FORTRAN "${PACKAGE_PREFIX_DIR}/include/static")
    endif ()
  endif ()
endforeach ()

with

foreach (comp IN LISTS ${HDF5_PACKAGE_NAME}_FIND_COMPONENTS)
  if (comp STREQUAL "shared")
    list (REMOVE_ITEM ${HDF5_PACKAGE_NAME}_FIND_COMPONENTS ${comp})
    set (${HDF5_PACKAGE_NAME}_LIB_TYPE ${${HDF5_PACKAGE_NAME}_LIB_TYPE} ${comp})

    if (${HDF5_PACKAGE_NAME}_BUILD_FORTRAN)
      if (${HDF5_PACKAGE_NAME}_INSTALL_MOD_FORTRAN STREQUAL "SHARED")
        set (${HDF5_PACKAGE_NAME}_INCLUDE_DIR_FORTRAN "${PACKAGE_PREFIX_DIR}/include/shared")
      else ()
        set (${HDF5_PACKAGE_NAME}_INCLUDE_DIR_FORTRAN "${PACKAGE_PREFIX_DIR}/mod/shared")
      endif ()
    endif ()
  elseif (comp STREQUAL "static")
    list (REMOVE_ITEM ${HDF5_PACKAGE_NAME}_FIND_COMPONENTS ${comp})
    set (${HDF5_PACKAGE_NAME}_LIB_TYPE ${${HDF5_PACKAGE_NAME}_LIB_TYPE} ${comp})

    if (${HDF5_PACKAGE_NAME}_BUILD_FORTRAN)
      if (${HDF5_PACKAGE_NAME}_INSTALL_MOD_FORTRAN STREQUAL "STATIC")
        set (${HDF5_PACKAGE_NAME}_INCLUDE_DIR_FORTRAN "${PACKAGE_PREFIX_DIR}/include/static")
      else ()
        set (${HDF5_PACKAGE_NAME}_INCLUDE_DIR_FORTRAN "${PACKAGE_PREFIX_DIR}/mod/static")
      endif ()
    endif ()
  endif ()
endforeach ()

[byrnHDF]

There is also an incorrect setting if ${HDF5_PACKAGE_NAME}_INSTALL_MOD_FORTRAN is not "NO"