add Hovercraft1d

src/ADNLPProblems/hovercraft1d.jl

@@ -0,0 +1,31 @@
+export hovercraft1d
+
+function hovercraft1d(args...; n::Int = default_nvar, type::Val{T} = Val(Float64), kwargs...) where {T}
+  N = div(n, 3)
+  function f(y)
+    x, v, u = y[1:N], y[(N + 1):(2 * N)], y[(2 * N + 1):end]
+    return sum(u .^ 2)
+  end
+  function c(y)
+    x, v, u = y[1:N], y[(N + 1):(2 * N)], y[(2 * N + 1):end]
+    return vcat(
+      x[1],
+      v[1],
+      x[N] - 100,
+      v[N],
+      [x[i + 1] - x[i] - v[i] for i = 1:(N - 1)],
+      [v[i + 1] - v[i] - u[i] for i = 1:(N - 1)],
+    )
+  end
+  xi = zeros(T, 3 * N - 1)
+  return ADNLPModels.ADNLPModel(
+    f,
+    xi,
+    c,
+    zeros(T, 2 * N + 2),
+    zeros(T, 2 * N + 2),
+    name = "hovercraft1d";
+    lin = collect(1:2 * N + 2),
+    kwargs...,
+  )
+end

src/Meta/hovercraft1d.jl

@@ -0,0 +1,25 @@
+hovercraft1d_meta = Dict(
+  :nvar => 3 * div(default_nvar, 3) - 1,
+  :variable_nvar => true,
+  :ncon => 2 * div(default_nvar, 3) + 2,
+  :variable_ncon => true,
+  :minimize => true,
+  :name => "hovercraft1d",
+  :has_equalities_only => true,
+  :has_inequalities_only => false,
+  :has_bounds => false,
+  :has_fixed_variables => false,
+  :objtype => :other,
+  :contype => :linear,
+  :best_known_lower_bound => -Inf,
+  :best_known_upper_bound => Inf,
+  :is_feasible => missing,
+  :defined_everywhere => missing,
+  :origin => :unknown,
+)
+get_hovercraft1d_nvar(; n::Integer = default_nvar, kwargs...) = 3 * div(default_nvar, 3) - 1
+get_hovercraft1d_ncon(; n::Integer = default_nvar, kwargs...) = 2 * div(default_nvar, 3) + 2
+get_hovercraft1d_nlin(; n::Integer = default_nvar, kwargs...) = 2 * div(default_nvar, 3) + 2
+get_hovercraft1d_nnln(; n::Integer = default_nvar, kwargs...) = 0
+get_hovercraft1d_nequ(; n::Integer = default_nvar, kwargs...) = 2 * div(default_nvar, 3) + 2
+get_hovercraft1d_nineq(; n::Integer = default_nvar, kwargs...) = 0

src/PureJuMP/hovercraft1d.jl

@@ -0,0 +1,30 @@
+# JuMP model follows Laurent Lessard CS/ECE/ISyE 524, University of Wisconsin–Madison, 
+# Introduction to Optimization class.
+
+# Hovercraft 1D example
+# https://laurentlessard.com/teaching/524-intro-to-optimization/
+
+function hovercraft1d(args...; n::Int = default_nvar, kwargs...)
+  nlp = Model()
+
+  T = div(n, 3)           # length of time horizon
+  @variable(nlp, x[1:T])    # resulting position
+  @variable(nlp, v[1:T])    # resulting velocity
+  @variable(nlp, u[1:(T - 1)])  # thruster input
+
+  # constraint on start and end positions and velocities
+  @constraint(nlp, x[1] == 0)
+  @constraint(nlp, v[1] == 0)
+  @constraint(nlp, x[T] == 100)
+  @constraint(nlp, v[T] == 0)
+
+  # satisfy the dynamics
+  for i = 1:(T - 1)
+    @constraint(nlp, x[i + 1] == x[i] + v[i])
+    @constraint(nlp, v[i + 1] == v[i] + u[i])
+  end
+
+  # minimize 2-norm
+  @objective(nlp, Min, sum(u .^ 2))
+  return nlp
+end