Single Burst DAC

[erry11]

Hello,

Thank you for sharing this library. I’ve found it extremely useful for one of my projects. I have a question regarding the "Send_DAC_Burst_Sine" example: is there a way to modify the waveform parameters at runtime or within the setup loop?

I'm not an expert in electronics or data acquisition, but my initial approach was to define a static array of N elements and, as a first test, copy the values from the sine_lut array into that array.

`

#include <SensEdu.h>
uint32_t lib_error = 0;
const uint16_t dac_cycle_num = 1;
const uint16_t sine_lut[] = {
0x0000,0x000a,0x0027,0x0058,0x009c,0x00f2,0x0159,0x01d1,0x0258,0x02ed,0x038e,0x043a,0x04f0,0x05ad,0x0670,0x0737,
0x0800,0x08c8,0x098f,0x0a52,0x0b0f,0x0bc5,0x0c71,0x0d12,0x0da7,0x0e2e,0x0ea6,0x0f0d,0x0f63,0x0fa7,0x0fd8,0x0ff5,
0x0fff,0x0ff5,0x0fd8,0x0fa7,0x0f63,0x0f0d,0x0ea6,0x0e2e,0x0da7,0x0d12,0x0c71,0x0bc5,0x0b0f,0x0a52,0x098f,0x08c8,
0x0800,0x0737,0x0670,0x05ad,0x04f0,0x043a,0x038e,0x02ed,0x0258,0x01d1,0x0159,0x00f2,0x009c,0x0058,0x0027,0x000a
};
static uint16_t custom_wave[64];

void setup() {
Serial.begin(115200);
delay(1000);
for (int i = 0; i < 64; i++)
{
  custom_wave[i] = sine_lut[i];
}
const size_t sine_lut_size = sizeof(custom_wave) / sizeof(custom_wave[0]);

SensEdu_DAC_Settings dac1_settings = {DAC1, 20*64, (uint16_t*)custom_wave, sine_lut_size, 
    SENSEDU_DAC_MODE_BURST_WAVE, dac_cycle_num};

SensEdu_DAC_Init(&dac1_settings);
 }`

The resulting custom_wave looked at the oscilloscope was not the same from sine_lut. Do you have some advice?
Thank you!

[fanfare-ff]

Hi, thanks for you interest in our project.

I tested it myself and you are right. There is a problem with using not constant table.

From the oscilloscope waves it looked most probably linked to cache problems.
I added the line SCB_CleanDCache_by_Addr((uint32_t*)custom_wave, sizeof(custom_wave)); to clear the cache manually before using custom_wave address. It worked well afterwards. For now, you can use it like this

In recent updates I'll test it with LUT modifications at run time and fix the cache internally in DAC functions. I let you know when it would be ready.

Before cache cleaning:

After cache cleaning:

Full code:

#include <SensEdu.h>

uint32_t lib_error = 0;

/* -------------------------------------------------------------------------- */
/*                                  Settings                                  */
/* -------------------------------------------------------------------------- */

// how many LUT repeats for one DAC transfer
const uint16_t dac_cycle_num = 2;

// DAC transfered symbols
const uint16_t sine_lut[] = {
    0x0000,0x000a,0x0027,0x0058,0x009c,0x00f2,0x0159,0x01d1,0x0258,0x02ed,0x038e,0x043a,0x04f0,0x05ad,0x0670,0x0737,
	0x0800,0x08c8,0x098f,0x0a52,0x0b0f,0x0bc5,0x0c71,0x0d12,0x0da7,0x0e2e,0x0ea6,0x0f0d,0x0f63,0x0fa7,0x0fd8,0x0ff5,
	0x0fff,0x0ff5,0x0fd8,0x0fa7,0x0f63,0x0f0d,0x0ea6,0x0e2e,0x0da7,0x0d12,0x0c71,0x0bc5,0x0b0f,0x0a52,0x098f,0x08c8,
	0x0800,0x0737,0x0670,0x05ad,0x04f0,0x043a,0x038e,0x02ed,0x0258,0x01d1,0x0159,0x00f2,0x009c,0x0058,0x0027,0x000a
};
const size_t sine_lut_size = sizeof(sine_lut) / sizeof(sine_lut[0]);
static uint16_t custom_wave[64];

/* -------------------------------------------------------------------------- */
/*                                    Setup                                   */
/* -------------------------------------------------------------------------- */
void setup() {
    Serial.begin(115200);

    for (uint16_t i = 0; i < 64; i++) {
        custom_wave[i] = sine_lut[i];
    }
    size_t custom_wave_size = sizeof(custom_wave) / sizeof(custom_wave[0]);

    SCB_CleanDCache_by_Addr((uint32_t*)custom_wave, sizeof(custom_wave)); // patch for cache problem
    SensEdu_DAC_Settings dac1_settings = {DAC1, 32000*64, (uint16_t*)custom_wave, custom_wave_size, 
        SENSEDU_DAC_MODE_BURST_WAVE, dac_cycle_num};

    SensEdu_DAC_Init(&dac1_settings);

    lib_error = SensEdu_GetError();
    while (lib_error != 0) {
        delay(1000);
        Serial.print("Error: 0x");
        Serial.println(lib_error, HEX);
    }

    Serial.println("Setup is successful.");
}

/* -------------------------------------------------------------------------- */
/*                                    Loop                                    */
/* -------------------------------------------------------------------------- */
void loop() {

    SensEdu_DAC_Enable(DAC1);
    
    // check errors
    lib_error = SensEdu_GetError();
    while (lib_error != 0) {
        delay(1000);
        Serial.print("Error: 0x");
        Serial.println(lib_error, HEX);
    }

    delay(100);
}

[erry11]

Hi,
it successfully solved the problem.
Thank you very much for the help!

[fanfare-ff]

Hi @erry11!
Latest release 0.4.1 covers this problem.

Now buffer is defined with macro SENSEDU_DAC_BUFFER(name, user_size), where you put your variable name as first argument and its size in uint16_t as the second.
The cache is handled automatically for the buffer defined this way and its contents could be modified in a run-time, accessing through variable name as for usual array.

You can refer to the example libraries\SensEdu\examples\Send_DAC_Variable_Wave\. With that I generated ramp with just 4 elements buffer, modifying it in the main loop.