Disable adaptive read buffering for PTY processes

Large TUI redraws (Claude Code, pi on resize) can emit hundreds of
KB in one write. Before Emacs 31, process-adaptive-read-buffering
defaults to t, throttling the filter to ~40 KB/s for bursty
processes — a 570 KB post-resize frame streams in over ~15 seconds,
making ghostel feel like a slow cascade (issue #85).

Let-bind process-adaptive-read-buffering to nil and raise
read-process-output-max to at least 1 MB around make-process in
both ghostel--spawn-pty and ghostel-compile--spawn.  Both values
are captured at make-process time so they must be bound there, not
set afterward. vterm does the same for the same reason.

On Emacs 31+ the first binding is a no-op (default already nil).
The read-process-output-max bump (max of user value, 1 MB) applies
everywhere and collapses a 570 KB frame from ~9 filter calls to 1.

Author: dakra

ghostel-compile.el

@@ -467,6 +467,9 @@ local machine happens to have)."
                         ;; Defeat pagers (git grep, etc.).
                         "PAGER=")
                   (copy-sequence process-environment)))
+         ;; See `ghostel--spawn-pty' for why these are set.
+         (process-adaptive-read-buffering nil)
+         (read-process-output-max (max read-process-output-max (* 1024 1024)))
          (proc (make-process
                 :name "ghostel-compile"
                 :buffer buffer

ghostel.el

@@ -2433,6 +2433,16 @@ matches the PTY window size, and stores the process in
             "COLORTERM=truecolor")
            extra-env
            process-environment))
+         ;; Large TUI redraws (Claude Code, pi on resize) can emit
+         ;; hundreds of KB in one write.  Before Emacs 31,
+         ;; `process-adaptive-read-buffering' defaults to t and
+         ;; throttles the filter to ~40 KB/s for bursty processes,
+         ;; making resize feel like a slow cascade.
+         ;; Also raise the per-read cap so one filter call can
+         ;; consume a full redraw frame.  Both are captured at
+         ;; `make-process' time, so they must be let-bound here.
+         (process-adaptive-read-buffering nil)
+         (read-process-output-max (max read-process-output-max (* 1024 1024)))
          (proc (make-process
                 :name "ghostel"
                 :buffer (current-buffer)

test/ghostel-test.el

@@ -5176,6 +5176,49 @@ integration script runs, so input echo must be enabled before exec."
             (when (process-live-p proc)
               (delete-process proc))))))))
 
+(ert-deftest ghostel-test-spawn-pty-disables-adaptive-read-buffering ()
+  "`ghostel--spawn-pty' must disable adaptive read buffering and raise
+`read-process-output-max'.  Before Emacs 31 the former defaulted to t
+and throttled bursty TUI redraws."
+  (let ((captured-adaptive 'unset)
+        (captured-max nil)
+        (orig-make-process (symbol-function #'make-process)))
+    (cl-letf (((symbol-function #'make-process)
+               (lambda (&rest plist)
+                 (setq captured-adaptive process-adaptive-read-buffering
+                       captured-max read-process-output-max)
+                 (apply orig-make-process plist))))
+      (with-temp-buffer
+        (let ((proc (ghostel--spawn-pty "/bin/sh" nil 24 80
+                                        "-ixon" nil nil)))
+          (unwind-protect
+              (progn
+                (should (null captured-adaptive))
+                (should (>= captured-max (* 1024 1024))))
+            (when (process-live-p proc)
+              (delete-process proc))))))))
+
+(ert-deftest ghostel-test-compile-spawn-disables-adaptive-read-buffering ()
+  "`ghostel-compile--spawn' must disable adaptive read buffering and
+raise `read-process-output-max'.  Same reason as
+`ghostel--spawn-pty' (issue #85)."
+  (let ((captured-adaptive 'unset)
+        (captured-max nil)
+        (orig-make-process (symbol-function #'make-process)))
+    (cl-letf (((symbol-function #'make-process)
+               (lambda (&rest plist)
+                 (setq captured-adaptive process-adaptive-read-buffering
+                       captured-max read-process-output-max)
+                 (apply orig-make-process plist))))
+      (with-temp-buffer
+        (let ((proc (ghostel-compile--spawn "true" (current-buffer) 24 80)))
+          (unwind-protect
+              (progn
+                (should (null captured-adaptive))
+                (should (>= captured-max (* 1024 1024))))
+            (when (process-live-p proc)
+              (delete-process proc))))))))
+
 ;; -----------------------------------------------------------------------
 ;; Tests: window resize
 ;; -----------------------------------------------------------------------