REGRESSION(308209@main): Top and bottom fixed position elements flicker when rubber band scrolling

https://bugs.webkit.org/show_bug.cgi?id=315320
rdar://176226179

Reviewed by Tim Horton.

When we throttle visible content rect updates to the WebContent process, we will still update layer positions and
scrolling tree state in the UI process. However, we were missing one change that the full unthrottled path does which
is to update the WKContentView's fixed clipping view bounds. Stale data here leads to fixed positioned elements flickering
when doing a rubber band scroll while changing obscured insets interactively in iOS Safari.

Test: Tools/TestWebKitAPI/Tests/WebKit/WKWebView/ios/WKScrollViewTests.mm

* Source/WebKit/UIProcess/API/ios/WKWebViewIOS.mm:
(-[WKWebView _updateViewportRelativeLayersOutOfBand]):
* Source/WebKit/UIProcess/API/ios/WKWebViewPrivateForTestingIOS.h:
* Source/WebKit/UIProcess/API/ios/WKWebViewTestingIOS.mm:
(-[WKWebView _fixedClippingViewBoundsForTesting]):
* Source/WebKit/UIProcess/ios/WKContentView.h:
* Source/WebKit/UIProcess/ios/WKContentView.mm:
(-[WKContentView _fixedClippingViewBoundsForTesting]):
* Tools/TestWebKitAPI/Tests/WebKit/WKWebView/ios/WKScrollViewTests.mm:
(TestWebKitAPI::(WKScrollViewTests, FixedClippingViewTracksRubberBandDuringInteractiveObscuredInsetsChange)):

Canonical link: https://commits.webkit.org/313759@main

Author: rreno

Source/WebKit/UIProcess/API/ios/WKWebViewIOS.mm

@@ -3173,6 +3173,7 @@ - (void)_updateViewportRelativeLayersOutOfBand
         _page->updateVisibleContentRectsLocally(*info);
         auto layoutViewport = _page->unconstrainedLayoutViewportRect();
         _page->adjustLayersForLayoutViewport(_page->unobscuredContentRect().location(), layoutViewport, _page->displayedContentScale());
+        [_contentView updateFixedClippingView:layoutViewport];
     }
 }
 

Source/WebKit/UIProcess/API/ios/WKWebViewPrivateForTestingIOS.h

@@ -104,6 +104,7 @@
 - (UIView *)_colorExtensionViewForTesting:(UIRectEdge)edge;
 
 @property (nonatomic, readonly) BOOL _hasPendingVisibleContentRectUpdateTimerForTesting;
+@property (nonatomic, readonly) CGRect _fixedClippingViewBoundsForTesting;
 
 @end
 

Source/WebKit/UIProcess/API/ios/WKWebViewTestingIOS.mm

@@ -553,6 +553,11 @@ - (BOOL)_hasPendingVisibleContentRectUpdateTimerForTesting
     return _pendingInteractiveObscuredInsetsChangeTimer && _pendingInteractiveObscuredInsetsChangeTimer->isActive();
 }
 
+- (CGRect)_fixedClippingViewBoundsForTesting
+{
+    return [_contentView _fixedClippingViewBoundsForTesting];
+}
+
 @end
 
 #endif // PLATFORM(IOS_FAMILY)

Source/WebKit/UIProcess/ios/WKContentView.h

@@ -78,6 +78,9 @@ using LayerHostingContextID = uint32_t;
 
 - (void)didUpdateVisibleRect:(const WebKit::VisibleContentRectUpdateInfo &)visibleContentRectUpdateInfo sendEvenIfUnchanged:(BOOL)sendEvenIfUnchanged;
 
+- (void)updateFixedClippingView:(WebCore::FloatRect)fixedPositionRectForUI;
+- (CGRect)_fixedClippingViewBoundsForTesting;
+
 - (void)didFinishScrolling;
 - (void)didZoomToScale:(CGFloat)scale;
 - (void)willStartZoomOrScroll;

Source/WebKit/UIProcess/ios/WKContentView.mm

@@ -611,6 +611,11 @@ - (void)updateFixedClippingView:(WebCore::FloatRect)fixedPositionRectForUI
     [_rootContentView setBounds:clippingBounds];
 }
 
+- (CGRect)_fixedClippingViewBoundsForTesting
+{
+    return [_fixedClippingView bounds];
+}
+
 - (void)_didExitStableState
 {
     _needsDeferredEndScrollingSelectionUpdate = self.shouldHideSelectionInFixedPositionWhenScrolling;

Tools/TestWebKitAPI/Tests/WebKit/WKWebView/ios/WKScrollViewTests.mm

@@ -1307,6 +1307,45 @@ HTTPServer server({
     EXPECT_LE(maxDeviation, 2);
 }
 
+TEST(WKScrollViewTests, FixedClippingViewTracksRubberBandDuringInteractiveObscuredInsetsChange)
+{
+    RetainPtr webView = adoptNS([[TestWKWebView alloc] initWithFrame:CGRectMake(0, 0, 400, 800)]);
+
+    auto insets = UIEdgeInsetsMake(50, 0, 0, 0);
+    [webView _setObscuredInsets:insets];
+    RetainPtr scrollView = [webView scrollView];
+    [scrollView setContentInsetAdjustmentBehavior:UIScrollViewContentInsetAdjustmentNever];
+    [scrollView setContentInset:insets];
+
+    [webView synchronouslyLoadTestPageNamed:@"simple-tall"];
+    [webView waitForNextPresentationUpdate];
+
+    // Park past home so the upcoming scroll is itself a rubber-band frame, not a mode transition.
+    [scrollView setContentOffset:CGPointMake(0, -100)];
+    [webView waitForNextVisibleContentRectUpdate];
+
+    [webView _beginInteractiveObscuredInsetsChange];
+
+    // Drive a deeper rubber-band scroll.
+    [scrollView setContentOffset:CGPointMake(0, -150)];
+    [webView waitForNextPresentationUpdate];
+
+    // The clip view's bounds origin should track the current unobscured content rect's Y
+    // (= scrollOffset.y + topInset = -100), even while updates to WebContent are throttled.
+    CGRect clipBounds = [webView _fixedClippingViewBoundsForTesting];
+    EXPECT_NEAR(clipBounds.origin.y, -100.0, 1.0);
+
+    // Drive another rubber-band step within the visible content rect throttle window to confirm we keep
+    // updating the clip rect frame-to-frame, not only on the first throttled frame.
+    [scrollView setContentOffset:CGPointMake(0, -200)];
+    [webView waitForNextPresentationUpdate];
+
+    clipBounds = [webView _fixedClippingViewBoundsForTesting];
+    EXPECT_NEAR(clipBounds.origin.y, -150.0, 1.0);
+
+    [webView _endInteractiveObscuredInsetsChange];
+}
+
 } // namespace TestWebKitAPI
 
 #endif // PLATFORM(IOS_FAMILY)