Bug #2524: Addition of CMake build files

CMake/xmlto.cmake

@@ -0,0 +1,103 @@
+# - Convert XML docBook files to various formats
+# This will convert XML docBook files to various formats like:
+# man html txt dvi ps pdf
+#  macro XMLTO(outfiles infiles... MODES modes...)
+
+set ( XmlTo_FOUND false )
+
+find_program ( XMLTO_EXECUTABLE
+  NAMES xmlto
+  DOC   "path to the xmlto docbook xslt frontend"  
+)
+
+if ( XMLTO_EXECUTABLE )
+  set ( XmlTo_FOUND true )
+endif ( XMLTO_EXECUTABLE )
+
+if ( NOT XmlTo_FIND_QUIETLY )
+  if ( XmlTo_FIND_REQUIRED )
+    FATAL_ERROR ( "xmlto not found" )
+  endif ( XmlTo_FIND_REQUIRED )
+endif ( NOT XmlTo_FIND_QUIETLY )
+
+macro ( _XMLTO_FILE outfiles mode)
+  #special settings
+  set ( XMLTO_FILEEXT_man 1 )
+  set ( XMLTO_MODE_html xhtml-nochunks )
+
+  if ( NOT XMLTO_MODE_${mode})
+    set ( XMLTO_MODE_${mode} ${mode} )
+  endif ( NOT XMLTO_MODE_${mode} )
+  if ( NOT XMLTO_FILEEXT_${mode} )
+    set ( XMLTO_FILEEXT_${mode} ${mode} )
+  endif ( NOT XMLTO_FILEEXT_${mode} )
+
+  foreach ( dbFile ${ARGN} )
+    #TODO: set XMLTO_FILEEXT_man to value from <manvolnum>
+    if ( "${mode}" STREQUAL "man" )
+      file ( READ "${dbFile}" _DB_FILE_CONTENTS )
+      string ( REGEX MATCH "<manvolnum>[^<]*" XMLTO_FILEEXT_${mode} "${_DB_FILE_CONTENTS}" )
+      string ( REGEX REPLACE "^<manvolnum>" "" XMLTO_FILEEXT_${mode} "${XMLTO_FILEEXT_${mode}}" )
+      string ( REGEX REPLACE "[[:space:]]" "" XMLTO_FILEEXT_${mode} "${XMLTO_FILEEXT_${mode}}" )
+    endif ( "${mode}" STREQUAL "man" )
+
+    get_filename_component ( dbFilePath ${CMAKE_CURRENT_BINARY_DIR}/${dbFile} PATH )
+    get_filename_component ( dbFileWE ${dbFile} NAME_WE )
+    get_filename_component ( dbFileAbsWE ${dbFilePath}/${dbFileWE} ABSOLUTE )
+
+    add_custom_command (
+      OUTPUT            ${dbFileAbsWE}.${XMLTO_FILEEXT_${mode}}
+      COMMAND           ${XMLTO_EXECUTABLE} ${XMLTO_COMMAND_ARGS} -o ${CMAKE_CURRENT_BINARY_DIR}
+                        ${XMLTO_MODE_${mode}} "${CMAKE_CURRENT_SOURCE_DIR}/${dbFile}"
+      MAIN_DEPENDENCY   ${CMAKE_CURRENT_SOURCE_DIR}/${dbFile}
+      VERBATIM
+    )
+
+    set ( ${outfiles}
+      ${${outfiles}}
+      ${dbFileAbsWE}.${XMLTO_FILEEXT_${mode}}
+    )
+  endforeach ( dbFile )
+endmacro ( _XMLTO_FILE outfiles )
+
+macro ( XMLTO )
+  set ( XMLTO_MODES )
+  set ( XMLTO_FILES )
+  set ( XMLTO_HAS_MODES false )
+  set ( XMLTO_ADD_DEFAULT false )
+  foreach ( arg ${ARGN} )
+    if ( ${arg} STREQUAL "MODES" )
+      set ( XMLTO_HAS_MODES true )
+    elseif ( ${arg} STREQUAL "ALL" )
+      set ( XMLTO_ADD_DEFAULT true )
+    else ( ${arg} STREQUAL "MODES" )
+      if ( XMLTO_HAS_MODES )
+	set ( XMLTO_MODES ${XMLTO_MODES} ${arg} )
+      else ( XMLTO_HAS_MODES )    
+	set ( XMLTO_FILES ${XMLTO_FILES} ${arg} )
+      endif ( XMLTO_HAS_MODES )
+    endif ( ${arg} STREQUAL "MODES" )
+  endforeach ( arg ${ARGN} )
+  if ( NOT XMLTO_MODES )
+    set ( XMLTO_MODES html )
+  endif ( NOT XMLTO_MODES )
+
+  foreach ( mode ${XMLTO_MODES} )
+    _xmlto_file ( XMLTO_FILES_${mode} ${mode} ${XMLTO_FILES} )
+    if ( XMLTO_ADD_DEFAULT )
+      add_custom_target ( ${mode} ALL
+	DEPENDS ${XMLTO_FILES_${mode}}
+	VERBATIM
+      )
+    else ( XMLTO_ADD_DEFAULT )
+      add_custom_target ( ${mode}
+	DEPENDS ${XMLTO_FILES_${mode}}
+	VERBATIM
+      )
+    endif ( XMLTO_ADD_DEFAULT )
+  endforeach ( mode )
+
+  set ( XMLTO_MODES )
+  set ( XMLTO_FILES )
+endmacro ( XMLTO )
+

