Added SFML build

libs/SFML-4fbefe7/CMakeLists.txt

@@ -0,0 +1,204 @@
+
+cmake_minimum_required(VERSION 2.8)
+
+# define a macro that helps defining an option
+macro(sfml_set_option var default type docstring)
+    if(NOT DEFINED ${var})
+        set(${var} ${default})
+    endif()
+    set(${var} ${${var}} CACHE ${type} ${docstring} FORCE)
+endmacro()
+
+# set a default build type if none was provided
+# this has to be done before the project() instruction!
+sfml_set_option(CMAKE_BUILD_TYPE Release STRING "Choose the type of build (Debug or Release)")
+
+# project name
+project(SFML)
+
+# include the configuration file
+include(${CMAKE_CURRENT_SOURCE_DIR}/cmake/Config.cmake)
+
+# setup version numbers
+set(VERSION_MAJOR 2)
+set(VERSION_MINOR 0)
+set(VERSION_PATCH 0)
+
+# add the SFML header path
+include_directories(${CMAKE_CURRENT_SOURCE_DIR}/include)
+
+# add an option for choosing the build type (shared or static)
+sfml_set_option(BUILD_SHARED_LIBS TRUE BOOL "TRUE to build SFML as shared libraries, FALSE to build it as static libraries")
+
+# add an option for building the examples
+sfml_set_option(SFML_BUILD_EXAMPLES FALSE BOOL "TRUE to build the SFML examples, FALSE to ignore them")
+
+# add an option for building the API documentation
+sfml_set_option(SFML_BUILD_DOC FALSE BOOL "TRUE to generate the API documentation, FALSE to ignore it")
+
+# Mac OS X specific options
+if(MACOSX)
+    # add an option to build frameworks instead of dylibs (release only)
+    sfml_set_option(SFML_BUILD_FRAMEWORKS FALSE BOOL "TRUE to build SFML as frameworks libraries (release only), FALSE to build according to BUILD_SHARED_LIBS")
+
+    # add an option to let the user specify a custom directory for frameworks installation (SFML, sndfile, ...)
+    sfml_set_option(CMAKE_INSTALL_FRAMEWORK_PREFIX "/Library/Frameworks" STRING "Frameworks installation directory")
+
+    # add an option to automatically install Xcode 4 templates
+    sfml_set_option(SFML_INSTALL_XCODE4_TEMPLATES FALSE BOOL "TRUE to automatically install the Xcode 4 templates, FALSE to do nothing about it")
+endif()
+
+# define SFML_STATIC if the build type is not set to 'shared'
+if(NOT BUILD_SHARED_LIBS)
+    add_definitions(-DSFML_STATIC)
+endif()
+
+# remove SL security warnings with Visual C++
+if(COMPILER_MSVC)
+    add_definitions(-D_CRT_SECURE_NO_DEPRECATE)
+endif()
+
+# define an option for choosing between static and dynamic C runtime (Windows only)
+if(WINDOWS)
+    sfml_set_option(SFML_USE_STATIC_STD_LIBS FALSE BOOL "TRUE to statically link to the standard libraries, FALSE to use them as DLLs")
+
+    # the following combination of flags is not valid
+    if (BUILD_SHARED_LIBS AND SFML_USE_STATIC_STD_LIBS)
+        message(FATAL_ERROR "BUILD_SHARED_LIBS and SFML_USE_STATIC_STD_LIBS cannot be used together")
+    endif()
+
+    # for VC++, we can apply it globally by modifying the compiler flags
+    if(COMPILER_MSVC AND SFML_USE_STATIC_STD_LIBS)
+        foreach(flag
+                CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE
+                CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO)
+            if(${flag} MATCHES "/MD")
+                string(REGEX REPLACE "/MD" "/MT" ${flag} "${${flag}}")
+            endif()
+        endforeach()
+    endif()
+endif()
+
+# disable the rpath stuff
+set(CMAKE_SKIP_BUILD_RPATH TRUE)
+
+# Setup Mac OS X stuff
+if(MACOSX)
+    # SFML_BUILD_FRAMEWORKS needs two things :
+    # first, it's available only for release
+    #    (because cmake currently doesn't allow specifying a custom framework name so XXX-d is not possible)
+    # secondly, it works only with BUILD_SHARED_LIBS enabled
+    if(SFML_BUILD_FRAMEWORKS)
+        # requirement #1
+        if(NOT CMAKE_BUILD_TYPE STREQUAL "Release")
+            message(FATAL_ERROR "CMAKE_BUILD_TYPE should be \"Release\" when SFML_BUILD_FRAMEWORKS is TRUE")
+            return()
+        endif()
+
+        # requirement #2
+        if(NOT BUILD_SHARED_LIBS)
+            message(FATAL_ERROR "BUILD_SHARED_LIBS should be TRUE when SFML_BUILD_FRAMEWORKS is TRUE")
+            return()
+        endif()
+    endif()
+endif()
+
+if(LINUX)
+    if(BUILD_SHARED_LIBS)
+        sfml_set_option(SFML_INSTALL_PKGCONFIG_FILES TRUE BOOL "TRUE to automatically install pkg-config files so other projects can find SFML")
+        if(SFML_INSTALL_PKGCONFIG_FILES)
+            foreach(sfml_module IN ITEMS all system window graphics audio network)
+                CONFIGURE_FILE(
+                    "tools/pkg-config/sfml-${sfml_module}.pc.in"
+                    "tools/pkg-config/sfml-${sfml_module}.pc"
+                    @ONLY)
+	    INSTALL(FILES "${CMAKE_CURRENT_BINARY_DIR}/tools/pkg-config/sfml-${sfml_module}.pc"
+                    DESTINATION "${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}/pkgconfig")
+            endforeach()
+        endif()
+    else()
+        if(SFML_INSTALL_PKGCONFIG_FILES)
+            message(WARNING "No pkg-config files are provided for the static SFML libraries (SFML_INSTALL_PKGCONFIG_FILES will be ignored).")
+        endif()
+    endif()
+endif()
+
+# add the subdirectories
+add_subdirectory(src/SFML)
+if(SFML_BUILD_EXAMPLES)
+    add_subdirectory(examples)
+endif()
+if(SFML_BUILD_DOC)
+    add_subdirectory(doc)
+endif()
+
+# setup the install rules
+if(NOT SFML_BUILD_FRAMEWORKS)
+    install(DIRECTORY include
+            DESTINATION .
+            COMPONENT devel
+            PATTERN ".svn" EXCLUDE)
+else()
+    # find only "root" headers
+    file(GLOB SFML_HEADERS RELATIVE ${PROJECT_SOURCE_DIR} "include/SFML/*")
+
+    # in fact we have to fool cmake to copy all the headers in subdirectories
+    # to do that we have to add the "root" headers to the PUBLIC_HEADER
+    # then we can run a post script to copy the remaining headers
+
+    # we need a dummy file in order to compile the framework
+    add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/dummy.cpp
+                       COMMAND touch ${CMAKE_CURRENT_BINARY_DIR}/dummy.cpp)
+
+    set(SFML_SOURCES ${SFML_HEADERS})
+    list(APPEND SFML_SOURCES ${CMAKE_CURRENT_BINARY_DIR}/dummy.cpp)
+
+    # create SFML.framework
+    add_library(SFML ${SFML_SOURCES})
+
+    # edit target properties
+    set_target_properties(SFML PROPERTIES 
+                          FRAMEWORK TRUE
+                          FRAMEWORK_VERSION ${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}
+                          MACOSX_FRAMEWORK_IDENTIFIER org.sfml-dev.SFML
+                          MACOSX_FRAMEWORK_SHORT_VERSION_STRING ${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}
+                          MACOSX_FRAMEWORK_BUNDLE_VERSION ${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}
+                          PUBLIC_HEADER "${SFML_HEADERS}")
+
+    # add the remaining headers
+    add_custom_command(TARGET SFML 
+                       POST_BUILD
+                       COMMAND cp -r ${PROJECT_SOURCE_DIR}/include/SFML/* SFML.framework/Versions/${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}/Headers)
+
+    # adapt install directory to allow distributing dylibs/frameworks in user’s frameworks/application bundle
+    # NOTE : it's not required to link agains SFML.framework
+    set_target_properties(SFML PROPERTIES 
+                          BUILD_WITH_INSTALL_RPATH 1 
+                          INSTALL_NAME_DIR "@executable_path/../Frameworks")
+
+    # install rule
+    install(TARGETS SFML
+            FRAMEWORK DESTINATION ${CMAKE_INSTALL_FRAMEWORK_PREFIX}
+            COMPONENT devel)
+endif()
+
+install(FILES cmake/Modules/FindSFML.cmake DESTINATION ${INSTALL_MISC_DIR}/cmake/Modules)
+install(FILES license.txt DESTINATION ${INSTALL_MISC_DIR})
+install(FILES readme.txt DESTINATION ${INSTALL_MISC_DIR})
+
+if(WINDOWS)
+    if(ARCH_32BITS)
+        install(FILES extlibs/bin/x86/libsndfile-1.dll DESTINATION bin)
+        install(FILES extlibs/bin/x86/openal32.dll DESTINATION bin)
+    elseif(ARCH_64BITS)
+        install(FILES extlibs/bin/x64/libsndfile-1.dll DESTINATION bin)
+        install(FILES extlibs/bin/x64/openal32.dll DESTINATION bin)
+    endif()
+elseif(MACOSX)
+    install(DIRECTORY extlibs/libs-osx/Frameworks/sndfile.framework DESTINATION ${CMAKE_INSTALL_FRAMEWORK_PREFIX})
+    install(DIRECTORY extlibs/libs-osx/Frameworks/freetype.framework DESTINATION ${CMAKE_INSTALL_FRAMEWORK_PREFIX})
+
+    if(SFML_INSTALL_XCODE4_TEMPLATES)
+        install(DIRECTORY tools/xcode/templates/SFML DESTINATION /Library/Developer/Xcode/Templates)
+    endif()
+endif()

libs/SFML-4fbefe7/cmake/Config.cmake

@@ -0,0 +1,75 @@
+# detect the OS
+if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
+    set(WINDOWS 1)
+
+    # detect the architecture (note: this test won't work for cross-compilation)
+    include(CheckTypeSize)
+    check_type_size(void* SIZEOF_VOID_PTR)
+    if("${SIZEOF_VOID_PTR}" STREQUAL "4")
+        set(ARCH_32BITS 1)
+    elseif("${SIZEOF_VOID_PTR}" STREQUAL "8")
+        set(ARCH_64BITS 1)
+    else()
+        message(FATAL_ERROR "Unsupported architecture")
+        return()
+    endif()
+elseif(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
+    set(LINUX 1)
+elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
+    # FreeBSD compile path is the same as Linux
+    set(LINUX 1)
+elseif(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
+    set(MACOSX 1)
+
+    # detect OS X version. (use '/usr/bin/sw_vers -productVersion' to extract V from '10.V.x'.)
+    EXEC_PROGRAM(/usr/bin/sw_vers ARGS -productVersion OUTPUT_VARIABLE MACOSX_VERSION_RAW)
+    STRING(REGEX REPLACE "10\\.([0-9]).*" "\\1" MACOSX_VERSION "${MACOSX_VERSION_RAW}")
+    if(${MACOSX_VERSION} LESS 5)
+        message(FATAL_ERROR "Unsupported version of OS X : ${MACOSX_VERSION_RAW}")
+        return()
+    endif()
+else()
+    message(FATAL_ERROR "Unsupported operating system")
+    return()
+endif()
+
+# detect the compiler and its version
+# Note: on some platforms (OS X), CMAKE_COMPILER_IS_GNUCXX is true
+# even when CLANG is used, therefore the Clang test is done first
+if(CMAKE_CXX_COMPILER MATCHES ".*clang[+][+]" OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
+   # CMAKE_CXX_COMPILER_ID is an internal CMake variable subject to change,
+   # but there is no other way to detect CLang at the moment
+   set(COMPILER_CLANG 1)
+   execute_process(COMMAND "${CMAKE_CXX_COMPILER}" "--version" OUTPUT_VARIABLE CLANG_VERSION_OUTPUT)
+   string(REGEX REPLACE ".*clang version ([0-9]+\\.[0-9]+).*" "\\1" CLANG_VERSION "${CLANG_VERSION_OUTPUT}")
+elseif(CMAKE_COMPILER_IS_GNUCXX)
+    set(COMPILER_GCC 1)
+    execute_process(COMMAND "${CMAKE_CXX_COMPILER}" "-dumpversion" OUTPUT_VARIABLE GCC_VERSION_OUTPUT)
+    string(REGEX REPLACE "([0-9]+\\.[0-9]+).*" "\\1" GCC_VERSION "${GCC_VERSION_OUTPUT}")
+    execute_process(COMMAND "${CMAKE_CXX_COMPILER}" "-dumpmachine" OUTPUT_VARIABLE GCC_MACHINE)
+    string(STRIP "${GCC_MACHINE}" GCC_MACHINE)
+    if(${GCC_MACHINE} MATCHES ".*w64.*")
+        set(COMPILER_GCC_W64 1)
+    endif()
+elseif(MSVC)
+    set(COMPILER_MSVC 1)
+    if(MSVC_VERSION EQUAL 1400)
+        set(MSVC_VERSION 2005)
+    elseif(MSVC_VERSION EQUAL 1500)
+        set(MSVC_VERSION 2008)
+    elseif(MSVC_VERSION EQUAL 1600)
+        set(MSVC_VERSION 2010)
+    elseif(MSVC_VERSION EQUAL 1700)
+        set(MSVC_VERSION 2011)
+    endif()
+else()
+    message(FATAL_ERROR "Unsupported compiler")
+    return()
+endif()
+
+# define the install directory for miscellaneous files
+if(WINDOWS)
+    set(INSTALL_MISC_DIR .)
+elseif(UNIX)
+    set(INSTALL_MISC_DIR share/SFML)
+endif()