Rename item* to step*.

[azriel91]

• Renaming attempt for item to step: Move types to *_model and *_rt_model crate structure  #187

This performs the rename, but doesn't go through with it (it reverts the changes).

Details will be on #187.

let term_search = 'item'
let term_replace = 'step'

# Rename directories
(
    fd -Ftd $term_search
    | lines
    | each {|dir_old|
        let dir_new = (echo $dir_old | str reverse | str replace ($term_search | str reverse) ($term_replace | str reverse) | str reverse)
        {
            dir_old: $dir_old
            dir_new: $dir_new
        }
    }
    | insert dir_name_length {|row| $row.dir_old | str length }
    | sort-by dir_name_length --reverse
    | each {|row| mv $row.dir_old $row.dir_new}
)

# rename files
(
    fd -Ftf $term_search
    | lines
    | each {|dir_old|
        let dir_new = (echo $dir_old | str reverse | str replace ($term_search | str reverse) ($term_replace | str reverse) | str reverse)
        {
            dir_old: $dir_old
            dir_new: $dir_new
        }
    }
    | insert dir_name_length {|row| $row.dir_old | str length }
    | sort-by dir_name_length --reverse
    | each {|row| mv $row.dir_old $row.dir_new}
)

# TODO
let item_rename_dir = [$env.TEMP item_rename] | path join
if not ($item_rename_dir | path exists) { mkdir $item_rename_dir }
let matches_item_file = $item_rename_dir | path join matches_item
# rg -Fi 'item' o> $matches_item_file
let matches_item_ignores = ([
    'align-item',
    'list-item',
    'list_aligned_item',
    'list of named items',
    'item in the list',
])
let match_item_ignores_str = $"($matches_item_ignores | each {|s| $"\(($s)\)"} | str join '|')"
let matches_item = (
    open $matches_item_file --raw
    | rg -v $match_item_ignores_str
    | lines
    | parse "{file}:{text}"
    | where file != 'CHANGELOG.md' and file != 'doc\src\learning_material\empathetic_code_design.md'
)

let replacements = (
    [
        [term replacement];
        ['an Item'   'a Step'  ]
        ['an [`Item' 'a [`Step']
        ['an [item'  'a [step' ]
        ['an `Item'  'a `Step' ]
        ['an item'   'a step'  ]
        [item step]
        [Item Step]
        [StepStruct ItemStruct]
        ['Iterator<Step' 'Iterator<Item']
        ['Stream<Step' 'Stream<Item']
        ['step_interrupt_poll' 'item_interrupt_poll']
        ['interrupted_next_step_include' 'interrupted_next_item_include']
        ['list_aligned_step_write' 'list_aligned_item_write']
        ['New-Step' 'New-Item']
        ['Remove-Step' 'Remove-Item']
        ['reorder_impl_steps' 'reorder_impl_items']
        ['step_struct' 'item_struct']
        ['get_step' 'get_item']
        ['set_step' 'set_item']
        ['remove_step' 'remove_item']
        ['GetStep' 'GetItem']
        ['RemoveStep' 'RemoveItem']
        ['SetStep' 'SetItem']
    ]
)
(
    $replacements
    | each {|entry|
        sd -s $"($entry.term)" $"($entry.replacement)" ...(
            $matches_item
            | get file
            | sort
            | uniq
        )
    }
)

# TODO:
# step_wrapper.rs: change `I` to `S`.