Series in Banach spaces

config/codespell-dictionary.txt

@@ -79,3 +79,4 @@ morphsims->morphisms
 outout->output
 ringr->ring
 ringrs->rings
+semiorm->seminorm

src/analysis.lagda.md

@@ -3,8 +3,17 @@
 ```agda
 module analysis where
 
+open import analysis.complete-metric-abelian-groups public
+open import analysis.complete-metric-abelian-groups-real-banach-spaces public
+open import analysis.convergent-series-complete-metric-abelian-groups public
 open import analysis.convergent-series-metric-abelian-groups public
+open import analysis.convergent-series-real-banach-spaces public
+open import analysis.convergent-series-real-numbers public
 open import analysis.derivatives-of-real-functions-on-proper-closed-intervals public
 open import analysis.metric-abelian-groups public
+open import analysis.metric-abelian-groups-normed-real-vector-spaces public
+open import analysis.series-complete-metric-abelian-groups public
 open import analysis.series-metric-abelian-groups public
+open import analysis.series-real-banach-spaces public
+open import analysis.series-real-numbers public
 ```

src/analysis/complete-metric-abelian-groups-real-banach-spaces.lagda.md

@@ -0,0 +1,63 @@
+# Complete metric abelian groups of real Banach spaces
+
+```agda
+module analysis.complete-metric-abelian-groups-real-banach-spaces where
+```
+
+<details><summary>Imports</summary>
+
+```agda
+open import analysis.complete-metric-abelian-groups
+open import analysis.metric-abelian-groups
+open import analysis.metric-abelian-groups-normed-real-vector-spaces
+
+open import foundation.dependent-pair-types
+open import foundation.identity-types
+open import foundation.subtypes
+open import foundation.universe-levels
+
+open import linear-algebra.real-banach-spaces
+
+open import real-numbers.metric-additive-group-of-real-numbers
+```
+
+</details>
+
+## Idea
+
+Every [real Banach space](linear-algebra.real-banach-spaces.md) forms a
+[complete metric abelian group](analysis.complete-metric-abelian-groups.md)
+under addition.
+
+## Definition
+
+```agda
+module _
+  {l1 l2 : Level}
+  (V : ℝ-Banach-Space l1 l2)
+  where
+
+  metric-ab-add-ℝ-Banach-Space : Metric-Ab l2 l1
+  metric-ab-add-ℝ-Banach-Space =
+    metric-ab-Normed-ℝ-Vector-Space (normed-vector-space-ℝ-Banach-Space V)
+
+  complete-metric-ab-add-ℝ-Banach-Space : Complete-Metric-Ab l2 l1
+  complete-metric-ab-add-ℝ-Banach-Space =
+    ( metric-ab-add-ℝ-Banach-Space , is-complete-metric-space-ℝ-Banach-Space V)
+```
+
+## Properties
+
+### The complete metric abelian group from the reals as a real Banach space equals the standard complete metric abelian group of the reals under addition
+
+```agda
+abstract
+  eq-complete-metric-ab-ℝ :
+    (l : Level) →
+    complete-metric-ab-add-ℝ-Banach-Space (real-banach-space-ℝ l) ＝
+    complete-metric-ab-add-ℝ l
+  eq-complete-metric-ab-ℝ l =
+    eq-type-subtype
+      ( is-complete-prop-Metric-Ab)
+      ( eq-metric-ab-normed-real-vector-space-metric-ab-ℝ l)
+```

src/analysis/complete-metric-abelian-groups.lagda.md