CMakeLists.txt

@@ -0,0 +1,37 @@
+# Minimal CMake build file
+# Builds:
+# - static library from lib directory
+# - commandline executable
+# - test suite
+# - Qt GUI
+
+# To build with CMake:
+# - install CMake 2.6 or later
+# - $ cmake .
+# - $ make
+
+cmake_minimum_required (VERSION 2.6)
+
+PROJECT(CPPCHECK)
+
+set(CMAKE_MODULE_PATH "${CPPCHECK_SOURCE_DIR}/cmake/modules" ${CMAKE_MODULE_PATH})
+
+# Building lib as static library is disabled due to bug
+# #1299 CMake: The CheckClass is not used
+# https://sourceforge.net/apps/trac/cppcheck/ticket/1299
+# Instead lib code is included directly into cli and gui targets
+# ADD_SUBDIRECTORY(lib)
+
+ADD_SUBDIRECTORY(cli)
+
+# Exclude tests from command line targets but include them to VS IDE targets.
+# There is 'make check' -target for compiling and running tests from
+# command line.
+IF (MSVC_IDE)
+  ADD_SUBDIRECTORY(test)
+ELSE (MSVC_IDE)
+  ADD_SUBDIRECTORY(test EXCLUDE_FROM_ALL)
+ENDIF (MSVC_IDE)
+
+ADD_SUBDIRECTORY(gui)
+ADD_SUBDIRECTORY(man)

cli/CMakeLists.txt

@@ -0,0 +1,41 @@
+# Minimal CMake build file to build cppcheck command line executable
+find_package(PCRE REQUIRED)
+
+set(TINYXML_INCLUDE_DIR "${CPPCHECK_SOURCE_DIR}/externals/tinyxml/")
+
+SET(CHECKCLI_SRCS
+  cmdlineparser.cpp
+  cppcheckexecutor.cpp
+  filelister.cpp
+  main.cpp
+  threadexecutor.cpp
+  "${TINYXML_INCLUDE_DIR}tinystr.cpp"
+  "${TINYXML_INCLUDE_DIR}tinyxml.cpp"
+  "${TINYXML_INCLUDE_DIR}tinyxmlerror.cpp"
+  "${TINYXML_INCLUDE_DIR}tinyxmlparser.cpp")
+
+set(CPPCHECK_LIB_DIR "${CPPCHECK_SOURCE_DIR}/lib/")
+include("${CPPCHECK_LIB_DIR}library_sources.cmake")
+
+if(WIN32)
+   # Add Windows resource file
+   set(CHECKCLI_SRCS ${CHECKCLI_SRCS} filelister_win32.cpp
+       cppcheck.rc)
+
+   if(NOT CYGWIN)
+      # Windows needs additional shlwapi library.
+      set(CHECK_LIBS ${CHECK_LIBS} shlwapi)
+   endif()
+else()
+   set(CHECKCLI_SRCS ${CHECKCLI_SRCS} filelister_unix.cpp)
+endif()
+
+if (CMAKE_COMPILER_IS_GNUCXX)
+  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wextra -pedantic -Wshadow -Wno-long-long -Wfloat-equal -Wcast-qual")
+endif (CMAKE_COMPILER_IS_GNUCXX)
+
+include_directories("${CPPCHECK_SOURCE_DIR}/lib"
+                    "${PCRE_INCLUDE_DIR}"
+                    "${TINYXML_INCLUDE_DIR}")
+add_executable(cppcheck ${CHECKCLI_SRCS} ${CPPCHECK_LIB_SOURCES})
+TARGET_LINK_LIBRARIES(cppcheck ${CHECK_LIBS} ${PCRE_LIBRARIES})

