✨ docker.#UpdateEnv or docker.#Path

[NarendraPatwardhan]

What are you trying to do?

I am trying to update the PATH variable based on its previous value inside docker.#Build. docker.#Set is insufficient for it. A mechanism to update env values or PATH specifically should be abstracted away as an action for ease in translation.

Why is this important to you?

Various pieces of software demand the PATH variable be updated for global discovery.
ENV PATH=${PATH}: is a common occurrence in most Dockerfiles, but it is extremely convoluted to do using Dagger in its current form.

How are you currently working around this?

No response

[helderco]

This is how I do it:

docker.#Set & {
    input: image.output
    config: env: PATH: "/foobar:\(input.config.env.PATH)"
}

We don't resolve variables like $VAR, but you can interpolate the value in CUE.

If this doesn't work for you, can you please show how you're using it? I may require a small tweak based on your use case.

[helderco]

Here's a full example:

package main

import (
	"dagger.io/dagger"
	"universe.dagger.io/docker"
)

#TestSet: {
	_build: docker.#Build & {
		steps: [
			docker.#Pull & {
				source: "ubuntu"
			},
			docker.#Set & {
				input: _ // with docker.#Build you don't need to set input, but we need a reference to use below
				config: env: PATH: "/foobar:\(input.config.env.PATH)"
			},
			docker.#Run & {
				always: true
				command: {
					name: "sh"
					flags: "-c": "echo $PATH"
				}
			},
		]
	}
	result: _build.output.config.env.PATH
}

dagger.#Plan & {
	actions: test: #TestSet
}

➜  dagger do test
[✔] actions.test
Field   Value                                                                                                                                                                                            
result  "/foobar:/usr/local/sbin:/usr/local/bin:/usr/sbin:/usr/bin:/sbin:/bin"

You can see the output of docker.#Run with --log-format plain:

6:29PM INF actions.test._build._dag."2"._exec | #3 0.098 /foobar:/usr/local/sbin:/usr/local/bin:/usr/sbin:/usr/bin:/sbin:/bin

[NarendraPatwardhan]

Thanks! This solved my problem. I didn't have a input: _ field in #Set