@@ -0,0 +1,65 @@
+# Complete metric abelian groups
+
+```agda
+module analysis.complete-metric-abelian-groups where
+```
+
+<details><summary>Imports</summary>
+
+```agda
+open import analysis.metric-abelian-groups
+
+open import foundation.dependent-pair-types
+open import foundation.propositions
+open import foundation.subtypes
+open import foundation.universe-levels
+
+open import metric-spaces.complete-metric-spaces
+open import metric-spaces.metric-spaces
+```
+
+</details>
+
+## Idea
+
+A {{#concept "complete metric abelian group" Agda=Complete-Metric-Ab}} is a
+[metric abelian group](analysis.metric-abelian-groups.md) whose associated
+[metric space](metric-spaces.metric-spaces.md) is
+[complete](metric-spaces.complete-metric-spaces.md).
+
+## Definition
+
+```agda
+is-complete-prop-Metric-Ab : {l1 l2 : Level} → Metric-Ab l1 l2 → Prop (l1 ⊔ l2)
+is-complete-prop-Metric-Ab G =
+  is-complete-prop-Metric-Space (metric-space-Metric-Ab G)
+
+is-complete-Metric-Ab : {l1 l2 : Level} → Metric-Ab l1 l2 → UU (l1 ⊔ l2)
+is-complete-Metric-Ab G = is-complete-Metric-Space (metric-space-Metric-Ab G)
+
+Complete-Metric-Ab : (l1 l2 : Level) → UU (lsuc l1 ⊔ lsuc l2)
+Complete-Metric-Ab l1 l2 = type-subtype (is-complete-prop-Metric-Ab {l1} {l2})
+```
+
+## Properties
+
+```agda
+module _
+  {l1 l2 : Level}
+  (G : Complete-Metric-Ab l1 l2)
+  where
+
+  metric-ab-Complete-Metric-Ab : Metric-Ab l1 l2
+  metric-ab-Complete-Metric-Ab = pr1 G
+
+  metric-space-Complete-Metric-Ab : Metric-Space l1 l2
+  metric-space-Complete-Metric-Ab =
+    metric-space-Metric-Ab metric-ab-Complete-Metric-Ab
+
+  complete-metric-space-Complete-Metric-Ab : Complete-Metric-Space l1 l2
+  complete-metric-space-Complete-Metric-Ab =
+    ( metric-space-Complete-Metric-Ab , pr2 G)
+
+  type-Complete-Metric-Ab : UU l1
+  type-Complete-Metric-Ab = type-Metric-Ab metric-ab-Complete-Metric-Ab
+```

src/analysis/convergent-series-complete-metric-abelian-groups.lagda.md

@@ -0,0 +1,79 @@
+# Convergent series in complete metric abelian groups
+
+```agda
+module analysis.convergent-series-complete-metric-abelian-groups where
+```
+
+<details><summary>Imports</summary>
+
+```agda
+open import analysis.complete-metric-abelian-groups
+open import analysis.convergent-series-metric-abelian-groups
+open import analysis.series-complete-metric-abelian-groups
+
+open import foundation.dependent-pair-types
+open import foundation.propositions
+open import foundation.universe-levels
+
+open import metric-spaces.cauchy-sequences-complete-metric-spaces
+open import metric-spaces.cauchy-sequences-metric-spaces
+```
+
+</details>
+
+## Idea
+
+A [series](analysis.series-metric-abelian-groups.md)
+[converges](analysis.convergent-series-metric-abelian-groups.md) in a
+[complete metric abelian group](analysis.complete-metric-abelian-groups.md) if
+its partial sums form a
+[Cauchy sequence](metric-spaces.cauchy-sequences-metric-spaces.md).
+
+A slightly modified converse is also true: if a series converges, there
+[exists](foundation.existential-quantification.md) a modulus making it a Cauchy
+sequence.
+
+## Definition
+
+```agda
+module _
+  {l1 l2 : Level}
+  (G : Complete-Metric-Ab l1 l2)
+  (σ : series-Complete-Metric-Ab G)
+  where
+
+  is-sum-prop-series-Complete-Metric-Ab : type-Complete-Metric-Ab G → Prop l2
+  is-sum-prop-series-Complete-Metric-Ab = is-sum-prop-series-Metric-Ab σ
+
+  is-sum-series-Complete-Metric-Ab : type-Complete-Metric-Ab G → UU l2
+  is-sum-series-Complete-Metric-Ab = is-sum-series-Metric-Ab σ
+
+  is-convergent-prop-series-Complete-Metric-Ab : Prop (l1 ⊔ l2)
+  is-convergent-prop-series-Complete-Metric-Ab =
+    is-convergent-prop-series-Metric-Ab σ
+
+  is-convergent-series-Complete-Metric-Ab : UU (l1 ⊔ l2)
+  is-convergent-series-Complete-Metric-Ab = is-convergent-series-Metric-Ab σ
+```
+
+## Properties
+
+### If the partial sums of a series form a Cauchy sequence, the series converges
+
+```agda
+module _
+  {l1 l2 : Level}
+  (G : Complete-Metric-Ab l1 l2)
+  (σ : series-Complete-Metric-Ab G)
+  where
+
+  is-convergent-is-cauchy-sequence-partial-sum-series-Complete-Metric-Ab :
+    is-cauchy-sequence-Metric-Space
+      ( metric-space-Complete-Metric-Ab G)
+      ( partial-sum-series-Complete-Metric-Ab G σ) →
+    is-convergent-series-Complete-Metric-Ab G σ
+  is-convergent-is-cauchy-sequence-partial-sum-series-Complete-Metric-Ab H =
+    has-limit-cauchy-sequence-Complete-Metric-Space
+      ( complete-metric-space-Complete-Metric-Ab G)
+      ( partial-sum-series-Complete-Metric-Ab G σ , H)
+```

src/analysis/convergent-series-real-banach-spaces.lagda.md

@@ -0,0 +1,79 @@
+# Convergent series in real Banach spaces
+
+```agda
+module analysis.convergent-series-real-banach-spaces where
+```
+
+<details><summary>Imports</summary>
+
+```agda
+open import analysis.complete-metric-abelian-groups-banach-spaces
+open import analysis.convergent-series-complete-metric-abelian-groups
+open import analysis.convergent-series-metric-abelian-groups
+open import analysis.series-real-banach-spaces
+
+open import foundation.propositions
+open import foundation.universe-levels
+
+open import linear-algebra.real-banach-spaces
+
+open import metric-spaces.cauchy-sequences-metric-spaces
+```
+
+</details>
+
+## Idea
+
+A [series](analysis.series-real-banach-spaces.md)
+[converges](analysis.convergent-series-metric-abelian-groups.md) in a
+[real Banach space](linear-algebra.real-banach-spaces.md) if its partial sums
+form a [Cauchy sequence](metric-spaces.cauchy-sequences-metric-spaces.md).
+
+A slightly modified converse is also true: if a series converges, there
+[exists](foundation.existential-quantification.md) a modulus making it a Cauchy
+sequence.
+
+## Definition
+
+```agda
+module _
+  {l1 l2 : Level}
+  (V : ℝ-Banach-Space l1 l2)
+  (σ : series-ℝ-Banach-Space V)
+  where
+
+  is-sum-prop-series-ℝ-Banach-Space : type-ℝ-Banach-Space V → Prop l1
+  is-sum-prop-series-ℝ-Banach-Space = is-sum-prop-series-Metric-Ab σ
+
+  is-sum-series-ℝ-Banach-Space : type-ℝ-Banach-Space V → UU l1
+  is-sum-series-ℝ-Banach-Space = is-sum-series-Metric-Ab σ
+
+  is-convergent-prop-series-ℝ-Banach-Space : Prop (l1 ⊔ l2)
+  is-convergent-prop-series-ℝ-Banach-Space =
+    is-convergent-prop-series-Metric-Ab σ
+
+  is-convergent-series-ℝ-Banach-Space : UU (l1 ⊔ l2)
+  is-convergent-series-ℝ-Banach-Space = is-convergent-series-Metric-Ab σ
+```
+
+## Properties
+
+### If the partial sums of a series form a Cauchy sequence, the series converges
+
+```agda
+module _
+  {l1 l2 : Level}
+  (V : ℝ-Banach-Space l1 l2)
+  (σ : series-ℝ-Banach-Space V)
+  where
+
+  is-convergent-is-cauchy-sequence-partial-sum-series-ℝ-Banach-Space :
+    is-cauchy-sequence-Metric-Space
+      ( metric-space-ℝ-Banach-Space V)
+      ( partial-sum-series-ℝ-Banach-Space V σ) →
+    is-convergent-series-ℝ-Banach-Space V σ
+  is-convergent-is-cauchy-sequence-partial-sum-series-ℝ-Banach-Space =
+    is-convergent-is-cauchy-sequence-partial-sum-series-Complete-Metric-Ab
+      ( complete-metric-ab-add-ℝ-Banach-Space V)
+      ( σ)
+```

src/analysis/convergent-series-real-numbers.lagda.md

@@ -0,0 +1,74 @@
+# Convergent series in the real numbers
+
+```agda
+module analysis.convergent-series-real-numbers where
+```
+
+<details><summary>Imports</summary>
+
+```agda
+open import analysis.convergent-series-complete-metric-abelian-groups
+open import analysis.convergent-series-metric-abelian-groups
+open import analysis.series-real-numbers
+
+open import foundation.propositions
+open import foundation.universe-levels
+
+open import real-numbers.cauchy-sequences-real-numbers
+open import real-numbers.dedekind-real-numbers
+open import real-numbers.metric-additive-group-of-real-numbers
+```
+
+</details>
+
+## Idea
+
+A [series of real numbers](analysis.series-real-numbers.md) is
+{{#concept "convergent" Disambiguation="series in 𝐑" Agda=is-convergent-series-ℝ Agda=convergent-series-ℝ WDID=Q1211057 WD="convergent series"}}
+if its partial sums converge in the
+[metric space of real numbers](real-numbers.metric-space-of-real-numbers.md).
+
+## Definition
+
+```agda
+module _
+  {l : Level}
+  (σ : series-ℝ l)
+  where
+
+  is-sum-prop-series-ℝ : ℝ l → Prop l
+  is-sum-prop-series-ℝ = is-sum-prop-series-Metric-Ab σ
+
+  is-sum-series-ℝ : ℝ l → UU l
+  is-sum-series-ℝ = is-sum-series-Metric-Ab σ
+
+  is-convergent-prop-series-ℝ : Prop (lsuc l)
+  is-convergent-prop-series-ℝ =
+    is-convergent-prop-series-Metric-Ab σ
+
+  is-convergent-series-ℝ : UU (lsuc l)
+  is-convergent-series-ℝ = is-convergent-series-Metric-Ab σ
+```
+
+## Properties
+
+### If the partial sums of a series form a Cauchy sequence, the series converges
+
+```agda
+module _
+  {l : Level}
+  (σ : series-ℝ l)
+  where
+
+  is-convergent-is-cauchy-sequence-partial-sum-series-ℝ :
+    is-cauchy-sequence-ℝ (partial-sum-series-ℝ σ) →
+    is-convergent-series-ℝ σ
+  is-convergent-is-cauchy-sequence-partial-sum-series-ℝ =
+    is-convergent-is-cauchy-sequence-partial-sum-series-Complete-Metric-Ab
+      ( complete-metric-ab-add-ℝ l)
+      ( σ)
+```
+
+## External links
+
+- [Convergent series](https://en.wikipedia.org/wiki/Ratio_test) on Wikipedia