script for catching up on reading the #commonlisp irc channel.

[vindarel]

see this snippet: https://gist.github.com/bo-tato/9df8182150dc49d0943f13635430b647 by @bo-tato (I'd like to see if you have more scripts!)

(in-package :ciel-user)
(use-package '(local-time periods))
(import 'periods::do-times)

(defconstant +last-date-file+ "~/.irc-log-reader-last")

(defun fmt-date (date)
 (format-timestring nil date :format +rfc3339-format/date-only+))

(do-times (day (-> +last-date-file+ str:from-file str:trim parse-timestring)
               (duration :days 1)
               (today))
  (let* ((url #?"https://libera.irclog.whitequark.org/commonlisp/${(fmt-date day)}")
         (doc (lquery:$ (initialize (dex:get url)))))
    (format t "~%:: ~a ::~%" day)
    (lquery:$ doc ".talk.op-msg" (text)
      (map [#'println {substitute #\Space #\Newline}]))))

(str:to-file +last-date-file+ (fmt-date (today)))

It uses the periods library, that we are evaluating to include in CIEL.

[vindarel]

bo-tato built his own CIEL with periods inside. You can quickload the library at startup:

(eval-when (:compile-toplevel :load-toplevel :execute)
  (ql:quickload "periods"))

(it adds some start up time, yes, that's why we include useful libraries)

[vindarel]

Here's the script in the repository, slightly adapted: https://github.com/ciel-lang/CIEL/blob/master/src/scripts/irc-fetcher.lisp

What's nice in the use of local-time and periods (periods:do-times and duration).

The periods library is now included in CIEL.

(in-package :ciel-user)

(use-package '(local-time
               ;; periods
               ))
(import 'periods::do-times)

;;;
;;; First use:
;;; ciel irc-fetcher.lisp 2026-09-10
;;; to fetch the #commonlisp IRC channel from this date.
;;;
;;; The script saves today's date to ~/.irc-log-reader-last
;;; and next calls use it to resume fetching.
;;;
;;; This script uses local-time's parse-timestring, format-timestring
;;; and period's do-times, duration
;;;
;;; src: https://gist.github.com/bo-tato/9df8182150dc49d0943f13635430b647
;;;


(defconstant +last-date-file+ "~/.irc-log-reader-last")

(defun last-date (&aux (cli-arg (second ciel-user:*script-args*)))
  "Read the last date to parse IRC: from a CLI arg or the ~/.irc-log-reader-last file."
  (cond
    ((str:non-blank-string-p cli-arg)
     (-> cli-arg
         parse-timestring))
    ((uiop:file-exists-p +last-date-file+)
     (-> +last-date-file+
         str:from-file
         str:trim
         parse-timestring))
    (t
     (format t "Please give the day to start fetching IRC as argument or in ~a. Next calls use this file.~&" +last-date-file+)
     (termp:quit))))


(defun fmt-date (date)
  "Format as YYYY-MM-DD"
  (format-timestring nil date :format +rfc3339-format/date-only+))

(defun fetchit (date)
  (do-times (day
             date
             (periods:duration :days 1)
             (today))
    (format! t "Fetching day ~a...~&" day)
    (let* ((url (str:concat "https://libera.irclog.whitequark.org/commonlisp/" (fmt-date day)))
           (doc (lquery:$ (initialize (dex:get url)))))
      (format t "~%:: ~a ::~%" day)
      (lquery:$ doc ".talk.op-msg" (text)
        ;; (map [#'println {substitute #\Space #\Newline}]))))
        (map #'println)))))

;; Run it:
#+ciel
(progn
  (fetchit (last-date))
  (str:to-file +last-date-file+ (fmt-date (today))))

Usage:

$ ciel irc-fetcher.lisp 2026-09-10

The next invocations resume from today.

Read more

• https://lisp-maintainers.github.io/periods/