cli/cli.pro

@@ -1,13 +1,14 @@
 TEMPLATE = app
 TARGET = cppcheck
 DEPENDPATH += .
-INCLUDEPATH += . ../lib
+TINYXML_DIR = ../externals/tinyxml/
+INCLUDEPATH += . ../lib $${TINYXML_DIR}
 OBJECTS_DIR = temp
 CONFIG += warn_on
 CONFIG -= qt app_bundle
 
-BASEPATH = ../externals/tinyxml/
-include($$PWD/../externals/tinyxml/tinyxml.pri)
+BASEPATH = $${TINYXML_DIR}
+include($$PWD/$${TINYXML_DIR}tinyxml.pri)
 BASEPATH = ../lib/
 include($$PWD/../lib/lib.pri)
 

cli/cmdlineparser.cpp

@@ -28,7 +28,7 @@
 #include "path.h"
 
 // xml is used in rules
-#include "tinyxml/tinyxml.h"
+#include "tinyxml.h"
 
 static void AddFilesToList(const std::string& FileList, std::vector<std::string>& PathNames)
 {

cli/cppcheck.vcproj

@@ -19,7 +19,7 @@
 			UseOfMfc="0">
 			<Tool
 				Name="VCCLCompilerTool"
-				AdditionalIncludeDirectories="&quot;.&quot;,&quot;..\lib&quot;,&quot;..\externals&quot;,c:\Qt\VS4.7.0\mkspecs\win32-msvc2008"
+				AdditionalIncludeDirectories="&quot;.&quot;,&quot;..\lib&quot;,&quot;..\externals\tinyxml&quot;,c:\Qt\VS4.7.0\mkspecs\win32-msvc2008"
 				AdditionalOptions="-Zm200 -w34100 -w34189"
 				AssemblerListingLocation="temp\"
 				BufferSecurityCheck="false"

cli/cppcheck.vcxproj

@@ -50,7 +50,7 @@
   </PropertyGroup>
   <ItemDefinitionGroup Condition="&apos;$(Configuration)|$(Platform)&apos;==&apos;Debug|Win32&apos;">
     <ClCompile>
-      <AdditionalIncludeDirectories>".";"..\lib";"..\externals";c:\Qt\VS4.7.0\mkspecs\win32-msvc2010;%(AdditionalIncludeDirectories)</AdditionalIncludeDirectories>
+      <AdditionalIncludeDirectories>".";"..\lib";"..\externals\tinyxml";c:\Qt\VS4.7.0\mkspecs\win32-msvc2010;%(AdditionalIncludeDirectories)</AdditionalIncludeDirectories>
       <AdditionalOptions>-Zm200 -w34100 -w34189 %(AdditionalOptions)</AdditionalOptions>
       <AssemblerListingLocation>temp\</AssemblerListingLocation>
       <BrowseInformation>false</BrowseInformation>
@@ -84,7 +84,7 @@
   </ItemDefinitionGroup>
   <ItemDefinitionGroup Condition="&apos;$(Configuration)|$(Platform)&apos;==&apos;Release|Win32&apos;">
     <ClCompile>
-      <AdditionalIncludeDirectories>".";"..\lib";"..\externals";c:\Qt\VS4.7.0\mkspecs\win32-msvc2010;%(AdditionalIncludeDirectories)</AdditionalIncludeDirectories>
+      <AdditionalIncludeDirectories>".";"..\lib";"..\externals\tinyxml";c:\Qt\VS4.7.0\mkspecs\win32-msvc2010;%(AdditionalIncludeDirectories)</AdditionalIncludeDirectories>
       <AdditionalOptions>-Zm200 -w34100 -w34189 %(AdditionalOptions)</AdditionalOptions>
       <AssemblerListingLocation>temp\</AssemblerListingLocation>
       <BrowseInformation>false</BrowseInformation>

cmake/modules/FindPCRE.cmake

@@ -0,0 +1,42 @@
+# - Try to find the PCRE regular expression library
+# Once done this will define
+#
+#  PCRE_FOUND - system has the PCRE library
+#  PCRE_INCLUDE_DIR - the PCRE include directory
+#  PCRE_LIBRARIES - The libraries needed to use PCRE
+
+# Copyright (c) 2006, Alexander Neundorf, <neundorf@kde.org>
+#
+# Redistribution and use is allowed according to the terms of the BSD license.
+# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+
+
+if (PCRE_INCLUDE_DIR AND PCRE_PCREPOSIX_LIBRARY AND PCRE_PCRE_LIBRARY)
+  # Already in cache, be silent
+  set(PCRE_FIND_QUIETLY TRUE)
+endif (PCRE_INCLUDE_DIR AND PCRE_PCREPOSIX_LIBRARY AND PCRE_PCRE_LIBRARY)
+
+
+if (NOT WIN32)
+  # use pkg-config to get the directories and then use these values
+  # in the FIND_PATH() and FIND_LIBRARY() calls
+  find_package(PkgConfig)
+
+  pkg_check_modules(PC_PCRE QUIET libpcre)
+
+  set(PCRE_DEFINITIONS ${PC_PCRE_CFLAGS_OTHER})
+endif (NOT WIN32)
+
+find_path(PCRE_INCLUDE_DIR pcre.h
+          HINTS "${PC_PCRE_INCLUDEDIR}" ${PC_PCRE_INCLUDE_DIRS}
+          PATH_SUFFIXES pcre)
+
+find_library(PCRE_PCRE_LIBRARY NAMES pcre pcred HINTS "${PC_PCRE_LIBDIR}" ${PC_PCRE_LIBRARY_DIRS})
+find_library(PCRE_PCREPOSIX_LIBRARY NAMES pcreposix pcreposixd HINTS "${PC_PCRE_LIBDIR}" ${PC_PCRE_LIBRARY_DIRS})
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(PCRE DEFAULT_MSG PCRE_INCLUDE_DIR PCRE_PCRE_LIBRARY PCRE_PCREPOSIX_LIBRARY )
+
+set(PCRE_LIBRARIES "${PCRE_PCRE_LIBRARY}" "${PCRE_PCREPOSIX_LIBRARY}")
+
+mark_as_advanced(PCRE_INCLUDE_DIR PCRE_LIBRARIES PCRE_PCREPOSIX_LIBRARY PCRE_PCRE_LIBRARY)

cmake/modules/FindXmlTo.cmake

@@ -0,0 +1,105 @@
+# Is Hendrik Sattler the original author of the following script?
+# http://cmake.org/pipermail/cmake/2007-April/013545.html
+
+# - Convert XML docBook files to various formats
+# This will convert XML docBook files to various formats like:
+# man html txt dvi ps pdf
+#  macro XMLTO(outfiles infiles... MODES modes...)
+
+set ( XmlTo_FOUND false )
+
+find_program ( XMLTO_EXECUTABLE NAMES xmlto
+  DOC "path to the xmlto docbook xslt frontend" )
+
+if ( XMLTO_EXECUTABLE )
+  set ( XmlTo_FOUND true )
+
+  if ( NOT XmlTo_FIND_QUIETLY )
+     message ( STATUS "Found ${XMLTO_EXECUTABLE}" )
+  endif ( NOT XmlTo_FIND_QUIETLY )
+else ( XMLTO_EXECUTABLE )
+  if ( XmlTo_FIND_REQUIRED )
+     message ( FATAL_ERROR "The xmlto program was not found." )
+  endif ( XmlTo_FIND_REQUIRED )
+endif ( XMLTO_EXECUTABLE )
+
+macro ( _XMLTO_FILE outfiles mode)
+  #special settings
+  set ( XMLTO_FILEEXT_man 1 )
+  set ( XMLTO_MODE_html xhtml-nochunks )
+
+  if ( NOT XMLTO_MODE_${mode})
+    set ( XMLTO_MODE_${mode} ${mode} )
+  endif ( NOT XMLTO_MODE_${mode} )
+  if ( NOT XMLTO_FILEEXT_${mode} )
+    set ( XMLTO_FILEEXT_${mode} ${mode} )
+  endif ( NOT XMLTO_FILEEXT_${mode} )
+
+  foreach ( dbFile ${ARGN} )
+    #TODO: set XMLTO_FILEEXT_man to value from <manvolnum>
+    if ( "${mode}" STREQUAL "man" )
+      file ( READ "${dbFile}" _DB_FILE_CONTENTS )
+      string ( REGEX MATCH "<manvolnum>[^<]*" XMLTO_FILEEXT_${mode} "${_DB_FILE_CONTENTS}" )
+      string ( REGEX REPLACE "^<manvolnum>" "" XMLTO_FILEEXT_${mode} "${XMLTO_FILEEXT_${mode}}" )
+      string ( REGEX REPLACE "[[:space:]]" "" XMLTO_FILEEXT_${mode} "${XMLTO_FILEEXT_${mode}}" )
+    endif ( "${mode}" STREQUAL "man" )
+
+    get_filename_component ( dbFilePath "${CMAKE_CURRENT_BINARY_DIR}/${dbFile}" PATH )
+    get_filename_component ( dbFileWE "${dbFile}" NAME_WE )
+    get_filename_component ( dbFileAbsWE "${dbFilePath}/${dbFileWE}" ABSOLUTE )
+
+    add_custom_command (
+      OUTPUT            "${dbFileAbsWE}.${XMLTO_FILEEXT_${mode}}"
+      COMMAND           "${XMLTO_EXECUTABLE}" ${XMLTO_COMMAND_ARGS} -o "${CMAKE_CURRENT_BINARY_DIR}"
+                        ${XMLTO_MODE_${mode}} "${CMAKE_CURRENT_SOURCE_DIR}/${dbFile}"
+      MAIN_DEPENDENCY   "${CMAKE_CURRENT_SOURCE_DIR}/${dbFile}"
+      VERBATIM
+    )
+
+    set ( ${outfiles}
+      ${${outfiles}}
+      "${dbFileAbsWE}.${XMLTO_FILEEXT_${mode}}"
+    )
+  endforeach ( dbFile )
+endmacro ( _XMLTO_FILE outfiles )
+
+macro ( XMLTO )
+  set ( XMLTO_MODES )
+  set ( XMLTO_FILES )
+  set ( XMLTO_HAS_MODES false )
+  set ( XMLTO_ADD_DEFAULT false )
+  foreach ( arg ${ARGN} )
+    if ( ${arg} STREQUAL "MODES" )
+      set ( XMLTO_HAS_MODES true )
+    elseif ( ${arg} STREQUAL "ALL" )
+      set ( XMLTO_ADD_DEFAULT true )
+    else ( ${arg} STREQUAL "MODES" )
+      if ( XMLTO_HAS_MODES )
+	set ( XMLTO_MODES ${XMLTO_MODES} ${arg} )
+      else ( XMLTO_HAS_MODES )
+	set ( XMLTO_FILES ${XMLTO_FILES} ${arg} )
+      endif ( XMLTO_HAS_MODES )
+    endif ( ${arg} STREQUAL "MODES" )
+  endforeach ( arg ${ARGN} )
+  if ( NOT XMLTO_MODES )
+    set ( XMLTO_MODES html )
+  endif ( NOT XMLTO_MODES )
+
+  foreach ( mode ${XMLTO_MODES} )
+    _xmlto_file ( XMLTO_FILES_${mode} ${mode} ${XMLTO_FILES} )
+    if ( XMLTO_ADD_DEFAULT )
+      add_custom_target ( ${mode} ALL
+	DEPENDS ${XMLTO_FILES_${mode}}
+	VERBATIM
+      )
+    else ( XMLTO_ADD_DEFAULT )
+      add_custom_target ( ${mode}
+	DEPENDS ${XMLTO_FILES_${mode}}
+	VERBATIM
+      )
+    endif ( XMLTO_ADD_DEFAULT )
+  endforeach ( mode )
+
+  set ( XMLTO_MODES )
+  set ( XMLTO_FILES )
+endmacro ( XMLTO )