Compatibility with Opta?

[scottmwyant]

It's likely I'm doing something wrong because I'm new to the Arduino platform. Not new to software dev.

Trying to use this library in a trivial example, use a coil to control state of an LED. I'm running a MODBUS server on an Opta, it seems to run fine but it refuses the connection from the client. I'm using the wired Ethernet interface on the opta if that matters.

Wondering if the Opta is supported, I see the mbed_opta architecture is listed but the opta is not called out in the product listings further down, so this is ambiguous to me.

https://docs.arduino.cc/libraries/arduinomodbus/#Compatibility

[scottmwyant]

I found the examples in the repo and got it working. I mistakenly assumed that ModbusTCPServer would get a socket at port 502 and listen for a connection. However your example shows the socket being managed outside of the library; when a client connects, you have to pass the client instance to the ModbusTCPServer.

#include <ArduinoModbus.h>
#include <Ethernet.h>

const int ledPin = LED_BUILTIN;
const int coilAddress = 0;
const int initState = 1;

// Static IP configuration
IPAddress localIp(192, 168, 1, 200);
IPAddress subnetMask(255, 255, 255, 0);
IPAddress gateway(0, 0, 0, 0);
IPAddress dnsServer(0, 0, 0, 0);

EthernetServer ethServer(502);
ModbusTCPServer mbServer;

void setup() {

  Serial.begin(9600);
  
  // Configure pins on the board
  pinMode(ledPin, OUTPUT);
  
  // Configure ethernet interface with a static IP
  Ethernet.begin(localIp, subnetMask, gateway, dnsServer);
  
  // Start listening for TCP connections
  ethServer.begin();
  
  // Start the Modbus TCP server
  if (!mbServer.begin()) {
    Serial.println("Failed to start Modbus TCP server!");
    while (1);
  }
  
  // Define a single coil for LED control
  mbServer.configureCoils(0, 1);  // Start at address 0, 1 coil
  mbServer.coilWrite(0, initState);
  
  Serial.println("Modbus TCP server started!");
  Serial.print("IP Address: ");
  Serial.println(Ethernet.localIP());
  updateLed();
}

void loop() {
  
  // Handle a connection from a client
  EthernetClient client = ethServer.available();
  
  if(client){
    Serial.println("New client");
    
    // Hand the client to the MODBUS server
    mbServer.accept(client);
    while (client.connected()) {
      mbServer.poll();
      updateLed();
    }
    Serial.println("Client disconnected");
  }
}

void updateLed(){
  // Read the coil value at address 0
  bool ledState = mbServer.coilRead(coilAddress);
  // Set the LED based on the coil state
  digitalWrite(ledPin, ledState);
}